Crit Rework Final Submission

2026-07-18 02:24:11 +01:00 · 2019-03-28 17:28:00 -04:00
parent 290e9135d0
commit d0ea5ee8b9
87 changed files with 797 additions and 480 deletions
@@ -0,0 +1,91 @@
+/obj/item/handheld_defibrillator
+	name = "handheld defibrillator"
+	desc = "Used to restart stopped hearts."
+	icon = 'icons/goonstation/objects/objects.dmi'
+	lefthand_file = 'icons/goonstation/mob/inhands/items_lefthand.dmi'
+	righthand_file = 'icons/goonstation/mob/inhands/items_righthand.dmi'
+	icon_state = "defib-on"
+	item_state = "defib"
+
+	var/icon_base = "defib"
+	var/cooldown = FALSE
+	var/charge_time = 100
+	var/emagged = FALSE
+
+/obj/item/handheld_defibrillator/emag_act(mob/user)
+	if(!emagged)
+		emagged = TRUE
+		desc += " The screen only shows the word KILL flashing over and over."
+		if(user)
+			to_chat(user, "<span class='warning'>you short out the safeties on [src]</span>")
+	else
+		emagged = FALSE
+		desc = "Used to restart stopped hearts."
+		if(user)
+			to_chat(user, "<span class='warning'>You restore the safeties on [src]</span>")
+
+/obj/item/handheld_defibrillator/emp_act(severity)
+	if(emagged)
+		emagged = FALSE
+		desc = "Used to restart stopped hearts."
+		visible_message("<span class='notice'>[src] beeps: Safety protocols enabled!</span>")
+		playsound(get_turf(src), 'sound/machines/defib_saftyon.ogg', 50, 0)
+	else
+		emagged = TRUE
+		desc += " The screen only shows the word KILL flashing over and over."
+		visible_message("<span class='notice'>[src] beeps: Safety protocols disabled!</span>")
+		playsound(get_turf(src), 'sound/machines/defib_saftyoff.ogg', 50, 0)
+
+/obj/item/handheld_defibrillator/attack(mob/living/carbon/human/H, mob/user)
+	if(!istype(H))
+		return ..()
+
+	if(cooldown)
+		to_chat(user, "<span class='warning'>[src] is still charging!</span>")
+		return
+
+	if(emagged || (H.health <= HEALTH_THRESHOLD_CRIT) || (H.undergoing_cardiac_arrest()))
+		user.visible_message("<span class='notice'>[user] shocks [H] with [src].</span>", "<span class='notice'>You shock [H] with [src].</span>")
+		add_attack_logs(user, H, "defibrillated with [src]")
+		playsound(user.loc, "sound/weapons/Egloves.ogg", 75, 1)
+
+		if(H.stat == DEAD)
+			to_chat(user, "<span class='danger'>[H] doesn't respond at all!</span>")
+		else
+			H.set_heartattack(FALSE)
+			var/total_damage = H.getBruteLoss() + H.getFireLoss() + H.getToxLoss()
+			if(H.health <= HEALTH_THRESHOLD_CRIT)
+				if(total_damage >= 90)
+					to_chat(user, "<span class='danger'>[H] looks horribly injured. Resuscitation alone may not help revive them.</span>")
+				if(prob(66))
+					to_chat(user, "<span class='notice'>[H] inhales deeply!</span>")
+					H.adjustOxyLoss(-50)
+				else
+					to_chat(user, "<span class='danger'>[H] doesn't respond!</span>")
+
+			H.AdjustParalysis(3)
+			H.AdjustStunned(5)
+			H.AdjustWeakened(5)
+			H.AdjustStuttering(10)
+			to_chat(H, "<span class='danger'>You feel a powerful jolt!</span>")
+			H.shock_internal_organs(100)
+
+			if(emagged && prob(10))
+				to_chat(user, "<span class='danger'>[src]'s on board scanner indicates that the target is undergoing a cardiac arrest!</span>")
+				H.set_heartattack(TRUE)
+
+		cooldown = TRUE
+		icon_state = "[icon_base]-shock"
+		addtimer(CALLBACK(src, .proc/short_charge), 10)
+		addtimer(CALLBACK(src, .proc/recharge), charge_time)
+
+	else
+		to_chat(user, "<span class='notice'>[src]'s on board medical scanner indicates that no shock is required.</span>")
+
+/obj/item/handheld_defibrillator/proc/short_charge()
+	icon_state = "[icon_base]-off"
+
+/obj/item/handheld_defibrillator/proc/recharge()
+	cooldown = FALSE
+	icon_state = "[icon_base]-on"
+	playsound(loc, "sound/weapons/flash.ogg", 75, 1)
@@ -125,8 +125,8 @@ REAGENT SCANNER
 	var/mode = 1;


