Ports Crusher Trophies

code/modules/mining/equipment/kinetic_crusher.dm

@@ -0,0 +1,439 @@
+/*********************Mining Hammer****************/
+/obj/item/twohanded/kinetic_crusher
+	icon = 'icons/obj/mining.dmi'
+	icon_state = "crusher"
+	item_state = "crusher0"
+	name = "proto-kinetic crusher"
+	desc = "An early design of the proto-kinetic accelerator, it is little more than a combination of various mining tools cobbled together, forming a high-tech club. \
+	While it is an effective mining tool, it did little to aid any but the most skilled and/or suicidal miners against local fauna."
+	force = 0 //You can't hit stuff unless wielded
+	w_class = WEIGHT_CLASS_BULKY
+	slot_flags = SLOT_BACK
+	force_unwielded = 0
+	force_wielded = 20
+	throwforce = 5
+	throw_speed = 4
+	armour_penetration = 10
+	materials = list(MAT_METAL = 1150, MAT_GLASS = 2075)
+	hitsound = 'sound/weapons/bladeslice.ogg'
+	attack_verb = list("smashed", "crushed", "cleaved", "chopped", "pulped")
+	sharp = TRUE
+	actions_types = list(/datum/action/item_action/toggle_light)
+	var/list/trophies = list()
+	var/charged = TRUE
+	var/charge_time = 15
+	var/detonation_damage = 50
+	var/backstab_bonus = 30
+	var/light_on = FALSE
+	var/brightness_on = 5
+
+/obj/item/twohanded/kinetic_crusher/Destroy()
+	QDEL_LIST(trophies)
+	return ..()
+
+/obj/item/twohanded/kinetic_crusher/examine(mob/living/user)
+	..()
+	to_chat(user, "<span class='notice'>Mark a large creature with the destabilizing force, then hit them in melee to do <b>[force + detonation_damage]</b> damage.</span>")
+	to_chat(user, "<span class='notice'>Does <b>[force + detonation_damage + backstab_bonus]</b> damage if the target is backstabbed, instead of <b>[force + detonation_damage]</b>.</span>")
+	for(var/t in trophies)
+		var/obj/item/crusher_trophy/T = t
+		to_chat(user, "<span class='notice'>It has \a [T] attached, which causes [T.effect_desc()].</span>")
+
+/obj/item/twohanded/kinetic_crusher/attackby(obj/item/I, mob/living/user)
+	if(iscrowbar(I))
+		if(LAZYLEN(trophies))
+			to_chat(user, "<span class='notice'>You remove [src]'s trophies.</span>")
+			playsound(loc, I.usesound, 100, 1)
+			for(var/t in trophies)
+				var/obj/item/crusher_trophy/T = t
+				T.remove_from(src, user)
+		else
+			to_chat(user, "<span class='warning'>There are no trophies on [src].</span>")
+	else if(istype(I, /obj/item/crusher_trophy))
+		var/obj/item/crusher_trophy/T = I
+		T.add_to(src, user)
+	else
+		return ..()
+
+/obj/item/twohanded/kinetic_crusher/attack(mob/living/target, mob/living/carbon/user)
+	if(!wielded)
+		to_chat(user, "<span class='warning'>[src] is too heavy to use with one hand. You fumble and drop everything.")
+		user.drop_r_hand()
+		user.drop_l_hand()
+		return
+	var/datum/status_effect/crusher_damage/C = target.has_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
+	var/target_health = target.health
+	..()
+	for(var/t in trophies)
+		if(!QDELETED(target))
+			var/obj/item/crusher_trophy/T = t
+			T.on_melee_hit(target, user)
+	if(!QDELETED(C) && !QDELETED(target))
+		C.total_damage += target_health - target.health //we did some damage, but let's not assume how much we did
+
+/obj/item/twohanded/kinetic_crusher/afterattack(atom/target, mob/living/user, proximity_flag, clickparams)
+	. = ..()
+	if(!wielded)
+		return
+	if(!proximity_flag && charged)//Mark a target, or mine a tile.
+		var/turf/proj_turf = user.loc
+		if(!isturf(proj_turf))
+			return
+		var/obj/item/projectile/destabilizer/D = new /obj/item/projectile/destabilizer(proj_turf)
+		for(var/t in trophies)
+			var/obj/item/crusher_trophy/T = t
+			T.on_projectile_fire(D, user)
+		D.preparePixelProjectile(target, get_turf(target), user, clickparams)
+		D.firer = user
+		D.hammer_synced = src
+		playsound(user, 'sound/weapons/plasma_cutter.ogg', 100, 1)
+		D.fire()
+		charged = FALSE
+		update_icon()
+		addtimer(CALLBACK(src, .proc/Recharge), charge_time)
+		return
+	if(proximity_flag && isliving(target))
+		var/mob/living/L = target
+		var/datum/status_effect/crusher_mark/CM = L.has_status_effect(STATUS_EFFECT_CRUSHERMARK)
+		if(!CM || CM.hammer_synced != src || !L.remove_status_effect(STATUS_EFFECT_CRUSHERMARK))
+			return
+		var/datum/status_effect/crusher_damage/C = L.has_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
+		var/target_health = L.health
+		for(var/t in trophies)
+			var/obj/item/crusher_trophy/T = t
+			T.on_mark_detonation(target, user)
+		if(!QDELETED(L))
+			if(!QDELETED(C))
+				C.total_damage += target_health - L.health //we did some damage, but let's not assume how much we did
+			new /obj/effect/temp_visual/kinetic_blast(get_turf(L))
+			var/backstab_dir = get_dir(user, L)
+			var/def_check = L.getarmor(type = "bomb")
+			if((user.dir & backstab_dir) && (L.dir & backstab_dir))
+				if(!QDELETED(C))
+					C.total_damage += detonation_damage + backstab_bonus //cheat a little and add the total before killing it, so certain mobs don't have much lower chances of giving an item
+				L.apply_damage(detonation_damage + backstab_bonus, BRUTE, blocked = def_check)
+				playsound(user, 'sound/weapons/kenetic_accel.ogg', 100, 1) //Seriously who spelled it wrong
+			else
+				if(!QDELETED(C))
+					C.total_damage += detonation_damage
+				L.apply_damage(detonation_damage, BRUTE, blocked = def_check)
+
+/obj/item/twohanded/kinetic_crusher/proc/Recharge()
+	if(!charged)
+		charged = TRUE
+		update_icon()
+		playsound(src.loc, 'sound/weapons/kenetic_reload.ogg', 60, 1)
+
+/obj/item/twohanded/kinetic_crusher/ui_action_click(mob/user, actiontype)
+	light_on = !light_on
+	playsound(user, 'sound/weapons/empty.ogg', 100, TRUE)
+	update_brightness(user)
+	update_icon()
+
+/obj/item/twohanded/kinetic_crusher/proc/update_brightness(mob/user = null)
+	if(light_on)
+		set_light(brightness_on)
+	else
+		set_light(0)
+
+/obj/item/twohanded/kinetic_crusher/update_icon()
+	..()
+	cut_overlays()
+	if(!charged)
+		add_overlay("[icon_state]_uncharged")
+	if(light_on)
+		add_overlay("[icon_state]_lit")
+	spawn(1)
+		for(var/X in actions)
+			var/datum/action/A = X
+			A.UpdateButtonIcon()
+	item_state = "crusher[wielded]"
+
+//destablizing force
+/obj/item/projectile/destabilizer
+	name = "destabilizing force"
+	icon_state = "pulse1"
+	nodamage = TRUE
+	damage = 0 //We're just here to mark people. This is still a melee weapon.
+	damage_type = BRUTE
+	flag = "bomb"
+	range = 6
+	log_override = TRUE
+	var/obj/item/twohanded/kinetic_crusher/hammer_synced
+
+/obj/item/projectile/destabilizer/Destroy()
+	hammer_synced = null
+	return ..()
+
+/obj/item/projectile/destabilizer/on_hit(atom/target, blocked = FALSE)
+	if(isliving(target))
+		var/mob/living/L = target
+		var/had_effect = (L.has_status_effect(STATUS_EFFECT_CRUSHERMARK)) //used as a boolean
+		var/datum/status_effect/crusher_mark/CM = L.apply_status_effect(STATUS_EFFECT_CRUSHERMARK, hammer_synced)
+		if(hammer_synced)
+			for(var/t in hammer_synced.trophies)
+				var/obj/item/crusher_trophy/T = t
+				T.on_mark_application(target, CM, had_effect)
+	var/target_turf = get_turf(target)
+	if(ismineralturf(target_turf))
+		var/turf/simulated/mineral/M = target_turf
+		new /obj/effect/temp_visual/kinetic_blast(M)
+		M.gets_drilled(firer)
+	..()
+
+//trophies
+/obj/item/crusher_trophy
+	name = "tail spike"
+	desc = "A strange spike with no usage."
+	icon = 'icons/obj/lavaland/artefacts.dmi'
+	icon_state = "tail_spike"
+	var/bonus_value = 10 //if it has a bonus effect, this is how much that effect is
+	var/denied_type = /obj/item/crusher_trophy
+
+/obj/item/crusher_trophy/examine(mob/living/user)
+	..()
+	to_chat(user, "<span class='notice'>Causes [effect_desc()] when attached to a kinetic crusher.</span>")
+
+/obj/item/crusher_trophy/proc/effect_desc()
+	return "errors"
+
+/obj/item/crusher_trophy/attackby(obj/item/A, mob/living/user)
+	if(istype(A, /obj/item/twohanded/kinetic_crusher))
+		add_to(A, user)
+	else
+		..()
+
+/obj/item/crusher_trophy/proc/add_to(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	for(var/t in H.trophies)
+		var/obj/item/crusher_trophy/T = t
+		if(istype(T, denied_type) || istype(src, T.denied_type))
+			to_chat(user, "<span class='warning'>You can't seem to attach [src] to [H]. Maybe remove a few trophies?</span>")
+			return FALSE
+	if(!user.drop_item())
+		return
+	forceMove(H)
+	H.trophies += src
+	to_chat(user, "<span class='notice'>You attach [src] to [H].</span>")
+	return TRUE
+
+/obj/item/crusher_trophy/proc/remove_from(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	forceMove(get_turf(H))
+	H.trophies -= src
+	return TRUE
+
+/obj/item/crusher_trophy/proc/on_melee_hit(mob/living/target, mob/living/user) //the target and the user
+
+/obj/item/crusher_trophy/proc/on_projectile_fire(obj/item/projectile/destabilizer/marker, mob/living/user) //the projectile fired and the user
+
+/obj/item/crusher_trophy/proc/on_mark_application(mob/living/target, datum/status_effect/crusher_mark/mark, had_mark) //the target, the mark applied, and if the target had a mark before
+
+/obj/item/crusher_trophy/proc/on_mark_detonation(mob/living/target, mob/living/user) //the target and the user
+
+//goliath
+/obj/item/crusher_trophy/goliath_tentacle
+	name = "goliath tentacle"
+	desc = "A sliced-off goliath tentacle. Suitable as a trophy for a kinetic crusher."
+	icon_state = "goliath_tentacle"
+	denied_type = /obj/item/crusher_trophy/goliath_tentacle
+	bonus_value = 2
+	var/missing_health_ratio = 0.1
+	var/missing_health_desc = 10
+
+/obj/item/crusher_trophy/goliath_tentacle/effect_desc()
+	return "mark detonation to do <b>[bonus_value]</b> more damage for every <b>[missing_health_desc]</b> health you are missing"
+
+/obj/item/crusher_trophy/goliath_tentacle/on_mark_detonation(mob/living/target, mob/living/user)
+	var/missing_health = user.health - user.maxHealth
+	missing_health *= missing_health_ratio //bonus is active at all times, even if you're above 90 health
+	missing_health *= bonus_value //multiply the remaining amount by bonus_value
+	if(missing_health > 0)
+		target.adjustBruteLoss(missing_health) //and do that much damage
+
+//watcher
+/obj/item/crusher_trophy/watcher_wing
+	name = "watcher wing"
+	desc = "A wing ripped from a watcher. Suitable as a trophy for a kinetic crusher."
+	icon_state = "watcher_wing"
+	denied_type = /obj/item/crusher_trophy/watcher_wing
+	bonus_value = 5
+
+/obj/item/crusher_trophy/watcher_wing/effect_desc()
+	return "mark detonation to prevent certain creatures from using certain attacks for <b>[bonus_value*0.1]</b> second\s"
+
+/obj/item/crusher_trophy/watcher_wing/on_mark_detonation(mob/living/target, mob/living/user)
+	if(ishostile(target))
+		var/mob/living/simple_animal/hostile/H = target
+		if(H.ranged) //briefly delay ranged attacks
+			if(H.ranged_cooldown >= world.time)
+				H.ranged_cooldown += bonus_value
+			else
+				H.ranged_cooldown = bonus_value + world.time
+
+//magmawing watcher
+/obj/item/crusher_trophy/blaster_tubes/magma_wing
+	name = "magmawing watcher wing"
+	desc = "A still-searing wing from a magmawing watcher. Suitable as a trophy for a kinetic crusher."
+	icon_state = "magma_wing"
+	gender = NEUTER
+	bonus_value = 5
+
+/obj/item/crusher_trophy/blaster_tubes/magma_wing/effect_desc()
+	return "mark detonation to make the next destabilizer shot deal <b>[bonus_value]</b> damage"
+
+/obj/item/crusher_trophy/blaster_tubes/magma_wing/on_projectile_fire(obj/item/projectile/destabilizer/marker, mob/living/user)
+	if(deadly_shot)
+		marker.name = "heated [marker.name]"
+		marker.icon_state = "lava"
+		marker.damage = bonus_value
+		marker.nodamage = FALSE
+		deadly_shot = FALSE
+
+//icewing watcher
+/obj/item/crusher_trophy/watcher_wing/ice_wing
+	name = "icewing watcher wing"
+	desc = "A carefully preserved frozen wing from an icewing watcher. Suitable as a trophy for a kinetic crusher."
+	icon_state = "ice_wing"
+	bonus_value = 8
+
+//legion
+/obj/item/crusher_trophy/legion_skull
+	name = "legion skull"
+	desc = "A dead and lifeless legion skull. Suitable as a trophy for a kinetic crusher."
+	icon_state = "legion_skull"
+	denied_type = /obj/item/crusher_trophy/legion_skull
+	bonus_value = 3
+
+/obj/item/crusher_trophy/legion_skull/effect_desc()
+	return "a kinetic crusher to recharge <b>[bonus_value*0.1]</b> second\s faster"
+
+/obj/item/crusher_trophy/legion_skull/add_to(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	. = ..()
+	if(.)
+		H.charge_time -= bonus_value
+
+/obj/item/crusher_trophy/legion_skull/remove_from(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	. = ..()
+	if(.)
+		H.charge_time += bonus_value
+
+//blood-drunk hunter
+/obj/item/crusher_trophy/miner_eye
+	name = "eye of a blood-drunk hunter"
+	desc = "Its pupil is collapsed and turned to mush. Suitable as a trophy for a kinetic crusher."
+	icon_state = "hunter_eye"
+	denied_type = /obj/item/crusher_trophy/miner_eye
+
+/obj/item/crusher_trophy/miner_eye/effect_desc()
+	return "mark detonation to grant stun immunity and <b>90%</b> damage reduction for <b>1</b> second"
+
+/obj/item/crusher_trophy/miner_eye/on_mark_detonation(mob/living/target, mob/living/user)
+	user.apply_status_effect(STATUS_EFFECT_BLOODDRUNK)
+
+//ash drake
+/obj/item/crusher_trophy/tail_spike
+	desc = "A spike taken from an ash drake's tail. Suitable as a trophy for a kinetic crusher."
+	denied_type = /obj/item/crusher_trophy/tail_spike
+	bonus_value = 5
+
+/obj/item/crusher_trophy/tail_spike/effect_desc()
+	return "mark detonation to do <b>[bonus_value]</b> damage to nearby creatures and push them back"
+
+/obj/item/crusher_trophy/tail_spike/on_mark_detonation(mob/living/target, mob/living/user)
+	for(var/mob/living/L in oview(2, user))
+		if(L.stat == DEAD)
+			continue
+		playsound(L, 'sound/magic/fireball.ogg', 20, 1)
+		new /obj/effect/temp_visual/fire(L.loc)
+		addtimer(CALLBACK(src, .proc/pushback, L, user), 1) //no free backstabs, we push AFTER module stuff is done
+		L.adjustFireLoss(bonus_value)
+
+/obj/item/crusher_trophy/tail_spike/proc/pushback(mob/living/target, mob/living/user)
+	if(!QDELETED(target) && !QDELETED(user) && (!target.anchored || ismegafauna(target))) //megafauna will always be pushed
+		step(target, get_dir(user, target))
+
+//bubblegum
+/obj/item/crusher_trophy/demon_claws
+	name = "demon claws"
+	desc = "A set of blood-drenched claws from a massive demon's hand. Suitable as a trophy for a kinetic crusher."
+	icon_state = "demon_claws"
+	gender = PLURAL
+	denied_type = /obj/item/crusher_trophy/demon_claws
+	bonus_value = 10
+	var/static/list/damage_heal_order = list(BRUTE, BURN, OXY)
+
+/obj/item/crusher_trophy/demon_claws/effect_desc()
+	return "melee hits to do <b>[bonus_value * 0.2]</b> more damage and heal you for <b>[bonus_value * 0.1]</b>, with <b>5X</b> effect on mark detonation"
+
+/obj/item/crusher_trophy/demon_claws/add_to(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	. = ..()
+	if(.)
+		H.force += bonus_value * 0.2
+		H.force_unwielded += bonus_value * 0.2
+		H.force_wielded += bonus_value * 0.2
+		H.detonation_damage += bonus_value * 0.8
+
+/obj/item/crusher_trophy/demon_claws/remove_from(obj/item/twohanded/kinetic_crusher/H, mob/living/user)
+	. = ..()
+	if(.)
+		H.force -= bonus_value * 0.2
+		H.force_unwielded -= bonus_value * 0.2
+		H.force_wielded -= bonus_value * 0.2
+		H.detonation_damage -= bonus_value * 0.8
+
+/obj/item/crusher_trophy/demon_claws/on_melee_hit(mob/living/target, mob/living/user)
+	user.heal_ordered_damage(bonus_value * 0.1, damage_heal_order)
+
+/obj/item/crusher_trophy/demon_claws/on_mark_detonation(mob/living/target, mob/living/user)
+	user.heal_ordered_damage(bonus_value * 0.4, damage_heal_order)
+
+//colossus
+/obj/item/crusher_trophy/blaster_tubes
+	name = "blaster tubes"
+	desc = "The blaster tubes from a colossus's arm. Suitable as a trophy for a kinetic crusher."
+	icon_state = "blaster_tubes"
+	gender = PLURAL
+	denied_type = /obj/item/crusher_trophy/blaster_tubes
+	bonus_value = 15
+	var/deadly_shot = FALSE
+
+/obj/item/crusher_trophy/blaster_tubes/effect_desc()
+	return "mark detonation to make the next destabilizer shot deal <b>[bonus_value]</b> damage but move slower"
+
+/obj/item/crusher_trophy/blaster_tubes/on_projectile_fire(obj/item/projectile/destabilizer/marker, mob/living/user)
+	if(deadly_shot)
+		marker.name = "deadly [marker.name]"
+		marker.icon_state = "chronobolt"
+		marker.damage = bonus_value
+		marker.nodamage = FALSE
+		marker.speed = 2
+		deadly_shot = FALSE
+
+/obj/item/crusher_trophy/blaster_tubes/on_mark_detonation(mob/living/target, mob/living/user)
+	deadly_shot = TRUE
+	addtimer(CALLBACK(src, .proc/reset_deadly_shot), 300, TIMER_UNIQUE|TIMER_OVERRIDE)
+
+/obj/item/crusher_trophy/blaster_tubes/proc/reset_deadly_shot()
+	deadly_shot = FALSE
+
+//hierophant
+/obj/item/crusher_trophy/vortex_talisman
+	name = "vortex talisman"
+	desc = "A glowing trinket that was originally the Hierophant's beacon. Suitable as a trophy for a kinetic crusher."
+	icon_state = "vortex_talisman"
+	denied_type = /obj/item/crusher_trophy/vortex_talisman
+
+/obj/item/crusher_trophy/vortex_talisman/effect_desc()
+	return "mark detonation to create a barrier you can pass"
+
+/obj/item/crusher_trophy/vortex_talisman/on_mark_detonation(mob/living/target, mob/living/user)
+	var/turf/T = get_turf(user)
+	new /obj/effect/temp_visual/hierophant/wall/crusher(T, user) //a wall only you can pass!
+	var/turf/otherT = get_step(T, turn(user.dir, 90))
+	if(otherT)
+		new /obj/effect/temp_visual/hierophant/wall/crusher(otherT, user)
+	otherT = get_step(T, turn(user.dir, -90))
+	if(otherT)
+		new /obj/effect/temp_visual/hierophant/wall/crusher(otherT, user)
+
+/obj/effect/temp_visual/hierophant/wall/crusher
+	duration = 75

code/modules/mining/equipment_locker.dm

@@ -421,7 +421,7 @@
 		new /datum/data/mining_equipment("Brute First-Aid Kit",			/obj/item/storage/firstaid/brute,									600),
 		new /datum/data/mining_equipment("Tracking Implant Kit", 		/obj/item/storage/box/minertracker,									600),
 		new /datum/data/mining_equipment("Jaunter",						/obj/item/wormhole_jaunter,											750),
-		new /datum/data/mining_equipment("Kinetic Crusher",				/obj/item/twohanded/required/kinetic_crusher,						750),
+		new /datum/data/mining_equipment("Kinetic Crusher",				/obj/item/twohanded/kinetic_crusher,								750),
 		new /datum/data/mining_equipment("Kinetic Accelerator",			/obj/item/gun/energy/kinetic_accelerator,							750),
 		new /datum/data/mining_equipment("Advanced Scanner",			/obj/item/t_scanner/adv_mining_scanner,								800),
 		new /datum/data/mining_equipment("Resonator",					/obj/item/resonator,												800),
@@ -625,7 +625,7 @@
 //			new /obj/item/stack/marker_beacon/thirty(drop_location)
 		if("Crusher Kit")
 			new /obj/item/extinguisher/mini(drop_location)
-			new /obj/item/twohanded/required/kinetic_crusher(drop_location)
+			new /obj/item/twohanded/kinetic_crusher(drop_location)
 		if("Mining Conscription Kit")
 			new /obj/item/storage/backpack/duffel/mining_conscript(drop_location)
 
@@ -1148,103 +1148,4 @@
 		return ..()
 	C.preserved = 1
 	to_chat(user, "<span class='notice'>You inject the hivelord core with the stabilizer. It will no longer go inert.</span>")
-	qdel(src)
-
-/*********************Mining Hammer****************/
-/obj/item/twohanded/required/kinetic_crusher
-	icon = 'icons/obj/mining.dmi'
-	icon_state = "mining_hammer1"
-	item_state = "mining_hammer1"
-	name = "proto-kinetic crusher"
-	desc = "An early design of the proto-kinetic accelerator, it is little more than an combination of various mining tools cobbled together, forming a high-tech club.\
-	  While it is an effective mining tool, it did little to aid any but the most skilled and/or suicidal miners against local fauna. \
-	 \n<span class='info'>Mark a mob with the destabilizing force, then hit them in melee to activate it for extra damage. Extra damage if backstabbed in this fashion. \
-	 This weapon is only particularly effective against large creatures.</span>"
-	force = 20 //As much as a bone spear, but this is significantly more annoying to carry around due to requiring the use of both hands at all times
-	w_class = WEIGHT_CLASS_BULKY
-	slot_flags = SLOT_BACK
-	force_unwielded = 20 //It's never not wielded so these are the same
-	force_wielded = 20
-	throwforce = 5
-	throw_speed = 4
-	light_range = 4
-	armour_penetration = 10
-	materials = list(MAT_METAL=1150, MAT_GLASS=2075)
-	hitsound = 'sound/weapons/bladeslice.ogg'
-	attack_verb = list("smashes", "crushes", "cleaves", "chops", "pulps")
-	sharp = 1
-	var/charged = 1
-	var/charge_time = 16
-	var/atom/mark = null
-	var/marked_image = null
-
-/obj/item/projectile/destabilizer
-	name = "destabilizing force"
-	icon_state = "pulse1"
-	damage = 0 //We're just here to mark people. This is still a melee weapon.
-	damage_type = BRUTE
-	flag = "bomb"
-	range = 6
-	var/obj/item/twohanded/required/kinetic_crusher/hammer_synced =  null
-
-/obj/item/projectile/destabilizer/on_hit(atom/target, blocked = 0, hit_zone)
-	if(hammer_synced)
-		if(hammer_synced.mark == target)
-			return ..()
-		if(isliving(target))
-			if(hammer_synced.mark && hammer_synced.marked_image)
-				hammer_synced.mark.underlays -= hammer_synced.marked_image
-				hammer_synced.marked_image = null
-			var/mob/living/L = target
-			if(L.mob_size >= MOB_SIZE_LARGE)
-				hammer_synced.mark = L
-				var/image/I = image('icons/effects/effects.dmi', loc = L, icon_state = "shield2",pixel_y = (-L.pixel_y),pixel_x = (-L.pixel_x))
-				L.underlays += I
-				hammer_synced.marked_image = I
-		var/target_turf = get_turf(target)
-		if(istype(target_turf, /turf/simulated/mineral))
-			var/turf/simulated/mineral/M = target_turf
-			new /obj/effect/temp_visual/kinetic_blast(M)
-			M.gets_drilled(firer)
-	..()
-
-/obj/item/twohanded/required/kinetic_crusher/afterattack(atom/target, mob/user, proximity_flag)
-	if(!proximity_flag && charged)//Mark a target, or mine a tile.
-		var/turf/proj_turf = get_turf(src)
-		if(!istype(proj_turf, /turf))
-			return
-		var/datum/gas_mixture/environment = proj_turf.return_air()
-		var/pressure = environment.return_pressure()
-		if(pressure > 50)
-			playsound(user, 'sound/weapons/empty.ogg', 100, 1)
-			return
-		var/obj/item/projectile/destabilizer/D = new /obj/item/projectile/destabilizer(user.loc)
-		D.preparePixelProjectile(target,get_turf(target), user)
-		D.hammer_synced = src
-		playsound(user, 'sound/weapons/plasma_cutter.ogg', 100, 1)
-		D.fire()
-		charged = 0
-		icon_state = "mining_hammer1_uncharged"
-		spawn(charge_time)
-			Recharge()
-		return
-	if(proximity_flag && target == mark && isliving(target))
-		var/mob/living/L = target
-		new /obj/effect/temp_visual/kinetic_blast(get_turf(L))
-		mark = 0
-		if(L.mob_size >= MOB_SIZE_LARGE)
-			L.underlays -= marked_image
-			QDEL_NULL(marked_image)
-			var/backstab = check_target_facings(user, L)
-			var/def_check = L.getarmor(type = "bomb")
-			if(backstab == FACING_INIT_FACING_TARGET_TARGET_FACING_PERPENDICULAR || backstab == FACING_SAME_DIR)
-				L.apply_damage(80, BRUTE, blocked = def_check)
-				playsound(user, 'sound/weapons/kenetic_accel.ogg', 100, 1) //Seriously who spelled it wrong
-			else
-				L.apply_damage(50, BRUTE, blocked = def_check)
-
-/obj/item/twohanded/required/kinetic_crusher/proc/Recharge()
-	if(!charged)
-		charged = 1
-		icon_state = "mining_hammer1"
-		playsound(loc, 'sound/weapons/kenetic_reload.ogg', 60, 1)
+	qdel(src)

code/modules/mining/explorer_gear.dm

@@ -41,4 +41,57 @@
 		"Drask" = 'icons/mob/species/drask/head.dmi',
 		"Grey" = 'icons/mob/species/grey/head.dmi',
 		"Skrell" = 'icons/mob/species/skrell/head.dmi'
-	)
+	)
+
+/obj/item/clothing/suit/space/hostile_environment
+	name = "H.E.C.K. suit"
+	desc = "Hostile Environment Cross-Kinetic Suit: A suit designed to withstand the wide variety of hazards from Lavaland. It wasn't enough for its last owner."
+	icon_state = "hostile_env"
+	item_state = "hostile_env"
+	flags = THICKMATERIAL //not spaceproof
+	max_heat_protection_temperature = FIRE_IMMUNITY_MAX_TEMP_PROTECT
+	burn_state = FIRE_PROOF | LAVA_PROOF
+	slowdown = 0
+	armor = list(melee = 70, bullet = 40, laser = 10, energy = 10, bomb = 50, bio = 100, rad = 100)
+	allowed = list(/obj/item/flashlight, /obj/item/tank, /obj/item/resonator, /obj/item/mining_scanner, /obj/item/t_scanner/adv_mining_scanner, /obj/item/gun/energy/kinetic_accelerator, /obj/item/pickaxe)
+
+/obj/item/clothing/suit/space/hostile_environment/New()
+	..()
+	AddComponent(/datum/component/spraycan_paintable)
+	START_PROCESSING(SSobj, src)
+
+/obj/item/clothing/suit/space/hostile_environment/Destroy()
+	STOP_PROCESSING(SSobj, src)
+	return ..()
+
+/obj/item/clothing/suit/space/hostile_environment/process()
+	var/mob/living/carbon/C = loc
+	if(istype(C) && prob(2)) //cursed by bubblegum
+		if(prob(15))
+			new /obj/effect/hallucination/oh_yeah(get_turf(C), C)
+			to_chat(C, "<span class='colossus'><b>[pick("I AM IMMORTAL.","I SHALL TAKE BACK WHAT'S MINE.","I SEE YOU.","YOU CANNOT ESCAPE ME FOREVER.","DEATH CANNOT HOLD ME.")]</b></span>")
+		else
+			to_chat(C, "<span class='warning'>[pick("You hear faint whispers.","You smell ash.","You feel hot.","You hear a roar in the distance.")]</span>")
+
+/obj/item/clothing/head/helmet/space/hostile_environment
+	name = "H.E.C.K. helmet"
+	desc = "Hostile Environiment Cross-Kinetic Helmet: A helmet designed to withstand the wide variety of hazards from Lavaland. It wasn't enough for its last owner."
+	icon_state = "hostile_env"
+	item_state = "hostile_env"
+	w_class = WEIGHT_CLASS_NORMAL
+	max_heat_protection_temperature = FIRE_IMMUNITY_MAX_TEMP_PROTECT
+	flags = THICKMATERIAL // no space protection
+	armor = list(melee = 70, bullet = 40, laser = 10, energy = 10, bomb = 50, bio = 100, rad = 100)
+	burn_state = FIRE_PROOF | LAVA_PROOF
+
+/obj/item/clothing/head/helmet/space/hostile_environment/New()
+	..()
+	AddComponent(/datum/component/spraycan_paintable)
+	update_icon()
+
+/obj/item/clothing/head/helmet/space/hostile_environment/update_icon()
+	..()
+	cut_overlays()
+	var/mutable_appearance/glass_overlay = mutable_appearance(icon, "hostile_env_glass")
+	glass_overlay.appearance_flags = RESET_COLOR
+	add_overlay(glass_overlay)

code/modules/mining/lavaland/loot/ashdragon_loot.dm

@@ -15,6 +15,15 @@
 		if(4)
 			new /obj/item/dragons_blood(src)
 
+
+/obj/structure/closet/crate/necropolis/dragon/crusher
+	name = "firey dragon chest"
+
+/obj/structure/closet/crate/necropolis/dragon/crusher/New()
+	..()
+	new /obj/item/crusher_trophy/tail_spike(src)
+
+
 // Spectral Blade
 
 /obj/item/melee/ghost_sword

code/modules/mining/lavaland/loot/bubblegum_loot.dm

@@ -3,6 +3,8 @@
 
 /obj/structure/closet/crate/necropolis/bubblegum/New()
 	..()
+	new /obj/item/clothing/suit/space/hostile_environment(src)
+	new /obj/item/clothing/head/helmet/space/hostile_environment(src)
 	var/loot = rand(1,3)
 	switch(loot)
 		if(1)
@@ -12,6 +14,13 @@
 		if(3)
 			new /obj/item/gun/magic/staff/spellblade(src)
 
+/obj/structure/closet/crate/necropolis/bubblegum/crusher
+	name = "bloody bubblegum chest"
+
+/obj/structure/closet/crate/necropolis/bubblegum/crusher/New()
+	..()
+	new /obj/item/crusher_trophy/demon_claws(src)
+
 // Mayhem
 
 /obj/item/mayhem

code/modules/mining/lavaland/loot/colossus_loot.dm

@@ -1,3 +1,22 @@
+//Colossus
+/obj/structure/closet/crate/necropolis/colossus
+	name = "colossus chest"
+
+/obj/structure/closet/crate/necropolis/colossus/New()
+	..()
+	var/list/choices = subtypesof(/obj/machinery/anomalous_crystal)
+	var/random_crystal = pick(choices)
+	new random_crystal(src)
+	new /obj/item/organ/internal/vocal_cords/colossus(src)
+
+/obj/structure/closet/crate/necropolis/colossus/crusher
+	name = "angelic colossus chest"
+
+/obj/structure/closet/crate/necropolis/colossus/crusher/New()
+	..()
+	new /obj/item/crusher_trophy/blaster_tubes(src)
+
+
 //Black Box
 
 /obj/machinery/smartfridge/black_box

code/modules/mining/lavaland/necropolis_chests.dm

@@ -57,7 +57,10 @@
 		if(15)
 			new /obj/item/guardiancreator(src)
 		if(16)
-			new /obj/item/disk/design_disk/modkit_disc/mob_and_turf_aoe(src)
+			if(prob(50))
+				new /obj/item/disk/design_disk/modkit_disc/mob_and_turf_aoe(src)
+			else
+				new /obj/item/disk/design_disk/modkit_disc/bounty(src)
 		if(17)
 			new /obj/item/warp_cube/red(src)
 		if(18)
@@ -118,6 +121,10 @@
 	name = "Resonator Blast Mod Disk"
 	modkit_design = /datum/design/unique_modkit/resonator_blast
 
+/obj/item/disk/design_disk/modkit_disc/bounty
+	name = "Death Syphon Mod Disk"
+	modkit_design = /datum/design/unique_modkit/bounty
+
 /datum/design/unique_modkit
 	category = list("Mining", "Cyborg Upgrade Modules") //can't be normally obtained
 	build_type = PROTOLATHE | MECHFAB
@@ -141,4 +148,12 @@
 	desc = "A device which causes kinetic accelerators to fire shots that leave and detonate resonator blasts."
 	id = "resonatormod"
 	materials = list(MAT_METAL = 5000, MAT_GLASS = 5000, MAT_SILVER= 5000, MAT_URANIUM = 5000)
-	build_path = /obj/item/borg/upgrade/modkit/resonator_blasts
+	build_path = /obj/item/borg/upgrade/modkit/resonator_blasts
+
+/datum/design/unique_modkit/bounty
+	name = "Kinetic Accelerator Death Syphon Mod"
+	desc = "A device which causes kinetic accelerators to permanently gain damage against creature types killed with it."
+	id = "bountymod"
+	materials = list(MAT_METAL = 4000, MAT_SILVER = 4000, MAT_GOLD = 4000, MAT_BLUESPACE = 4000)
+	reagents_list = list("blood" = 40)
+	build_path = /obj/item/borg/upgrade/modkit/bounty

code/modules/mob/living/carbon/human/update_icons.dm

@@ -586,7 +586,8 @@ var/global/list/damage_icon_parts = list()
 					standing.overlays += image("icon" = A.sprite_sheets[dna.species.name], "icon_state" = "[A.icon_state]")
 				else
 					standing.overlays += image("icon" = 'icons/mob/ties.dmi', "icon_state" = "[tie_color]")
-
+		standing.alpha = w_uniform.alpha
+		standing.color = w_uniform.color
 		overlays_standing[UNIFORM_LAYER] = standing
 	else
 		// Automatically drop anything in store / id / belt if you're not wearing a uniform.	//CHECK IF NECESARRY
@@ -769,6 +770,8 @@ var/global/list/damage_icon_parts = list()
 			var/image/bloodsies = image("icon" = dna.species.blood_mask, "icon_state" = "shoeblood")
 			bloodsies.color = shoes.blood_color
 			standing.overlays += bloodsies
+		standing.alpha = shoes.alpha
+		standing.color = shoes.color
 		overlays_standing[SHOES_LAYER] = standing
 	else
 		if(feet_blood_DNA)
@@ -819,6 +822,8 @@ var/global/list/damage_icon_parts = list()
 			var/image/bloodsies = image("icon" = dna.species.blood_mask, "icon_state" = "helmetblood")
 			bloodsies.color = head.blood_color
 			standing.overlays += bloodsies
+		standing.alpha = head.alpha
+		standing.color = head.color
 		overlays_standing[HEAD_LAYER] = standing
 	apply_overlay(HEAD_LAYER)
 
@@ -886,6 +891,8 @@ var/global/list/damage_icon_parts = list()
 			bloodsies.color = wear_suit.blood_color
 			standing.overlays += bloodsies
 
+		standing.alpha = wear_suit.alpha
+		standing.color = wear_suit.color
 		overlays_standing[SUIT_LAYER] = standing
 
 	apply_overlay(SUIT_LAYER)
@@ -951,6 +958,8 @@ var/global/list/damage_icon_parts = list()
 			var/image/bloodsies = image("icon" = dna.species.blood_mask, "icon_state" = "maskblood")
 			bloodsies.color = wear_mask.blood_color
 			standing.overlays += bloodsies
+		standing.alpha = wear_mask.alpha
+		standing.color = wear_mask.color
 		overlays_standing[FACEMASK_LAYER] = standing
 	apply_overlay(FACEMASK_LAYER)
 
@@ -973,6 +982,8 @@ var/global/list/damage_icon_parts = list()
 			standing = mutable_appearance('icons/mob/back.dmi', "[back.icon_state]", layer = -BACK_LAYER)
 
 		//create the image
+		standing.alpha = back.alpha
+		standing.color = back.color
 		overlays_standing[BACK_LAYER] = standing
 	apply_overlay(BACK_LAYER)
 

code/modules/mob/living/simple_animal/hostile/megafauna/blood_drunk_miner.dm

@@ -37,6 +37,7 @@ Difficulty: Medium
 	ranged = 1
 	ranged_cooldown_time = 16
 	pixel_x = -16
+	crusher_loot = list(/obj/item/melee/energy/cleaving_saw, /obj/item/gun/energy/kinetic_accelerator, /obj/item/crusher_trophy/miner_eye)
 	loot = list(/obj/item/melee/energy/cleaving_saw, /obj/item/gun/energy/kinetic_accelerator)
 	wander = FALSE
 	del_on_death = TRUE
@@ -48,7 +49,7 @@ Difficulty: Medium
 	var/guidance = FALSE
 	deathmessage = "falls to the ground, decaying into glowing particles."
 	death_sound = "bodyfall"
-    
+
 /obj/item/gps/internal/miner
 	icon_state = null
 	gpstag = "Resonant Signal"

code/modules/mob/living/simple_animal/hostile/megafauna/bubblegum.dm

@@ -42,6 +42,7 @@ Difficulty: Hard
 	ranged = 1
 	pixel_x = -32
 	del_on_death = 1
+	crusher_loot = list(/obj/structure/closet/crate/necropolis/bubblegum/crusher)
 	loot = list(/obj/structure/closet/crate/necropolis/bubblegum)
 	var/charging = 0
 	medal_type = BOSS_MEDAL_BUBBLEGUM

code/modules/mob/living/simple_animal/hostile/megafauna/colossus.dm

@@ -45,7 +45,8 @@ Difficulty: Very Hard
 	del_on_death = 1
 	medal_type = BOSS_MEDAL_COLOSSUS
 	score_type = COLOSSUS_SCORE
-	loot = list(/obj/machinery/anomalous_crystal/random, /obj/item/organ/internal/vocal_cords/colossus)
+	crusher_loot = list(/obj/structure/closet/crate/necropolis/colossus/crusher)
+	loot = list(/obj/structure/closet/crate/necropolis/colossus)
 	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/sinew = 5, /obj/item/stack/sheet/animalhide/ashdrake = 10, /obj/item/stack/sheet/bone = 30)
 	deathmessage = "disintegrates, leaving a glowing core in its wake."
 	death_sound = 'sound/misc/demon_dies.ogg'

code/modules/mob/living/simple_animal/hostile/megafauna/drake.dm

@@ -43,6 +43,7 @@ Difficulty: Medium
 	move_to_delay = 10
 	ranged = 1
 	pixel_x = -16
+	crusher_loot = list(/obj/structure/closet/crate/necropolis/dragon/crusher)
 	loot = list(/obj/structure/closet/crate/necropolis/dragon)
 	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/sinew = 5, /obj/item/stack/sheet/animalhide/ashdrake = 10, /obj/item/stack/sheet/bone = 30)
 	var/swooping = 0
@@ -271,6 +272,7 @@ Difficulty: Medium
 	melee_damage_lower = 30
 	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 1, CLONE = 1, STAMINA = 0, OXY = 1)
 	loot = list()
+	crusher_loot = list()
 
 /mob/living/simple_animal/hostile/megafauna/dragon/lesser/grant_achievement(medaltype,scoretype)
 	return

code/modules/mob/living/simple_animal/hostile/megafauna/hierophant.dm

@@ -53,6 +53,7 @@ Difficulty: Hard
 	ranged_cooldown_time = 40
 	aggro_vision_range = 23
 	loot = list(/obj/item/hierophant_staff)
+	crusher_loot = list(/obj/item/hierophant_staff, /obj/item/crusher_trophy/vortex_talisman)
 	wander = FALSE
 	var/burst_range = 3 //range on burst aoe
 	var/beam_range = 5 //range on cross blast beams
@@ -556,6 +557,37 @@ Difficulty: Hard
 		playsound(M,'sound/weapons/sear.ogg', 50, 1, -4)
 		M.take_damage(damage, BURN, 0, 0)
 
+/obj/effect/temp_visual/hierophant/wall //smoothing and pooling were not friends, but pooling is dead.
+	name = "vortex wall"
+	icon = 'icons/turf/walls/hierophant_wall_temp.dmi'
+	icon_state = "wall"
+	light_range = MINIMUM_USEFUL_LIGHT_RANGE
+	duration = 100
+	smooth = SMOOTH_TRUE
+
+/obj/effect/temp_visual/hierophant/wall/New(loc, new_caster)
+	..()
+	queue_smooth_neighbors(src)
+	queue_smooth(src)
+
+/obj/effect/temp_visual/hierophant/wall/Destroy()
+	queue_smooth_neighbors(src)
+	return ..()
+
+/obj/effect/temp_visual/hierophant/wall/CanPass(atom/movable/mover, turf/target)
+	if(QDELETED(caster))
+		return FALSE
+	if(mover == caster.pulledby)
+		return TRUE
+	if(istype(mover, /obj/item/projectile))
+		var/obj/item/projectile/P = mover
+		if(P.firer == caster)
+			return TRUE
+	if(mover == caster)
+		return TRUE
+	return FALSE
+
+
 /obj/effect/hierophant
 	name = "hierophant rune"
 	desc = "A powerful magic mark allowing whomever attunes themself to it to return to it at will."

code/modules/mob/living/simple_animal/hostile/megafauna/megafauna.dm

@@ -31,6 +31,7 @@
 	/obj/structure/barricade,
 	/obj/machinery/field,
 	/obj/machinery/power/emitter)
