mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-08-27 14:07:51 +01:00
add VV for ID cards and card access (#29897)
* add VV for ID card access * Update code/game/objects/obj_vv.dm Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com> Signed-off-by: warriorstar-orion <orion@snowfrost.garden> * hell * ID card VV * dumb * fix build * log and message admins --------- Signed-off-by: warriorstar-orion <orion@snowfrost.garden> Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com>
This commit is contained in:
warriorstar-orion
co-authored by
Contrabang
Contrabang
parent
860d091ee1
commit
94e7b1d007
@@ -0,0 +1,92 @@
|
||||
RESTRICT_TYPE(/datum/ui_module/obj_access_modifier)
|
||||
|
||||
/datum/ui_module/obj_access_modifier
|
||||
name = "Access Modifier"
|
||||
var/obj/target_obj
|
||||
|
||||
/datum/ui_module/obj_access_modifier/New(datum/_host, obj/target)
|
||||
..()
|
||||
if(!(isobj(target)))
|
||||
stack_trace("Attempted to create an access modifier on a non-/obj")
|
||||
qdel(src)
|
||||
return
|
||||
|
||||
target_obj = target
|
||||
|
||||
/datum/ui_module/obj_access_modifier/ui_state(mob/user)
|
||||
return GLOB.admin_state
|
||||
|
||||
/datum/ui_module/obj_access_modifier/ui_interact(mob/user, datum/tgui/ui)
|
||||
ui = SStgui.try_update_ui(user, src, ui)
|
||||
if(!ui)
|
||||
ui = new(user, src, "ObjAccessModifier", name)
|
||||
ui.autoupdate = FALSE
|
||||
ui.open()
|
||||
|
||||
/datum/ui_module/obj_access_modifier/ui_data(mob/user)
|
||||
var/list/data = list(
|
||||
"one_access" = length(target_obj.req_one_access),
|
||||
"selected_accesses" = length(target_obj.req_one_access) ? target_obj.req_one_access : target_obj.req_access
|
||||
)
|
||||
|
||||
return data
|
||||
|
||||
/datum/ui_module/obj_access_modifier/ui_static_data(mob/user)
|
||||
var/list/data = list()
|
||||
data["regions"] = get_accesslist_static_data(REGION_GENERAL, REGION_MISC)
|
||||
return data
|
||||
|
||||
/datum/ui_module/obj_access_modifier/ui_act(action, list/params, datum/tgui/ui, datum/ui_state/state)
|
||||
if(..())
|
||||
return
|
||||
|
||||
var/one_access = length(target_obj.req_one_access)
|
||||
|
||||
switch(action)
|
||||
if("set_one_access")
|
||||
if((params["access"] == "one") && (length(target_obj.req_access)))
|
||||
target_obj.req_one_access = target_obj.req_access.Copy()
|
||||
target_obj.req_access.Cut()
|
||||
else
|
||||
target_obj.req_access = target_obj.req_one_access.Copy()
|
||||
target_obj.req_one_access.Cut()
|
||||
if("set")
|
||||
var/access = text2num(params["access"])
|
||||
if(isnull(access))
|
||||
return FALSE
|
||||
if(one_access)
|
||||
if(access in target_obj.req_one_access)
|
||||
target_obj.req_one_access -= access
|
||||
else
|
||||
target_obj.req_one_access |= access
|
||||
else
|
||||
if(access in target_obj.req_access)
|
||||
target_obj.req_access -= access
|
||||
else
|
||||
target_obj.req_access |= access
|
||||
if("grant_region")
|
||||
var/region = text2num(params["region"])
|
||||
if(isnull(region) || region < REGION_GENERAL || region > REGION_MISC)
|
||||
return FALSE
|
||||
if(one_access)
|
||||
target_obj.req_one_access |= get_region_accesses(region)
|
||||
else
|
||||
target_obj.req_access |= get_region_accesses(region)
|
||||
if("deny_region")
|
||||
var/region = text2num(params["region"])
|
||||
if(isnull(region) || region < REGION_GENERAL || region > REGION_MISC)
|
||||
return FALSE
|
||||
if(one_access)
|
||||
target_obj.req_one_access -= get_region_accesses(region)
|
||||
else
|
||||
target_obj.req_access -= get_region_accesses(region)
|
||||
if("grant_all")
|
||||
if(one_access)
|
||||
target_obj.req_one_access = get_absolutely_all_accesses()
|
||||
else
|
||||
target_obj.req_access = get_absolutely_all_accesses()
|
||||
if("clear_all")
|
||||
target_obj.req_one_access.Cut()
|
||||
target_obj.req_access.Cut()
|
||||
|
||||
return TRUE
|
||||
@@ -0,0 +1,93 @@
|
||||
RESTRICT_TYPE(/datum/ui_module/id_card_modifier)
|
||||
|
||||
/datum/ui_module/id_card_modifier
|
||||
name = "ID Card Modifier"
|
||||
var/obj/item/card/id/card
|
||||
|
||||
/datum/ui_module/id_card_modifier/New(datum/_host, obj/item/card/id/target)
|
||||
..()
|
||||
if(!istype(target))
|
||||
stack_trace("Attempted to create an access modifier on a non-/obj")
|
||||
qdel(src)
|
||||
return
|
||||
|
||||
card = target
|
||||
|
||||
/datum/ui_module/id_card_modifier/ui_state(mob/user)
|
||||
return GLOB.admin_state
|
||||
|
||||
/datum/ui_module/id_card_modifier/ui_interact(mob/user, datum/tgui/ui)
|
||||
ui = SStgui.try_update_ui(user, src, ui)
|
||||
if(!ui)
|
||||
ui = new(user, src, "IdCardModifier", name)
|
||||
ui.autoupdate = FALSE
|
||||
ui.open()
|
||||
|
||||
/datum/ui_module/id_card_modifier/ui_data(mob/user)
|
||||
. = list()
|
||||
.["card"] = card.to_tgui()
|
||||
.["card_skins"] = format_card_skins(get_station_card_skins())
|
||||
.["all_centcom_skins"] = format_card_skins(get_centcom_card_skins())
|
||||
|
||||
/datum/ui_module/id_card_modifier/ui_static_data(mob/user)
|
||||
. = list()
|
||||
.["regions"] = get_accesslist_static_data(REGION_GENERAL, REGION_MISC)
|
||||
|
||||
/datum/ui_module/id_card_modifier/ui_act(action, list/params, datum/tgui/ui, datum/ui_state/state)
|
||||
if(..())
|
||||
return
|
||||
|
||||
switch(action)
|
||||
if("reg")
|
||||
var/temp_name = reject_bad_name(input(usr, "Who is this ID for?", "ID Card Renaming", card.registered_name), TRUE)
|
||||
if(!temp_name)
|
||||
to_chat(usr, "<span class='warning'>Rejecting invalid name `[temp_name]`.</span>")
|
||||
return
|
||||
card.registered_name = temp_name
|
||||
card.regenerate_name()
|
||||
if("set_card_skin")
|
||||
card.icon_state = params["skin_target"]
|
||||
card.update_appearance(UPDATE_ICON_STATE)
|
||||
if("set_card_account_number") // card account number
|
||||
var/account_num = tgui_input_number(usr, "Account Number", "Input Number", card.associated_account_number, 9999999, 1000000)
|
||||
if(isnull(account_num))
|
||||
return
|
||||
card.associated_account_number = account_num
|
||||
if("set_job_name")
|
||||
var/job_name = tgui_input_text(
|
||||
usr,
|
||||
"Please input a job name. Note that this does not perform any security record or data core updates.",
|
||||
"Job Name",
|
||||
card.rank)
|
||||
if(isnull(job_name))
|
||||
return
|
||||
card.rank = job_name
|
||||
card.assignment = job_name
|
||||
card.regenerate_name()
|
||||
|
||||
// shamelessly copy-pasted from id_card_console.dm
|
||||
// Changing card access
|
||||
if("set") // add/remove a single access number
|
||||
var/access = text2num(params["access"])
|
||||
if(access in card.access)
|
||||
card.access -= access
|
||||
else
|
||||
card.access += access
|
||||
if("grant_region")
|
||||
var/region = text2num(params["region"])
|
||||
if(isnull(region) || region < REGION_GENERAL)
|
||||
to_chat(usr, "<span class='warning'>Rejecting invalid region `[region]`.</span>")
|
||||
return
|
||||
card.access |= get_region_accesses(region)
|
||||
if("deny_region")
|
||||
var/region = text2num(params["region"])
|
||||
if(isnull(region) || region < REGION_GENERAL)
|
||||
to_chat(usr, "<span class='warning'>Rejecting invalid region `[region]`.</span>")
|
||||
return
|
||||
card.access -= get_region_accesses(region)
|
||||
if("clear_all")
|
||||
card.access = list()
|
||||
if("grant_all")
|
||||
card.access |= get_all_accesses()
|
||||
|
||||
return TRUE
|
||||
Reference in New Issue
Block a user