Updates maploader code to be in line with tg's, startup improvements

code/modules/admin/admin_verbs.dm

@@ -151,7 +151,9 @@ var/list/admin_verbs_debug = list(
 	/client/proc/test_movable_UI,
 	/client/proc/test_snap_UI,
 	/client/proc/cinematic,
-	/proc/machine_upgrade
+	/proc/machine_upgrade,
+	/client/proc/map_template_load,
+	/client/proc/map_template_upload
 	)
 var/list/admin_verbs_possess = list(
 	/proc/possess,

code/modules/admin/verbs/map_template_loadverb.dm

@@ -0,0 +1,45 @@
+/client/proc/map_template_load()
+	set category = "Debug"
+	set name = "Map Template - Place"
+
+	if(!holder)
+		return
+
+	var/datum/map_template/template
+
+	var/map = input(usr, "Choose a Map Template to place at your CURRENT LOCATION","Place Map Template") as null|anything in map_templates
+	if(!map)
+		return
+	template = map_templates[map]
+
+	var/turf/T = get_turf(mob)
+	if(!T)
+		return
+
+	var/list/preview = list()
+	for(var/S in template.get_affected_turfs(T,centered = TRUE))
+		preview += image('icons/turf/overlays.dmi',S,"greenOverlay")
+	usr.client.images += preview
+	if(alert(usr,"Confirm location.","Template Confirm","Yes","No") == "Yes")
+		template.load(T, centered = TRUE)
+		message_admins("[key_name_admin(usr)] has placed a map template ([template.name]) at <A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[T.x];Y=[T.y];Z=[T.z]'>(JMP)</A>")
+	usr.client.images -= preview
+
+/client/proc/map_template_upload()
+	set category = "Debug"
+	set name = "Map Template - Upload"
+
+	if(!holder)
+		return
+
+	var/map = input(usr, "Choose a Map Template to upload to template storage","Upload Map Template") as null|file
+	if(!map)
+		return
+	if(copytext("[map]",-4) != ".dmm")
+		usr << "Bad map file: [map]"
+		return
+
+	var/datum/map_template/M = new(map=map, rename="[map]")
+	M.preload_size(map)
+	map_templates[M.name] = M
+	message_admins("[key_name_admin(usr)] has uploaded a map template ([map])")