-/obj/item/healthanalyzer/attack(mob/living/M as mob, mob/living/user as mob)
-	if(( (CLUMSY in user.mutations) || user.getBrainLoss() >= 60) && prob(50))
+/obj/item/healthanalyzer/attack(mob/living/M, mob/living/user)
+	if(((CLUMSY in user.mutations) || user.getBrainLoss() >= 60) && prob(50))
 		to_chat(user, text("<span class='warning'>You try to analyze the floor's vitals!</span>"))
 		for(var/mob/O in viewers(M, null))
 			O.show_message(text("<span class='warning'>[user] has analyzed the floor's vitals!</span>"), 1)
@@ -137,7 +137,7 @@ REAGENT SCANNER
 		return
 	user.visible_message("<span class='notice'>[user] has analyzed [M]'s vitals.</span>","<span class='notice'> You have analyzed [M]'s vitals.</span>")

-	if(!istype(M,/mob/living/carbon/human) || M.isSynthetic())
+	if(!ishuman(M) || M.isSynthetic())
 		//these sensors are designed for organic life
 		user.show_message("<span class='notice'>Analyzing Results for ERROR:\n\t Overall Status: ERROR</span>")
 		user.show_message("\t Key: <font color='blue'>Suffocation</font>/<font color='green'>Toxin</font>/<font color='#FFA500'>Burns</font>/<font color='red'>Brute</font>", 1)
@@ -147,122 +147,132 @@ REAGENT SCANNER
 		user.show_message("<span class='notice'>Subject's pulse: <font color='red'>-- bpm.</font></span>")
 		return

-	var/fake_oxy = max(rand(1,40), M.getOxyLoss(), (300 - (M.getToxLoss() + M.getFireLoss() + M.getBruteLoss())))
-	var/OX = M.getOxyLoss() > 50 	? 	"<b>[M.getOxyLoss()]</b>" 		: M.getOxyLoss()
-	var/TX = M.getToxLoss() > 50 	? 	"<b>[M.getToxLoss()]</b>" 		: M.getToxLoss()
-	var/BU = M.getFireLoss() > 50 	? 	"<b>[M.getFireLoss()]</b>" 		: M.getFireLoss()
-	var/BR = M.getBruteLoss() > 50 	? 	"<b>[M.getBruteLoss()]</b>" 	: M.getBruteLoss()
-	if(M.status_flags & FAKEDEATH)
+	var/mob/living/carbon/human/H = M
+	var/fake_oxy = max(rand(1,40), H.getOxyLoss(), (300 - (H.getToxLoss() + H.getFireLoss() + H.getBruteLoss())))
+	var/OX = H.getOxyLoss() > 50 	? 	"<b>[H.getOxyLoss()]</b>" 		: H.getOxyLoss()
+	var/TX = H.getToxLoss() > 50 	? 	"<b>[H.getToxLoss()]</b>" 		: H.getToxLoss()
+	var/BU = H.getFireLoss() > 50 	? 	"<b>[H.getFireLoss()]</b>" 		: H.getFireLoss()
+	var/BR = H.getBruteLoss() > 50 	? 	"<b>[H.getBruteLoss()]</b>" 	: H.getBruteLoss()
+	if(H.status_flags & FAKEDEATH)
 		OX = fake_oxy > 50 			? 	"<b>[fake_oxy]</b>" 			: fake_oxy