+	var/list/crusher_loot
 	var/medal_type
 	var/score_type = BOSS_SCORE
 	var/elimination = 0
@@ -43,6 +44,10 @@
 	layer = LARGE_MOB_LAYER //Looks weird with them slipping under mineral walls and cameras and shit otherwise
 	mouse_opacity = MOUSE_OPACITY_OPAQUE // Easier to click on in melee, they're giant targets anyway
 
+/mob/living/simple_animal/hostile/megafauna/New()
+	..()
+	apply_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
+
 /mob/living/simple_animal/hostile/megafauna/Destroy()
 	QDEL_NULL(internal_gps)
 	. = ..()
@@ -53,11 +58,17 @@
 /mob/living/simple_animal/hostile/megafauna/death(gibbed)
 	// this happens before the parent call because `del_on_death` may be set
 	if(can_die() && !admin_spawned)
-		feedback_set_details("megafauna_kills","[initial(name)]")
+		var/datum/status_effect/crusher_damage/C = has_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
+		if(C && crusher_loot && C.total_damage >= maxHealth * 0.6)
+			spawn_crusher_loot()
 		if(!elimination)	//used so the achievment only occurs for the last legion to die.
 			grant_achievement(medal_type,score_type)
+			feedback_set_details("megafauna_kills","[initial(name)]")
 	return ..()
 
