Merge pull request #1326 from Fox-McCloud/revenants

Revenant

code/modules/mob/living/simple_animal/revenant/revenant.dm

@@ -0,0 +1,315 @@
+//Revenants: based off of wraiths from Goon
+//"Ghosts" that are invisible and move like ghosts, cannot take damage while invsible
+//Don't hear deadchat and are NOT normal ghosts
+//Admin-spawn or random event
+
+/mob/living/simple_animal/revenant
+	name = "revenant"
+	desc = "A malevolent spirit."
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "revenant_idle"
+	incorporeal_move = 3
+	invisibility = INVISIBILITY_OBSERVER
+	health = 25
+	maxHealth = 25
+	see_in_dark = 255
+	see_invisible = SEE_INVISIBLE_OBSERVER
+	universal_understand = 1
+	response_help   = "passes through"
+	response_disarm = "swings at"
+	response_harm   = "punches"
+	minbodytemp = 0
+	maxbodytemp = INFINITY
+	harm_intent_damage = 5
+	speak_emote = list("hisses", "spits", "growls")
+	friendly = "touches"
+	status_flags = 0
+	wander = 0
+	density = 0
+
+	var/essence = 25 //The resource of revenants. Max health is equal to twice this amount
+	var/essence_regen_cap = 25 //The regeneration cap of essence (go figure); regenerates every Life() tick up to this amount.
+	var/essence_regen = 1 //If the revenant regenerates essence or not; 1 for yes, 0 for no
+	var/essence_min = 1 //The minimum amount of essence a revenant can have; by default, it never drops below one
+	var/strikes = 0 //How many times a revenant can die before dying for good
+	var/revealed = 0 //If the revenant can take damage from normal sources.
+	var/inhibited = 0 //If the revenant's abilities are blocked by a chaplain's power.
+
+/mob/living/simple_animal/revenant/Life()
+	..()
+	if(essence < essence_min)
+		essence = essence_min
+		if(strikes > 0)
+			strikes--
+			src << "<span class='boldannounce'>Your essence has dropped below critical levels. You barely manage to save yourself - [strikes ? "you can't keep this up!" : "next time, it's death."]</span>"
+		else if(strikes <= 0)
+			death()
+	maxHealth = essence * 2
+	if(!revealed)
+		health = maxHealth //Heals to full when not revealed
+	if(essence_regen && !inhibited && essence < essence_regen_cap) //While inhibited, essence will not regenerate
+		essence++
+
+/mob/living/simple_animal/revenant/ex_act(severity)
+	return 1 //Immune to the effects of explosions.
+
+/mob/living/simple_animal/revenant/ClickOn(var/atom/A, var/params) //Copypaste from ghost code - revenants can't interact with the world directly.
+	if(client.buildmode)
+		build_click(src, client.buildmode, params, A)
+		return
+
+	var/list/modifiers = params2list(params)
+	if(modifiers["middle"])
+		MiddleClickOn(A)
+		return
+	if(modifiers["shift"])
+		ShiftClickOn(A)
+		return
+	if(modifiers["alt"])
+		AltClickOn(A)
+		return
+	if(modifiers["ctrl"])
+		CtrlClickOn(A)
+		return
+
+	if(world.time <= next_move)
+		return
+	A.attack_ghost(src)
+
+/mob/living/simple_animal/revenant/say(message)
+	return 0 //Revenants cannot speak out loud.
+
+/mob/living/simple_animal/revenant/Stat()
+	..()
+	if(statpanel("Status"))
+		stat(null, "Current essence: [essence]E")
+
+/mob/living/simple_animal/revenant/New()
+	..()
+	spawn(5)
+		if(src.mind)
+			src.mind.wipe_memory()
+			src << 'sound/effects/ghost.ogg'
+			src << "<br>"
+			src << "<span class='deadsay'><font size=3><b>You are a revenant.</b></font></span>"
+			src << "<b>Your formerly mundane spirit has been infused with alien energies and empowered into a revenant.</b>"
+			src << "<b>You are not dead, not alive, but somewhere in between. You are capable of limited interaction with both worlds.</b>"
+			src << "<b>You are invincible and invisible to everyone but other ghosts. Some abilities may change this.</b>"
+			src << "<b>To function, you are to drain the life essence from humans. This essence is a resource and will power all of your abilities.</b>"
+			src << "<b><i>You do not remember anything of your past lives, nor will you remember anything about this one after your death.</i></b>"
+			src << "<b>Be sure to read the wiki page at http://nanotrasen.se/wiki/index.php/Revenant to learn more.</b>"
+			var/datum/objective/revenant/objective = new
+			objective.owner = src
+			src.mind.objectives += objective
+			src << "<b>Objective #1</b>: [objective.explanation_text]"
+			var/datum/objective/revenantFluff/objective2 = new
+			objective2.owner = src
+			src.mind.objectives += objective2
+			src << "<b>Objective #2</b>: [objective2.explanation_text]"
+			ticker.mode.traitors |= src.mind //Necessary for announcing
+		if(!src.giveSpells())
+			message_admins("Revenant was created but has no mind. Trying again in five seconds.")
+			spawn(50)
+				if(!src.giveSpells())
+					message_admins("Revenant still has no mind. Deleting...")
+					qdel(src)
+
+/mob/living/simple_animal/revenant/proc/giveSpells()
+	if(src.mind)
+		src.mind.spell_list += new /obj/effect/proc_holder/spell/wizard/targeted/revenant_harvest
+		src.mind.spell_list += new /obj/effect/proc_holder/spell/wizard/targeted/revenant_transmit
+		src.mind.spell_list += new /obj/effect/proc_holder/spell/wizard/aoe_turf/revenant_light
+		src.mind.spell_list += new /obj/effect/proc_holder/spell/wizard/aoe_turf/revenantDefile
+		return 1
+	return 0
+
+/mob/living/simple_animal/revenant/death()
+	if(strikes)
+		return 0 //Impossible to die with strikes still active
+	..(1)
+	src << "<span class='userdanger'><b>NO! No... it's too late, you can feel yourself fading...</b></span>"
+	notransform = 1
+	revealed = 1
+	invisibility = 0
+	playsound(src, 'sound/effects/screech.ogg', 100, 1)
+	visible_message("<span class='warning'>[src] lets out a waning screech as violet mist swirls around its dissolving body!</span>")
+	icon_state = "revenant_draining"
+	for(var/i = alpha, i > 0, i -= 10)
+		sleep(0.1)
+		alpha = i
+	visible_message("<span class='danger'>[src]'s body breaks apart into blue dust.</span>")
+	new /obj/item/weapon/ectoplasm/revenant(get_turf(src))
+	ghostize()
+	qdel(src)
+	return
+
+
+/mob/living/simple_animal/revenant/attackby(obj/item/W, mob/living/user, params)
+	..()
+	if(istype(W, /obj/item/weapon/nullrod))
+		visible_message("<span class='warning'>[src] violently flinches!</span>", \
+						"<span class='boldannounce'>The null rod invokes agony in you! You feel your essence draining away!</span>")
+		essence -= 25 //hella effective
+		inhibited = 1
+		spawn(30)
+			inhibited = 0
+
+
+
+/mob/living/simple_animal/revenant/proc/castcheck(var/essence_cost)
+	var/mob/living/simple_animal/revenant/user = usr
+	if(!istype(user) || !user)
+		return
+	var/turf/T = get_turf(usr)
+	if(istype(T, /turf/simulated/wall))
+		user << "<span class='warning'>You cannot use abilities from inside of a wall.</span>"
+		return 0
+	if(!user.change_essence_amount(essence_cost, 1))
+		user << "<span class='warning'>You lack the essence to use that ability.</span>"
+		return 0
+	if(user.inhibited)
+		user << "<span class='warning'>Your powers have been suppressed by holy energies!</span>"
+		return 0
+	return 1
+
+
+
+/mob/living/simple_animal/revenant/proc/change_essence_amount(var/essence_amt, var/silent = 0, var/source = null)
+	var/mob/living/simple_animal/revenant/user = usr
+	if(!istype(usr) || !usr)
+		return
+	if(user.essence + essence_amt <= 0)
+		return
+	user.essence += essence_amt
+	user.essence = Clamp(user.essence, 0, INFINITY)
+	if(!silent)
+		if(essence_amt > 0)
+			user << "<span class='notice'>Gained [essence_amt]E from [source].</span>"
+		else
+			user << "<span class='danger'>Lost [essence_amt]E from [source].</span>"
+	return 1
+
+
+
+/mob/living/simple_animal/revenant/proc/reveal(var/time, var/stun)
+	var/mob/living/simple_animal/revenant/R = usr
+	if(!istype(usr) || !usr)
+		return
+	R.revealed = 1
+	R.invisibility = 0
+	if(stun)
+		R.notransform = 1
+	R << "<span class='warning'>You have been revealed [stun ? "and cannot move" : ""].</span>"
+	spawn(time)
+		R.revealed = 0
+		R.invisibility = INVISIBILITY_OBSERVER
+		if(stun)
+			R.notransform = 0
+		R << "<span class='notice'>You are once more concealed [stun ? "and can move again" : ""].</span>"
+
+/datum/objective/revenant
+	var/targetAmount = 100
+
+/datum/objective/revenant/New()
+	targetAmount = rand(100,200)
+	explanation_text = "Absorb [targetAmount] points of essence."
+	..()
+
+/datum/objective/revenant/check_completion()
+	if(!istype(owner.current, /mob/living/simple_animal/revenant) || !owner.current)
+		return 0
+	var/mob/living/simple_animal/revenant/R = owner.current
+	if(!R || R.stat == DEAD)
+		return 0
+	var/essenceAccumulated = R.essence
+	if(essenceAccumulated < targetAmount)
+		return 0
+	return 1
+
+/datum/objective/revenantFluff
+
+/datum/objective/revenantFluff/New()
+	var/list/explanationTexts = list("Attempt to make your presence unknown to the crew.", \
+									 "Collaborate with existing antagonists aboard the station to gain essence.", \
+									 "Remain nonlethal and only absorb bodies that have already died.", \
+									 "Use your environments to eliminate isolated people.", \
+									 "If there is a chaplain aboard the station, ensure they are killed.", \
+									 "Hinder the crew without killing them.")
+	explanation_text = pick(explanationTexts)
+	..()
+
+/datum/objective/revenantFluff/check_completion()
+	return 1
+
+
+/obj/item/weapon/ectoplasm/revenant
+	name = "glimmering residue"
+	desc = "A pile of fine blue dust. Small tendrils of violet mist swirl around it."
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "revenantEctoplasm"
+	w_class = 2
+	var/reforming = 0
+	var/reformed = 0
+
+/obj/item/weapon/ectoplasm/revenant/New()
+	..()
+	reforming = 1
+	spawn(1800) //3 minutes
+		if(src && reforming)
+			return reform()
+		if(src && !reforming)
+			visible_message("<span class='warning'>[src] settles down and seems lifeless.</span>")
+			return
+
+/obj/item/weapon/ectoplasm/revenant/attack_hand(mob/user)
+	if(reformed)
+		user << "<span class='warning'>[src] keeps slipping out of your hands, you can't get a hold on it!</span>"
+		return
+	..()
+
+/obj/item/weapon/ectoplasm/revenant/attack_self(mob/user)
+	if(!reforming)
+		return ..()
+	user.visible_message("<span class='notice'>[user] scatters [src] in all directions.</span>", \
+						 "<span class='notice'>You scatter [src] across the area. The particles slowly fade away.</span>")
+	user.drop_item()
+	qdel(src)
+
+/obj/item/weapon/ectoplasm/revenant/throw_impact(atom/hit_atom)
+	..()
+	visible_message("<span class='notice'>[src] breaks into particles upon impact, which fade away to nothingness.</span>")
+	qdel(src)
+
+/obj/item/weapon/ectoplasm/revenant/examine(mob/user)
+	..()
+	if(reforming)
+		user << "<span class='warning'>It is shifting and distorted. It would be wise to destroy this.</span>"
+	else if(!reforming)
+		user << "<span class='notice'>It seems inert.</span>"
+
+/obj/item/weapon/ectoplasm/revenant/proc/reform()
+	if(!reforming || !src)
+		return
+	message_admins("Revenant ectoplasm was left undestroyed for 3 minutes and has reformed into a new revenant.")
+	loc = get_turf(src) //In case it's in a backpack or someone's hand
+	visible_message("<span class='boldannounce'>[src] suddenly rises into the air before fading away.</span>")
+	var/mob/living/simple_animal/revenant/R = new(get_turf(src))
+	qdel(src)
+	var/list/candidates = get_candidates(BE_REVENANT)
+	if(!candidates.len)
+		message_admins("No candidates were found for the new revenant. Oh well!")
+		return 0
+	var/client/C = pick(candidates)
+	var/key_of_revenant = C.key
+	if(!key_of_revenant)
+		message_admins("No ckey was found for the new revenant. Oh well!")
+		return 0
+	var/datum/mind/player_mind = new /datum/mind(key_of_revenant)
+	player_mind.active = 1
+	player_mind.transfer_to(R)
+	player_mind.assigned_role = "revenant"
+	player_mind.special_role = "Revenant"
+	ticker.mode.traitors |= player_mind
+	message_admins("[key_of_revenant] has been made into a revenant by reforming ectoplasm.")
+	log_game("[key_of_revenant] was spawned as a revenant by reforming ectoplasm.")
+	return 1

