Merge remote-tracking branch 'upstream/master' into night_shift

# Conflicts:
#	paradise.dme

code/controllers/subsystem/nanoui.dm

@@ -0,0 +1,33 @@
+SUBSYSTEM_DEF(nanoui)
+	name = "Nanoui"
+	wait = 9
+	flags = SS_NO_INIT
+	priority = FIRE_PRIORITY_NANOUI
+	runlevels = RUNLEVEL_LOBBY | RUNLEVELS_DEFAULT
+
+	var/list/currentrun = list()
+	var/list/open_uis = list() // A list of open UIs, grouped by src_object and ui_key.
+	var/list/processing_uis = list() // A list of processing UIs, ungrouped.
+
+/datum/controller/subsystem/nanoui/Shutdown()
+	close_all_uis()
+
+/datum/controller/subsystem/nanoui/stat_entry()
+	..("P:[processing_uis.len]")
+
+/datum/controller/subsystem/nanoui/fire(resumed = 0)
+	if(!resumed)
+		src.currentrun = processing_uis.Copy()
+	//cache for sanic speed (lists are references anyways)
+	var/list/currentrun = src.currentrun
+
+	while(currentrun.len)
+		var/datum/nanoui/ui = currentrun[currentrun.len]
+		currentrun.len--
+		if(ui && ui.user && ui.src_object)
+			ui.process()
+		else
+			processing_uis.Remove(ui)
+		if(MC_TICK_CHECK)
+			return
+

code/controllers/subsystem/sun.dm

@@ -0,0 +1,42 @@
+SUBSYSTEM_DEF(sun)
+	name = "Sun"
+	wait = 600
+	flags = SS_NO_TICK_CHECK|SS_NO_INIT
+	var/angle
+	var/dx
+	var/dy
+	var/rate
+	var/list/solars	= list()
+
+/datum/controller/subsystem/sun/PreInit()
+	angle = rand (0,360)			// the station position to the sun is randomised at round start
+	rate = rand(50,200)/100			// 50% - 200% of standard rotation
+	if(prob(50))					// same chance to rotate clockwise than counter-clockwise
+		rate = -rate
+
+/datum/controller/subsystem/sun/stat_entry(msg)
+	..("P:[solars.len]")
+
+/datum/controller/subsystem/sun/fire()
+	angle = (360 + angle + rate * 6) % 360	 // increase/decrease the angle to the sun, adjusted by the rate
+
+	// now calculate and cache the (dx,dy) increments for line drawing
+	var/s = sin(angle)
+	var/c = cos(angle)
+
+	// Either "abs(s) < abs(c)" or "abs(s) >= abs(c)"
+	// In both cases, the greater is greater than 0, so, no "if 0" check is needed for the divisions
+
+	if(abs(s) < abs(c))
+		dx = s / abs(c)
+		dy = c / abs(c)
+	else
+		dx = s / abs(s)
+		dy = c / abs(s)
+
+	//now tell the solar control computers to update their status and linked devices
+	for(var/obj/machinery/power/solar_control/SC in solars)
+		if(!SC.powernet)
+			solars.Remove(SC)
+			continue
+		SC.update()