+/mob/living/simple_animal/hostile/megafauna/proc/spawn_crusher_loot()
+	loot = crusher_loot
+
 /mob/living/simple_animal/hostile/megafauna/AttackingTarget()
 	..()
 	if(isliving(target))

code/modules/mob/living/simple_animal/hostile/mining/basilisk.dm

@@ -77,6 +77,7 @@
 	stat_attack = 1
 	flying = TRUE
 	robust_searching = 1
+	crusher_loot = /obj/item/crusher_trophy/watcher_wing
 	loot = list()
 	butcher_results = list(/obj/item/stack/ore/diamond = 2, /obj/item/stack/sheet/sinew = 2, /obj/item/stack/sheet/bone = 1)
 
@@ -102,6 +103,8 @@
 	light_power = 2.5
 	light_color = LIGHT_COLOR_ORANGE
 	projectiletype = /obj/item/projectile/temp/basilisk/magmawing
+	crusher_loot = /obj/item/crusher_trophy/blaster_tubes/magma_wing
+	crusher_drop_mod = 60
 
 /mob/living/simple_animal/hostile/asteroid/basilisk/watcher/icewing
 	name = "icewing watcher"
@@ -114,6 +117,8 @@
 	health = 170
 	projectiletype = /obj/item/projectile/temp/basilisk/icewing
 	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/bone = 1) //No sinew; the wings are too fragile to be usable