-		user.show_message("<span class='notice'>Analyzing Results for [M]:\n\t Overall Status: dead</span>")
+		user.show_message("<span class='notice'>Analyzing Results for [H]:\n\t Overall Status: dead</span>")
 	else
-		user.show_message("<span class='notice'>Analyzing Results for [M]:\n\t Overall Status: [M.stat > 1 ? "dead" : "[M.health]% healthy"]</span>")
+		user.show_message("<span class='notice'>Analyzing Results for [H]:\n\t Overall Status: [H.stat > 1 ? "dead" : "[H.health]% healthy"]</span>")
 	user.show_message("\t Key: <font color='blue'>Suffocation</font>/<font color='green'>Toxin</font>/<font color='#FFA500'>Burns</font>/<font color='red'>Brute</font>", 1)
 	user.show_message("\t Damage Specifics: <font color='blue'>[OX]</font> - <font color='green'>[TX]</font> - <font color='#FFA500'>[BU]</font> - <font color='red'>[BR]</font>")
-	user.show_message("<span class='notice'>Body Temperature: [M.bodytemperature-T0C]&deg;C ([M.bodytemperature*1.8-459.67]&deg;F)</span>", 1)
-	if(M.timeofdeath && (M.stat == DEAD || (M.status_flags & FAKEDEATH)))
-		user.show_message("<span class='notice'>Time of Death: [station_time_timestamp("hh:mm:ss", M.timeofdeath)]</span>")
-		var/tdelta = round(world.time - M.timeofdeath)
+	user.show_message("<span class='notice'>Body Temperature: [H.bodytemperature-T0C]&deg;C ([H.bodytemperature*1.8-459.67]&deg;F)</span>", 1)
+	if(H.timeofdeath && (H.stat == DEAD || (H.status_flags & FAKEDEATH)))
+		user.show_message("<span class='notice'>Time of Death: [station_time_timestamp("hh:mm:ss", H.timeofdeath)]</span>")
+		var/tdelta = round(world.time - H.timeofdeath)
 		if(tdelta < (DEFIB_TIME_LIMIT * 10))
 			user.show_message("<span class='danger'>Subject died [DisplayTimeText(tdelta)] ago, defibrillation may be possible!</span>")

-	if(istype(M, /mob/living/carbon/human) && mode == 1)
-		var/mob/living/carbon/human/H = M
+	if(mode == 1)
 		var/list/damaged = H.get_damaged_organs(1,1)
 		user.show_message("<span class='notice'>Localized Damage, Brute/Burn:</span>",1)
 		if(length(damaged) > 0)
 			for(var/obj/item/organ/external/org in damaged)
 				user.show_message("\t\t<span class='info'>[capitalize(org.name)]: [(org.brute_dam > 0) ? "<font color='red'>[org.brute_dam]</font></span>" : "<font color='red'>0</font>"]-[(org.burn_dam > 0) ? "<font color='#FF8000'>[org.burn_dam]</font>" : "<font color='#FF8000'>0</font>"]")

-	OX = M.getOxyLoss() > 50 ? 	"<font color='blue'><b>Severe oxygen deprivation detected</b></font>" 		: 	"Subject bloodstream oxygen level normal"
-	TX = M.getToxLoss() > 50 ? 	"<font color='green'><b>Dangerous amount of toxins detected</b></font>" 	: 	"Subject bloodstream toxin level minimal"
-	BU = M.getFireLoss() > 50 ? 	"<font color='#FFA500'><b>Severe burn damage detected</b></font>" 			:	"Subject burn injury status O.K"
-	BR = M.getBruteLoss() > 50 ? "<font color='red'><b>Severe anatomical damage detected</b></font>" 		: 	"Subject brute-force injury status O.K"
-	if(M.status_flags & FAKEDEATH)
+	OX = H.getOxyLoss() > 50 ? 	"<font color='blue'><b>Severe oxygen deprivation detected</b></font>" 		: 	"Subject bloodstream oxygen level normal"
+	TX = H.getToxLoss() > 50 ? 	"<font color='green'><b>Dangerous amount of toxins detected</b></font>" 	: 	"Subject bloodstream toxin level minimal"
+	BU = H.getFireLoss() > 50 ? 	"<font color='#FFA500'><b>Severe burn damage detected</b></font>" 			:	"Subject burn injury status O.K"
+	BR = H.getBruteLoss() > 50 ? "<font color='red'><b>Severe anatomical damage detected</b></font>" 		: 	"Subject brute-force injury status O.K"
+	if(H.status_flags & FAKEDEATH)
 		OX = fake_oxy > 50 ? 		"<span class='danger'>Severe oxygen deprivation detected</span>" 	: 	"<span class='notice'>Subject bloodstream oxygen level normal</span>"
 	user.show_message("[OX] | [TX] | [BU] | [BR]")
