/obj/item/mecha_modkit
	name = "mecha modification kit"
	desc = "A kit to modify your mech. This one doesn't do anything."
	icon = 'icons/obj/module.dmi'
	icon_state = "harddisk_mini"
	materials = list(MAT_METAL = 500)
	var/install_time = 15

/obj/item/mecha_modkit/proc/install(obj/mecha/mech, mob/user)
	if(user)
		to_chat(user, SPAN_NOTICE("You install [src] into [mech]."))
	return TRUE

/obj/item/mecha_modkit/voice
	name = "mecha voice modification kit : Standard"
	desc = "This modification kit updates a mech's onboard voice to Standard."
	var/nominalsound = 'sound/mecha/nominal.ogg'
	var/zoomsound = 'sound/mecha/imag_enh.ogg'
	var/critdestrsound = 'sound/mecha/critdestr.ogg'
	var/weapdestrsound = 'sound/mecha/weapdestr.ogg'
	var/lowpowersound = 'sound/mecha/lowpower.ogg'
	var/longactivationsound = 'sound/mecha/nominal.ogg'

/obj/item/mecha_modkit/voice/install(obj/mecha/mech, mob/living/carbon/user)
	if(istype(mech, /obj/mecha/combat/reticence) && user)
		to_chat(user, SPAN_WARNING("You attempt to install [src] into [mech], but an invisible barrier prevents you from doing so!"))
		return FALSE
	if(istype(mech, /obj/mecha/combat/honker) && user)
		to_chat(user, SPAN_WARNING("You attempt to install [src] into [mech], but you somehow trip before you get it in!"))
		user.slip("your own foot", 16 SECONDS, 0, 0, 1, "trip")
		return FALSE
	mech.nominalsound = nominalsound
	mech.zoomsound = zoomsound
	mech.critdestrsound = critdestrsound
	mech.weapdestrsound = weapdestrsound
	mech.lowpowersound = lowpowersound
	mech.longactivationsound = longactivationsound
	..()

/obj/item/mecha_modkit/voice/nanotrasen
	name = "mecha voice modification kit : Nanotrasen"
	desc = "This modification kit updates a mech's onboard voice to Nanotrasen."
	icon_state = "harddisk_mini_nt"
	nominalsound = 'sound/mecha/nominalnano.ogg'
	zoomsound = 'sound/mecha/imag_enhnano.ogg'
	critdestrsound = 'sound/mecha/critdestrnano.ogg'
	weapdestrsound = 'sound/mecha/weapdestrnano.ogg'
	lowpowersound = 'sound/mecha/lowpowernano.ogg'
	longactivationsound = 'sound/mecha/LongNanoActivation.ogg'

/obj/item/mecha_modkit/voice/syndicate
	name = "mecha voice modification kit : Syndicate"
	desc = "This suspicious modification kit updates a mech's onboard voice to Syndicate."
	icon_state = "harddisk_mini_syndi"
	origin_tech = "syndicate=1"
	nominalsound = 'sound/mecha/nominalsyndi.ogg'
	zoomsound = 'sound/mecha/imag_enhsyndi.ogg'
	critdestrsound = 'sound/mecha/critdestrsyndi.ogg'
	weapdestrsound = 'sound/mecha/weapdestrsyndi.ogg'
	lowpowersound = 'sound/mecha/lowpowersyndi.ogg'
	longactivationsound = 'sound/mecha/LongSyndiActivation.ogg'
	materials = list(MAT_METAL = 400, MAT_TITANIUM = 100)

/obj/item/mecha_modkit/voice/honk
	name = "mecha voice modification kit : Honk"
	desc = "This modification kit updates a mech's onboard voice to Honk. Why?"
	icon_state = "harddisk_mini_clown"
	nominalsound = 'sound/items/bikehorn.ogg'
	zoomsound = 'sound/items/bikehorn.ogg'
	critdestrsound = 'sound/items/Airhorn2.ogg'
	weapdestrsound = 'sound/items/Airhorn2.ogg'
	lowpowersound = 'sound/items/Airhorn2.ogg'
	longactivationsound = 'sound/items/bikehorn.ogg'
	materials = list(MAT_METAL = 400, MAT_BANANIUM = 100)

/obj/item/mecha_modkit/voice/silent
	name = "mecha voice modification kit : Silent"
	desc = "This modification kit silences a mech's onboard voice."
	icon_state = "harddisk_mini_mime"
	nominalsound = null
	zoomsound = null
	critdestrsound = null
	weapdestrsound = null
	lowpowersound = null
	longactivationsound = null