+	crusher_loot = /obj/item/crusher_trophy/watcher_wing/ice_wing
+	crusher_drop_mod = 30
 
 /obj/item/projectile/temp/basilisk/magmawing
 	name = "scorching blast"

code/modules/mob/living/simple_animal/hostile/mining/goliath.dm

@@ -83,6 +83,7 @@
 	icon_dead = "goliath_dead"
 	throw_message = "does nothing to the tough hide of the"
 	pre_attack_icon = "goliath2"
+	crusher_loot = /obj/item/crusher_trophy/goliath_tentacle
 	butcher_results = list(/obj/item/reagent_containers/food/snacks/goliath = 2, /obj/item/stack/sheet/animalhide/goliath_hide = 1, /obj/item/stack/sheet/bone = 2)
 	loot = list()
 	stat_attack = TRUE

code/modules/mob/living/simple_animal/hostile/mining/hivelord.dm

@@ -45,6 +45,9 @@
 /mob/living/simple_animal/hostile/asteroid/hivelord/AttackingTarget()
 	OpenFire()
 
+/mob/living/simple_animal/hostile/asteroid/hivelord/spawn_crusher_loot()
+	loot += crusher_loot //we don't butcher
+
 /mob/living/simple_animal/hostile/asteroid/hivelord/death(gibbed)
 	// Only execute the below if we successfully died
 	. = ..(gibbed)