code/modules/mob/living/simple_animal/revenant/revenant_abilities.dm

@@ -0,0 +1,188 @@
+//Harvest Essence: The bread and butter of the revenant. The basic way of harvesting additional essence.
+/obj/effect/proc_holder/spell/wizard/targeted/revenant_harvest
+	name = "Harvest (0E)"
+	desc = "Siphons the lingering spectral essence from a human, empowering yourself."
+	panel = "Revenant Abilities"
+	charge_max = 100 //Short cooldown
+	clothes_req = 0
+	range = 5
+	var/essence_drained = 0
+	var/draining
+	var/list/drained_mobs = list() //Cannot harvest the same mob twice
+
+/obj/effect/proc_holder/spell/wizard/targeted/revenant_harvest/cast(list/targets, var/mob/living/simple_animal/revenant/user = usr)
+	if(!user.castcheck(0))
+		charge_counter = charge_max
+		return
+	for(var/mob/living/carbon/human/target in targets)
+		spawn(0)
+			if(draining)
+				user << "<span class='warning'>You are already siphoning the essence of a soul!</span>"
+				return
+			if(target in drained_mobs)
+				user << "<span class='warning'>[target]'s soul is dead and empty.</span>"
+				return
+			if(target.stat != DEAD)
+				user << "<span class='notice'>This being's soul is too strong to harvest.</span>"
+				if(prob(10))
+					target << "You feel as if you are being watched."
+				return
+			draining = 1
+			essence_drained = 1
+			user << "<span class='notice'>You search for the still-living soul of [target].</span>"
+			sleep(10)
+			if(target.ckey)
+				user << "<span class='notice'>Their soul burns with intelligence.</span>"
+				essence_drained += 3
+			sleep(20)
+			switch(essence_drained)
+				if(1 to 2)
+					user << "<span class='info'>[target] will not yield much essence. Still, every bit counts.</span>"
+				if(3 to 4)
+					user << "<span class='info'>[target] will yield an average amount of essence.</span>"
+				if(5 to INFINITY)
+					user << "<span class='info'>Such a feast! [target] will yield much essence to you.</span>"
+			sleep(30)
+			if(!in_range(user, target))
+				user << "<span class='warning'>You are not close enough to siphon [target]'s soul. The link has been broken.</span>"
+				draining = 0
+				return
+			if(!target.stat)
+				user << "<span class='warning'>They are now powerful enough to fight off your draining.</span>"
+				target << "<span class='boldannounce'>You feel something tugging across your body before subsiding.</span>"
+			user << "<span class='danger'>You begin siphoning essence from [target]'s soul. You can not move while this is happening.</span>"
+			if(target.stat != DEAD)
+				target << "<span class='warning'>You feel a horribly unpleasant draining sensation as your grip on life weakens...</span>"
+			user.icon_state = "revenant_draining"
+			user.notransform = 1
+			user.revealed = 1
+			user.invisibility = 0
+			target.visible_message("<span class='warning'>[target] suddenly rises slightly into the air, their skin turning an ashy gray.</span>")
+			target.Beam(user,icon_state="drain_life",icon='icons/effects/effects.dmi',time=80)
+			target.death(0)
+			target.visible_message("<span class='warning'>[target] gently slumps back onto the ground.</span>")
+			user.icon_state = "revenant_idle"
+			user.change_essence_amount(essence_drained * 5, 0, target)
+			user << "<span class='info'>[target]'s soul has been considerably weakened and will yield no more essence for the time being.</span>"
+			user.revealed = 0
+			user.notransform = 0
+			user.invisibility = INVISIBILITY_OBSERVER
+			drained_mobs.Add(target)
+			draining = 0
+
+
+//Transmit: the revemant's only direct way to communicate. Sends a single message silently to a single mob for 5E.
+/obj/effect/proc_holder/spell/wizard/targeted/revenant_transmit
+	name = "Transmit (5E)"
+	desc = "Telepathically transmits a message to the target."
+	panel = "Revenant Abilities (Locked)"
+	charge_max = 50
+	clothes_req = 0
+	range = -1
+	include_user = 1
+	var/locked = 1
+
+/obj/effect/proc_holder/spell/wizard/targeted/revenant_transmit/cast(list/targets, var/mob/living/simple_animal/revenant/user = usr)
+	if(!user.castcheck(-5))
+		charge_counter = charge_max
+		return
+	if(locked)
+		usr << "<span class='info'>You have unlocked Transmit!</span>"
+		locked = 0
+		charge_counter = charge_max
+		panel = "Revenant Abilities"
+		range = 7
+		include_user = 0
+		return
+	for(var/mob/living/M in targets)
+		spawn(0)
+			var/msg = stripped_input(usr, "What do you wish to tell [M]?", null, "")
+			if(!msg)
+				charge_counter = charge_max
+				return
+			usr << "<span class='info'><b>You transmit to [M]:</b> [msg]</span>"
+			M << "<span class='deadsay'><b>A strange voice resonates in your head...</b></span><i> [msg]</I>"
+
+
+//Overload Light: Breaks a light that's online and sends out lightning bolts to all nearby people.
+/obj/effect/proc_holder/spell/wizard/aoe_turf/revenant_light
+	name = "Overload Light (25E)"
+	desc = "Directs a large amount of essence into an electrical light, causing an impressive light show."
+	panel = "Revenant Abilities (Locked)"
+	charge_max = 300
+	clothes_req = 0
+	range = 1
+	var/locked = 1
+
+/obj/effect/proc_holder/spell/wizard/aoe_turf/revenant_light/cast(list/targets, var/mob/living/simple_animal/revenant/user = usr)
+	if(!user.castcheck(-25))
+		charge_counter = charge_max
+		return
+	if(locked)
+		user << "<span class='info'>You have unlocked Overload Light!</span>"
+		panel = "Revenant Abilities"
+		locked = 0
+		range = 5
+		charge_counter = charge_max
+		return
+	for(var/turf/T in targets)
+		spawn(0)
+			for(var/obj/machinery/light/L in T.contents)
+				spawn(0)
+					if(!L.on)
+						return
+					L.visible_message("<span class='warning'><b>\The [L] suddenly flares brightly and begins to spark!</span>")
+					sleep(20)
+					for(var/mob/living/M in orange(4, L))
+						if(M == user)
+							return
+						M.Beam(L,icon_state="lightning",icon='icons/effects/effects.dmi',time=5)
+						M.electrocute_act(25, "[L.name]")
+						playsound(M, 'sound/machines/defib_zap.ogg', 50, 1, -1)
+	user.reveal(50, 1)
+
+
+//Defile: Corrupts nearby stuff, unblesses floor tiles.
+/obj/effect/proc_holder/spell/wizard/aoe_turf/revenantDefile
+	name = "Defile (30E)"
+	desc = "Twists and corrupts certain nearby objects. Also dispels holy auras on floors, but not salt lines."
+	panel = "Revenant Abilities (Locked)"
+	charge_max = 300
+	clothes_req = 0
+	range = 1
+	var/locked = 1
+
+/obj/effect/proc_holder/spell/wizard/aoe_turf/revenantDefile/cast(list/targets, var/mob/living/simple_animal/revenant/user = usr)
+	if(!user.castcheck(-30))
+		charge_counter = charge_max
+		return
+	if(locked)
+		user << "<span class='info'>You have unlocked Defile!</span>"
+		panel = "Revenant Abilities"
+		locked = 0
+		range = 4
+		charge_counter = charge_max
+		return
+	for(var/turf/T in targets)
+		spawn(0)
+			if(T.flags & NOJAUNT)
+				T.flags -= NOJAUNT
+			for(var/obj/machinery/bot/secbot/secbot in T.contents) //Not including ED-209
+				secbot.emagged = 2
+				secbot.Emag(null)
+			for(var/obj/machinery/bot/cleanbot/cleanbot in T.contents)
+				cleanbot.emagged = 2
+				cleanbot.Emag(null)
+			for(var/mob/living/carbon/human/human in T.contents)
+				human << "<span class='warning'>You suddenly feel tired.</span>"
+				human.adjustStaminaLoss(25)
+			for(var/mob/living/silicon/robot/robot in T.contents)
+				robot.visible_message("<span class='warning'>[robot] lets out an alarm!</span>", \
+									  "<span class='boldannounce'>01001111 01010110 01000101 01010010 01001100 01001111 01000001 01000100</span>") //Translates to "OVERLOAD"
+				robot << 'sound/misc/interference.ogg'
+				playsound(robot, 'sound/machines/warning-buzzer.ogg', 50, 1)
+			for(var/obj/structure/window/window in T.contents)
+				window.hit(rand(10,50))
+			for(var/obj/machinery/light/light in T.contents)
+				light.flicker() //spooky
+	user.reveal(30, 1)

