Update NanoUI to be up-to-date with Bay

code/modules/nano/interaction/admin.dm

@@ -0,0 +1,7 @@
+/*
+	This state checks that the user is an admin, end of story
+*/
+/var/global/datum/topic_state/admin_state/admin_state = new()
+
+/datum/topic_state/admin_state/can_use_topic(var/src_object, var/mob/user)
+	return check_rights(R_ADMIN, 0, user) ? STATUS_INTERACTIVE : STATUS_CLOSE

code/modules/nano/interaction/base.dm

@@ -0,0 +1,19 @@
+/datum/proc/nano_host()
+	return src
+
+/datum/proc/CanUseTopic(var/mob/user, var/datum/topic_state/state)
+	var/src_object = nano_host()
+	return state.can_use_topic(src_object, user)
+
+/datum/topic_state/proc/href_list(var/mob/user)
+	return list()
+
+/datum/topic_state/proc/can_use_topic(var/src_object, var/mob/user)
+	return STATUS_CLOSE
+
+/mob/proc/shared_nano_interaction()
+	if (src.stat || !client)
+		return STATUS_CLOSE						// no updates, close the interface
+	else if (restrained() || lying || stat || stunned || weakened)
+		return STATUS_UPDATE					// update only (orange visibility)
+	return STATUS_INTERACTIVE

code/modules/nano/interaction/contained.dm

@@ -0,0 +1,18 @@
+/*
+	This state checks if user is somewhere within src_object, as well as the default NanoUI interaction.
+*/
+/var/global/datum/topic_state/contained_state/contained_state = new()
+
+/datum/topic_state/contained_state/can_use_topic(var/atom/src_object, var/mob/user)
+	if(!src_object.contains(user))
+		return STATUS_CLOSE
+
+	return user.shared_nano_interaction()
+
+/atom/proc/contains(var/atom/location)
+	if(!location)
+		return 0
+	if(location == src)
+		return 1
+
+	return contains(location.loc)

code/modules/nano/interaction/default.dm