-	if(istype(M, /mob/living/carbon))
-		if(upgraded)
-			chemscan(user, M)
-		for(var/thing in M.viruses)
-			var/datum/disease/D = thing
-			if(!(D.visibility_flags & HIDDEN_SCANNER))
-				user.show_message("<span class='alert'><b>Warning: [D.form] detected</b>\nName: [D.name].\nType: [D.spread_text].\nStage: [D.stage]/[D.max_stages].\nPossible Cure: [D.cure_text]</span>")
-	if(M.getStaminaLoss())
+
+	if(upgraded)
+		chemscan(user, H)
+	for(var/thing in H.viruses)
+		var/datum/disease/D = thing
+		if(!(D.visibility_flags & HIDDEN_SCANNER))
+			user.show_message("<span class='alert'><b>Warning: [D.form] detected</b>\nName: [D.name].\nType: [D.spread_text].\nStage: [D.stage]/[D.max_stages].\nPossible Cure: [D.cure_text]</span>")
+	if(H.undergoing_cardiac_arrest())
+		var/obj/item/organ/internal/heart/heart = H.get_int_organ(/obj/item/organ/internal/heart)
+		if(heart && !(heart.status & ORGAN_DEAD))
+			user.show_message("<span class='alert'><b>Warning: Medical Emergency detected</b>\nName: Cardiac Arrest.\nType: The patient's heart has stopped.\nStage: 1/1.\nPossible Cure: Electric Shock</span>")
+		else if(heart && (heart.status & ORGAN_DEAD))
+			user.show_message("<span class='alert'><b>Subject's heart is necrotic.</b></span>")
+		else if(!heart)
+			user.show_message("<span class='alert'><b>Subject has no heart.</b></span>")
+
+	if(H.getStaminaLoss())
 		user.show_message("<span class='info'>Subject appears to be suffering from fatigue.</span>")
-	if(M.getCloneLoss())
-		user.show_message("<span class='warning'>Subject appears to have [M.getCloneLoss() > 30 ? "severe" : "minor"] cellular damage.</span>")
-	if(M.has_brain_worms())
+	if(H.getCloneLoss())
+		user.show_message("<span class='warning'>Subject appears to have [H.getCloneLoss() > 30 ? "severe" : "minor"] cellular damage.</span>")
+	if(H.has_brain_worms())
 		user.show_message("<span class='warning'>Subject suffering from aberrant brain activity. Recommend further scanning.</span>")
-	else if(M.getBrainLoss() >= 100 || istype(M, /mob/living/carbon/human) && !M.get_int_organ(/obj/item/organ/internal/brain))
-		user.show_message("<span class='warning'>Subject is brain dead.</span>")
-	else if(M.getBrainLoss() >= 60)
-		user.show_message("<span class='warning'>Severe brain damage detected. Subject likely to have mental retardation.</span>")
-	else if(M.getBrainLoss() >= 10)
-		user.show_message("<span class='warning'>Significant brain damage detected. Subject may have had a concussion.</span>")
-	if(ishuman(M))
-		var/mob/living/carbon/human/H = M
-		for(var/name in H.bodyparts_by_name)
-			var/obj/item/organ/external/e = H.bodyparts_by_name[name]
-			if(!e)
-				continue
-			var/limb = e.name
-			if(e.status & ORGAN_BROKEN)
-				if((e.limb_name in list("l_arm", "r_arm", "l_hand", "r_hand", "l_leg", "r_leg", "l_foot", "r_foot")) && !(e.status & ORGAN_SPLINTED))
-					user.show_message("<span class='warning'>Unsecured fracture in subject [limb]. Splinting recommended for transport.</span>")
-			if(e.has_infected_wound())
-				user.show_message("<span class='warning'>Infected wound detected in subject [limb]. Disinfection recommended.</span>")