code/modules/mob/living/simple_animal/revenant/revenant_spawn_event.dm

@@ -0,0 +1,67 @@
+#define REVENANT_SPAWN_THRESHOLD 10
+
+/datum/event/revenant
+	var/key_of_revenant
+
+
+/datum/event/revenant/proc/get_revenant(var/end_if_fail = 0)
+	var/deadMobs = 0
+	for(var/mob/M in dead_mob_list)
+		deadMobs++
+	if(deadMobs < REVENANT_SPAWN_THRESHOLD)
+		message_admins("Random event attempted to spawn a revenant, but there were only [deadMobs]/[REVENANT_SPAWN_THRESHOLD] dead mobs.")
+		return
+	key_of_revenant = null
+	if(!key_of_revenant)
+		var/list/candidates = get_candidates(BE_REVENANT)
+		if(!candidates.len)
+			if(end_if_fail)
+				return 0
+			return find_revenant()
+		var/client/C = pick(candidates)
+		key_of_revenant = C.key
+	if(!key_of_revenant)
+		if(end_if_fail)
+			return 0
+		return find_revenant()
+	var/datum/mind/player_mind = new /datum/mind(key_of_revenant)
+	player_mind.active = 1
+	var/list/spawn_locs = list()
+	for(var/obj/effect/landmark/L in landmarks_list)
+		if(isturf(L.loc))
+			switch(L.name)
+				if("revenantspawn")
+					spawn_locs += L.loc
+	if(!spawn_locs) //If we can't find any revenant spawns, try the carp spawns
+		for(var/obj/effect/landmark/L in landmarks_list)
+			if(isturf(L.loc))
+				switch(L.name)
+					if("carpspawn")
+						spawn_locs += L.loc
+	if(!spawn_locs) //If we can't find either, just spawn the revenant at the player's location
+		spawn_locs += get_turf(player_mind.current)
+	if(!spawn_locs) //If we can't find THAT, then just retry
+		return find_revenant()
+	var/mob/living/simple_animal/revenant/revvie = new /mob/living/simple_animal/revenant/(pick(spawn_locs))
+	player_mind.transfer_to(revvie)
+	player_mind.assigned_role = "revenant"
+	player_mind.special_role = "Revenant"
+	ticker.mode.traitors |= player_mind
+	message_admins("[key_of_revenant] has been made into a revenant by an event.")
+	log_game("[key_of_revenant] was spawned as a revenant by an event.")
+	return 1
+
+
+/datum/event/revenant/start()
+	get_revenant()
+
+
+/datum/event/revenant/proc/find_revenant()
+	message_admins("An event failed to spawn a revenant. Retrying momentarily...")
+	spawn(50)
+		if(get_revenant(1))
+			message_admins("[key_of_revenant] has been spawned as a revenant.")
+			log_game("[key_of_revenant] was spawned as a revenant by an event.")
+			return 0
+		message_admins("No candidates were available for becoming a revenant.")
+	return kill()

code/modules/mob/mob_movement.dm

@@ -440,6 +440,16 @@
 					anim(mobloc,mob,'icons/mob/mob.dmi',,"shadow",,L.dir)
 				L.loc = get_step(L, direct)
 			L.dir = direct
+		if(3) //Incorporeal move, but blocked by holy-watered tiles
+			var/turf/simulated/floor/stepTurf = get_step(L, direct)
+			if(stepTurf.flags & NOJAUNT)
+				L << "<span class='warning'>Holy energies block your path.</span>"
+				L.notransform = 1
+				spawn(2)
+					L.notransform = 0
+			else
+				L.loc = get_step(L, direct)
+				L.dir = direct
 	return 1