@@ -231,6 +234,7 @@
 	speak_emote = list("echoes")
 	attack_sound = 'sound/weapons/pierce.ogg'
 	throw_message = "bounces harmlessly off of"
+	crusher_loot = /obj/item/crusher_trophy/legion_skull
 	loot = list(/obj/item/organ/internal/hivelord_core/legion)
 	brood_type = /mob/living/simple_animal/hostile/asteroid/hivelordbrood/legion
 	del_on_death = 1

code/modules/mob/living/simple_animal/hostile/mining/mining.dm

@@ -1,4 +1,4 @@
-/mob/living/simple_animal/hostile/asteroid/
+/mob/living/simple_animal/hostile/asteroid
 	vision_range = 2
 	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
 	unsuitable_atmos_damage = 15
@@ -13,12 +13,18 @@
 	response_harm = "strikes"
 	status_flags = 0
 	a_intent = INTENT_HARM
+	var/crusher_loot
 	var/throw_message = "bounces off of"
 	var/icon_aggro = null // for swapping to when we get aggressive
 	var/fromtendril = FALSE
 	see_in_dark = 8
 	see_invisible = SEE_INVISIBLE_MINIMUM
 	mob_size = MOB_SIZE_LARGE
+	var/crusher_drop_mod = 25
+
+/mob/living/simple_animal/hostile/asteroid/New()
+	..()
+	apply_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
 
 /mob/living/simple_animal/hostile/asteroid/Aggro()
 	..()