-		for(var/name in H.bodyparts_by_name)
-			var/obj/item/organ/external/e = H.bodyparts_by_name[name]
-			if(!e)
-				continue
-			if(e.status & ORGAN_BROKEN)
-				user.show_message(text("<span class='warning'>Bone fractures detected. Advanced scanner required for location.</span>"), 1)
-				break
-		for(var/obj/item/organ/external/e in H.bodyparts)
-			if(e.internal_bleeding)
-				user.show_message(text("<span class='warning'>Internal bleeding detected. Advanced scanner required for location.</span>"), 1)
-				break
-		var/blood_id = H.get_blood_id()
-		if(blood_id)
-			if(H.bleed_rate)
-				user.show_message("<span class='danger'>Subject is bleeding!</span>")
-			var/blood_percent =  round((H.blood_volume / BLOOD_VOLUME_NORMAL)*100)
-			var/blood_type = H.b_type
-			if(blood_id != "blood")//special blood substance
-				var/datum/reagent/R = GLOB.chemical_reagents_list[blood_id]
-				if(R)
-					blood_type = R.name
-				else
-					blood_type = blood_id
-			if(H.blood_volume <= BLOOD_VOLUME_SAFE && H.blood_volume > BLOOD_VOLUME_OKAY)
-				user.show_message("<span class='danger'>LOW blood level [blood_percent] %, [H.blood_volume] cl,</span> <span class='info'>type: [blood_type]</span>")
-			else if(H.blood_volume <= BLOOD_VOLUME_OKAY)
-				user.show_message("<span class='danger'>CRITICAL blood level [blood_percent] %, [H.blood_volume] cl,</span> <span class='info'>type: [blood_type]</span>")
+	if(H.get_int_organ(/obj/item/organ/internal/brain))
+		if(H.getBrainLoss() >= 100)
+			user.show_message("<span class='warning'>Subject is brain dead.</span>")
+		else if(H.getBrainLoss() >= 60)
+			user.show_message("<span class='warning'>Severe brain damage detected. Subject likely to have mental retardation.</span>")
+		else if(H.getBrainLoss() >= 10)
+			user.show_message("<span class='warning'>Significant brain damage detected. Subject may have had a concussion.</span>")
+	else
+		user.show_message("<span class='warning'>Subject has no brain.</span>")
+
+	for(var/name in H.bodyparts_by_name)
+		var/obj/item/organ/external/e = H.bodyparts_by_name[name]
+		if(!e)
+			continue
+		var/limb = e.name
+		if(e.status & ORGAN_BROKEN)
+			if((e.limb_name in list("l_arm", "r_arm", "l_hand", "r_hand", "l_leg", "r_leg", "l_foot", "r_foot")) && !(e.status & ORGAN_SPLINTED))
+				user.show_message("<span class='warning'>Unsecured fracture in subject [limb]. Splinting recommended for transport.</span>")
+		if(e.has_infected_wound())
+			user.show_message("<span class='warning'>Infected wound detected in subject [limb]. Disinfection recommended.</span>")
+
+	for(var/name in H.bodyparts_by_name)
+		var/obj/item/organ/external/e = H.bodyparts_by_name[name]
+		if(!e)
+			continue
+		if(e.status & ORGAN_BROKEN)
+			user.show_message(text("<span class='warning'>Bone fractures detected. Advanced scanner required for location.</span>"), 1)
+			break
+	for(var/obj/item/organ/external/e in H.bodyparts)
+		if(e.internal_bleeding)
+			user.show_message(text("<span class='warning'>Internal bleeding detected. Advanced scanner required for location.</span>"), 1)
+			break
+	var/blood_id = H.get_blood_id()
+	if(blood_id)
+		if(H.bleed_rate)
+			user.show_message("<span class='danger'>Subject is bleeding!</span>")
+		var/blood_percent =  round((H.blood_volume / BLOOD_VOLUME_NORMAL)*100)
+		var/blood_type = H.b_type
+		if(blood_id != "blood")//special blood substance
+			var/datum/reagent/R = GLOB.chemical_reagents_list[blood_id]
+			if(R)
+				blood_type = R.name
 			else
