//Stetchkin//
/obj/item/gun/projectile/automatic/pistol
	name = "stechkin pistol"
	desc = "A small, easily concealable 10mm handgun. Has a threaded barrel for suppressors."
	icon_state = "pistol"
	w_class = WEIGHT_CLASS_SMALL
	origin_tech = "combat=3;materials=2;syndicate=3"
	can_holster = TRUE
	mag_type = /obj/item/ammo_box/magazine/m10mm
	fire_sound = 'sound/weapons/gunshots/gunshot_pistol.ogg'
	magin_sound = 'sound/weapons/gun_interactions/pistol_magin.ogg'
	magout_sound = 'sound/weapons/gun_interactions/pistol_magout.ogg'
	can_suppress = TRUE
	burst_size = 1
	fire_delay = 0
	execution_speed = 4 SECONDS
	actions_types = list()

/obj/item/gun/projectile/automatic/pistol/update_icon_state()
	icon_state = "[initial(icon_state)][magazine ? "-[magazine.max_ammo]" : ""][chambered ? "" : "-e"][suppressed ? "-suppressed" : ""]"

//M1911//
/obj/item/gun/projectile/automatic/pistol/m1911
	name = "\improper M1911"
	desc = "A classic .45 handgun with a small magazine capacity."
	icon_state = "m1911"
	w_class = WEIGHT_CLASS_NORMAL
	mag_type = /obj/item/ammo_box/magazine/m45
	can_suppress = FALSE

//Enforcer//
/obj/item/gun/projectile/automatic/pistol/enforcer
	name = "\improper NF10 'Enforcer' pistol"
	desc = "A 9mm sidearm commonly used by Nanotrasen Asset Protection."
	icon_state = "enforcer_grey"
	force = 10
	mag_type = /obj/item/ammo_box/magazine/enforcer
	can_suppress = TRUE
	unique_reskin = TRUE
	can_flashlight = TRUE

/obj/item/gun/projectile/automatic/pistol/enforcer/Initialize(mapload)
	. = ..()
	options["Grey slide"] = "enforcer_grey"
	options["Red slide"] = "enforcer_red"
	options["Green slide"] = "enforcer_green"
	options["Tan slide"] = "enforcer_tan"
	options["Black slide"] = "enforcer_black"
	options["Green Handle"] = "enforcer_greengrip"
	options["Tan Handle"] = "enforcer_tangrip"
	options["Red Handle"] = "enforcer_redgrip"

/obj/item/gun/projectile/automatic/pistol/enforcer/update_icon_state()
	if(current_skin)
		icon_state = "[current_skin][chambered ? "" : "-e"]"
	else
		icon_state = "[initial(icon_state)][chambered ? "" : "-e"]"

/obj/item/gun/projectile/automatic/pistol/enforcer/update_overlays()
	. = list()
	if(suppressed)
		. += image(icon = icon, icon_state = "enforcer_supp", pixel_x = 4)
	if(gun_light)
		var/flashlight = "Enforcer_light"
		if(gun_light.on)
			flashlight = "Enforcer_light-on"
		. += image(icon = icon, icon_state = flashlight, pixel_x = 0)

/obj/item/gun/projectile/automatic/pistol/enforcer/ui_action_click()
	toggle_gunlight()

/obj/item/gun/projectile/automatic/pistol/enforcer/lethal
	mag_type = /obj/item/ammo_box/magazine/enforcer/lethal

//Desert Eagle//
/obj/item/gun/projectile/automatic/pistol/deagle
	name = "\improper Desert Eagle"
	desc = "A robust .50 AE handgun."
	icon_state = "deagle"
	force = 14.0
	mag_type = /obj/item/ammo_box/magazine/m50
	fire_sound = 'sound/weapons/gunshots/gunshot_pistolH.ogg'
	magin_sound = 'sound/weapons/gun_interactions/hpistol_magin.ogg'
	magout_sound = 'sound/weapons/gun_interactions/hpistol_magout.ogg'
	can_suppress = FALSE

/obj/item/gun/projectile/automatic/pistol/deagle/gold
	desc = "A gold plated Desert Eagle folded over a million times by superior martian gunsmiths. Uses .50 AE ammo."
	icon_state = "deagleg"
	item_state = "deagleg"

/obj/item/gun/projectile/automatic/pistol/deagle/camo
	desc = "A Deagle brand Deagle for operators operating operationally. Uses .50 AE ammo."
	icon_state = "deaglecamo"
	item_state = "deagleg"

//APS Pistol//
/obj/item/gun/projectile/automatic/pistol/APS
	name = "stechkin APS pistol"
	desc = "A deadly automatic pistol produced by the USSP's State Armory. Uses 10mm ammo."
	icon_state = "aps"
	w_class = WEIGHT_CLASS_NORMAL
	origin_tech = "combat=3;materials=2;syndicate=3"
	mag_type = /obj/item/ammo_box/magazine/apsm10mm
	can_suppress = FALSE
	burst_size = 3
	fire_delay = 2
	actions_types = list(/datum/action/item_action/toggle_firemode)