@@ -46,3 +52,12 @@
 			visible_message("<span class='notice'>The [T.name] [src.throw_message] [src.name]!</span>")
 			return
 	..()
+
+/mob/living/simple_animal/hostile/asteroid/death(gibbed)
+	var/datum/status_effect/crusher_damage/C = has_status_effect(STATUS_EFFECT_CRUSHERDAMAGETRACKING)
+	if(C && crusher_loot && prob((C.total_damage/maxHealth) * crusher_drop_mod)) //on average, you'll need to kill 4 creatures before getting the item
+		spawn_crusher_loot()
+	..(gibbed)
+
+/mob/living/simple_animal/hostile/asteroid/proc/spawn_crusher_loot()
+	butcher_results[crusher_loot] = 1

code/modules/projectiles/guns/energy/kinetic_accelerator.dm

@@ -474,6 +474,45 @@
 			return
 		new /obj/effect/temp_visual/resonance(target_turf, K.firer, null, 30)
 
+/obj/item/borg/upgrade/modkit/bounty
+	name = "death syphon"
+	desc = "Killing or assisting in killing a creature permanently increases your damage against that type of creature."
+	denied_type = /obj/item/borg/upgrade/modkit/bounty
+	modifier = 1.25
+	cost = 30
+	var/maximum_bounty = 25
+	var/list/bounties_reaped = list()
+
+/obj/item/borg/upgrade/modkit/bounty/projectile_prehit(obj/item/projectile/kinetic/K, atom/target, obj/item/gun/energy/kinetic_accelerator/KA)
+	if(isliving(target))
+		var/mob/living/L = target
+		var/list/existing_marks = L.has_status_effect_list(STATUS_EFFECT_SYPHONMARK)
+		for(var/i in existing_marks)
+			var/datum/status_effect/syphon_mark/SM = i
+			if(SM.reward_target == src) //we want to allow multiple people with bounty modkits to use them, but we need to replace our own marks so we don't multi-reward
+				SM.reward_target = null
+				qdel(SM)
+		L.apply_status_effect(STATUS_EFFECT_SYPHONMARK, src)
+
+/obj/item/borg/upgrade/modkit/bounty/projectile_strike(obj/item/projectile/kinetic/K, turf/target_turf, atom/target, obj/item/gun/energy/kinetic_accelerator/KA)
+	if(isliving(target))
+		var/mob/living/L = target
+		if(bounties_reaped[L.type])
+			var/kill_modifier = 1
+			if(K.pressure_decrease_active)
+				kill_modifier *= K.pressure_decrease
+			var/armor = L.run_armor_check(K.def_zone, K.flag, "", "", K.armour_penetration)
+			L.apply_damage(bounties_reaped[L.type]*kill_modifier, K.damage_type, K.def_zone, armor)
+
+/obj/item/borg/upgrade/modkit/bounty/proc/get_kill(mob/living/L)
+	var/bonus_mod = 1
+	if(ismegafauna(L)) //megafauna reward
+		bonus_mod = 4
+	if(!bounties_reaped[L.type])
+		bounties_reaped[L.type] = min(modifier * bonus_mod, maximum_bounty)
+	else
+		bounties_reaped[L.type] = min(bounties_reaped[L.type] + (modifier * bonus_mod), maximum_bounty)
+
 //Indoors
 /obj/item/borg/upgrade/modkit/indoors
 	name = "decrease pressure penalty"