-				user.show_message("<span class='info'>Blood level [blood_percent] %, [H.blood_volume] cl, type: [blood_type]</span>")
-
-		if(H.undergoing_cardiac_arrest() && H.stat != DEAD)
-			user.show_message("<span class='userdanger'>Subject suffering from heart attack: Apply defibrillator immediately.</span>")
-		user.show_message("<span class='notice'>Subject's pulse: <font color='[H.pulse == PULSE_THREADY || H.pulse == PULSE_NONE ? "red" : "blue"]'>[H.get_pulse(GETPULSE_TOOL)] bpm.</font></span>")
-		var/implant_detect
-		for(var/obj/item/organ/internal/cyberimp/CI in H.internal_organs)
-			if(CI.is_robotic())
-				implant_detect += "[H.name] is modified with a [CI.name].<br>"
-		if(implant_detect)
-			user.show_message("<span class='notice'>Detected cybernetic modifications:</span>")
-			user.show_message("<span class='notice'>[implant_detect]</span>")
-		if(H.gene_stability < 40)
-			user.show_message("<span class='userdanger'>Subject's genes are quickly breaking down!</span>")
-		else if(H.gene_stability < 70)
-			user.show_message("<span class='danger'>Subject's genes are showing signs of spontaneous breakdown.</span>")
-		else if(H.gene_stability < 85)
-			user.show_message("<span class='warning'>Subject's genes are showing minor signs of instability.</span>")
+				blood_type = blood_id
+		if(H.blood_volume <= BLOOD_VOLUME_SAFE && H.blood_volume > BLOOD_VOLUME_OKAY)
+			user.show_message("<span class='danger'>LOW blood level [blood_percent] %, [H.blood_volume] cl,</span> <span class='info'>type: [blood_type]</span>")
+		else if(H.blood_volume <= BLOOD_VOLUME_OKAY)
+			user.show_message("<span class='danger'>CRITICAL blood level [blood_percent] %, [H.blood_volume] cl,</span> <span class='info'>type: [blood_type]</span>")
 		else
-			user.show_message("<span class='notice'>Subject's genes are stable.</span>")
-	src.add_fingerprint(user)
-	return
+			user.show_message("<span class='info'>Blood level [blood_percent] %, [H.blood_volume] cl, type: [blood_type]</span>")
+
+	user.show_message("<span class='notice'>Subject's pulse: <font color='[H.pulse == PULSE_THREADY || H.pulse == PULSE_NONE ? "red" : "blue"]'>[H.get_pulse(GETPULSE_TOOL)] bpm.</font></span>")
+	var/implant_detect
+	for(var/obj/item/organ/internal/cyberimp/CI in H.internal_organs)
+		if(CI.is_robotic())
+			implant_detect += "[H.name] is modified with a [CI.name].<br>"
+	if(implant_detect)
+		user.show_message("<span class='notice'>Detected cybernetic modifications:</span>")
+		user.show_message("<span class='notice'>[implant_detect]</span>")
+	if(H.gene_stability < 40)
+		user.show_message("<span class='userdanger'>Subject's genes are quickly breaking down!</span>")
+	else if(H.gene_stability < 70)
+		user.show_message("<span class='danger'>Subject's genes are showing signs of spontaneous breakdown.</span>")
+	else if(H.gene_stability < 85)
+		user.show_message("<span class='warning'>Subject's genes are showing minor signs of instability.</span>")
+	else
+		user.show_message("<span class='notice'>Subject's genes are stable.</span>")
+	add_fingerprint(user)
+

 /obj/item/healthanalyzer/verb/toggle_mode()
 	set name = "Switch Verbosity"