@@ -0,0 +1,101 @@
+/var/global/datum/topic_state/default/default_state = new()
+
+/datum/topic_state/default/href_list(var/mob/user)
+	return list()
+
+/datum/topic_state/default/can_use_topic(var/src_object, var/mob/user)
+	return user.default_can_use_topic(src_object)
+
+/mob/proc/default_can_use_topic(var/src_object)
+	return STATUS_CLOSE // By default no mob can do anything with NanoUI
+
+/mob/dead/observer/default_can_use_topic()
+	if(check_rights(R_ADMIN, 0, src))
+		return STATUS_INTERACTIVE				// Admins are more equal
+	return STATUS_UPDATE						// Ghosts can view updates
+
+/mob/living/silicon/pai/default_can_use_topic(var/src_object)
+	if(src_object == src && !stat)
+		return STATUS_INTERACTIVE
+	else
+		return ..()
+
+/mob/living/silicon/robot/default_can_use_topic(var/src_object)
+	if(stat || !client)
+		return STATUS_CLOSE
+	if(lockcharge || stunned || weakened)
+		return STATUS_DISABLED
+	// robots can interact with things they can see within their view range
+	if((src_object in view(src)) && get_dist(src_object, src) <= src.client.view)
+		return STATUS_INTERACTIVE	// interactive (green visibility)
+	return STATUS_DISABLED			// no updates, completely disabled (red visibility)
+
+/mob/living/silicon/robot/syndicate/default_can_use_topic(var/src_object)
+	. = ..()
+	if(. != STATUS_INTERACTIVE)
+		return
+
+	if(z in config.admin_levels)						// Syndicate borgs can interact with everything on the admin level
+		return STATUS_INTERACTIVE
+	if(istype(get_area(src), /area/syndicate_station))	// If elsewhere, they can interact with everything on the syndicate shuttle
+		return STATUS_INTERACTIVE
+	if(istype(src_object, /obj/machinery))				// Otherwise they can only interact with emagged machinery
+		var/obj/machinery/Machine = src_object
+		if(Machine.emagged)
+			return STATUS_INTERACTIVE
+	return STATUS_UPDATE
+
+/mob/living/silicon/ai/default_can_use_topic(var/src_object)
+	if(!client || check_unable(1))
+		return STATUS_CLOSE
+	// Prevents the AI from using Topic on admin levels (by for example viewing through the court/thunderdome cameras)
+	// unless it's on the same level as the object it's interacting with.
+	var/turf/T = get_turf(src_object)
+	if(!T || !(z == T.z || (T.z in config.player_levels)))
+		return STATUS_CLOSE
+
+	// If an object is in view then we can interact with it
+	if(src_object in view(client.view, src))
+		return STATUS_INTERACTIVE
+
+	// If we're installed in a chassi, rather than transfered to an inteliCard or other container, then check if we have camera view
+	if(is_in_chassis())
+		//stop AIs from leaving windows open and using then after they lose vision
+		//apc_override is needed here because AIs use their own APC when powerless
+		if(cameranet && !cameranet.checkTurfVis(get_turf(src_object)))
+			return apc_override ? STATUS_INTERACTIVE : STATUS_CLOSE
+		return STATUS_INTERACTIVE
+
+	return STATUS_CLOSE
+
+//Some atoms such as vehicles might have special rules for how mobs inside them interact with NanoUI.
+/atom/proc/contents_nano_distance(var/src_object, var/mob/living/user)
+	return user.shared_living_nano_distance(src_object)
+
+/mob/living/proc/shared_living_nano_distance(var/atom/movable/src_object)
+	if (!(src_object in view(4, src))) 	// If the src object is not in visable, disable updates
+		return STATUS_CLOSE
+
+	var/dist = get_dist(src_object, src)
+	if (dist <= 1)
+		return STATUS_INTERACTIVE	// interactive (green visibility)
+	else if (dist <= 2)
+		return STATUS_UPDATE 		// update only (orange visibility)
+	else if (dist <= 4)
+		return STATUS_DISABLED 		// no updates, completely disabled (red visibility)
+	return STATUS_CLOSE
+
+/mob/living/default_can_use_topic(var/src_object)
+	. = shared_nano_interaction(src_object)
+	if(. == STATUS_INTERACTIVE)
+		if(loc)
+			. = loc.contents_nano_distance(src_object, src)
+	if(STATUS_INTERACTIVE)
+		return STATUS_UPDATE
+
+/mob/living/carbon/human/default_can_use_topic(var/src_object)
+	. = shared_nano_interaction(src_object)
+	if(. == STATUS_INTERACTIVE)
+		. = shared_living_nano_distance(src_object)
+		if(. == STATUS_UPDATE && (TK in mutations))	// If we have telekinesis and remain close enough, allow interaction.
+			return STATUS_INTERACTIVE

code/modules/nano/interaction/inventory.dm

@@ -0,0 +1,10 @@
+/*
+	This state checks that the src_object is somewhere in the user's first-level inventory (in hands, on ear, etc.), but not further down (such as in bags).
+*/
+/var/global/datum/topic_state/inventory_state/inventory_state = new()
+
+/datum/topic_state/inventory_state/can_use_topic(var/src_object, var/mob/user)
+	if(!(src_object in user))
+		return STATUS_CLOSE
+
+	return user.shared_nano_interaction()

code/modules/nano/interaction/zlevel.dm

@@ -0,0 +1,13 @@
+/*
+	This state checks that the user is on the same Z-level as src_object
+*/
+
+/var/global/datum/topic_state/z_state/z_state = new()
+
+/datum/topic_state/z_state/can_use_topic(var/src_object, var/mob/user)
+	var/turf/turf_obj = get_turf(src_object)
+	var/turf/turf_usr = get_turf(user)
+	if(!turf_obj || !turf_usr)
+		return STATUS_CLOSE
+
+	return turf_obj.z == turf_usr.z ? STATUS_INTERACTIVE : STATUS_CLOSE