@@ -275,19 +285,21 @@ REAGENT SCANNER
 		if(0)
 			to_chat(usr, "The scanner no longer shows limb damage.")

-/obj/item/healthanalyzer/attackby(obj/item/W, mob/user, params)
-	if(istype(W, /obj/item/healthupgrade))
+/obj/item/healthanalyzer/attackby(obj/item/I, mob/user, params)
+	if(istype(I, /obj/item/healthupgrade))
 		if(upgraded)
 			to_chat(user, "<span class='notice'>You have already installed an upgraded in the [src].</span>")
 		else
 			to_chat(user, "<span class='notice'>You install the upgrade in the [src].</span>")
 			overlays += "advanced"
-			playsound(loc, W.usesound, 50, 1)
-			upgraded = 1
-			qdel(W)
+			playsound(loc, I.usesound, 50, 1)
+			upgraded = TRUE
+			qdel(I)
+		return
+	return ..()

 /obj/item/healthanalyzer/advanced
-	upgraded = 1
+	upgraded = TRUE

 /obj/item/healthanalyzer/advanced/New()
 	overlays += "advanced"
@@ -834,4 +846,4 @@ REAGENT SCANNER
 	if(target.disabilities & NEARSIGHTED)
 		dat += "<font color='red'>Retinal misalignment detected.</font><BR>"

-	return dat
+	return dat
@@ -313,7 +313,7 @@

 /obj/item/twohanded/shockpaddles/attack(mob/M, mob/user)
 	var/tobehealed
-	var/threshold = -config.health_threshold_dead
+	var/threshold = -HEALTH_THRESHOLD_DEAD
 	var/mob/living/carbon/human/H = M

 	if(busy)
@@ -472,7 +472,7 @@

 /obj/item/borg_defib/attack(mob/M, mob/user)
 	var/tobehealed
-	var/threshold = -config.health_threshold_dead
+	var/threshold = -HEALTH_THRESHOLD_DEAD
 	var/mob/living/carbon/human/H = M

 	if(busy)
@@ -176,10 +176,6 @@
 		affected_mob.SetSleeping(0)
 		affected_mob.SetSlowed(0)
 		affected_mob.SetConfused(0)
-		if(ishuman(affected_mob))
-			var/mob/living/carbon/human/H = affected_mob
-			if(H.traumatic_shock < 100)
-				H.shock_stage = 0
 		stage = 1
 		switch(progenitor.hunger)
 			if(10 to 60)
@@ -112,6 +112,7 @@
 	icon_state = "medicalbelt"
 	item_state = "medical"
 	use_item_overlays = 1
+	max_w_class = WEIGHT_CLASS_NORMAL
 	can_hold = list(
 		/obj/item/healthanalyzer,
 		/obj/item/dnainjector,
@@ -133,6 +134,7 @@
 		/obj/item/rad_laser,
 		/obj/item/sensor_device,
 		/obj/item/wrench/medical,
+		/obj/item/handheld_defibrillator
 	)

 /obj/item/storage/belt/medical/surgery
@@ -70,6 +70,7 @@
 	new /obj/item/radio/headset/headset_med(src)
 	new /obj/item/clothing/gloves/color/latex/nitrile(src)
 	new /obj/item/defibrillator/loaded(src)
+	new /obj/item/handheld_defibrillator(src)
 	new /obj/item/storage/belt/medical(src)
 	new /obj/item/clothing/glasses/hud/health(src)
 	new /obj/item/clothing/shoes/sandal/white(src)
@@ -184,6 +185,7 @@
 	new /obj/item/radio/headset/heads/cmo(src)
 	new /obj/item/clothing/gloves/color/latex/nitrile(src)
 	new /obj/item/defibrillator/compact/loaded(src)
+	new /obj/item/handheld_defibrillator(src)
 	new /obj/item/storage/belt/medical(src)
 	new /obj/item/flash(src)
 	new /obj/item/reagent_containers/hypospray/CMO(src)