SUBSYSTEM_DEF(events)
	name = "Events"
	init_order = INIT_ORDER_EVENTS
	runlevels = RUNLEVEL_GAME
	flags = SS_KEEP_TIMING
	offline_implications = "Random events will no longer happen. No immediate action is needed."
	cpu_display = SS_CPUDISPLAY_LOW
	// Report events at the end of the rouund
	var/report_at_round_end = 0

	// UI vars
	var/window_x = 700
	var/window_y = 600
	var/table_options = "align='center'"
	var/head_options = "style='font-weight:bold;'"
	var/row_options1 = "width='85px'"
	var/row_options2 = "width='260px'"
	var/row_options3 = "width='150px'"

	// Event vars
	var/datum/event_container/selected_event_container = null
	var/list/active_events = list()
	var/list/finished_events = list()
	var/list/allEvents
	var/list/event_containers = alist(
			EVENT_LEVEL_MUNDANE 	= new/datum/event_container/mundane,
			EVENT_LEVEL_MODERATE	= new/datum/event_container/moderate,
			EVENT_LEVEL_MAJOR 		= new/datum/event_container/major,
			EVENT_LEVEL_DISASTER = new/datum/event_container/disaster
		)

	var/datum/event_meta/new_event = new

	var/list/biohazards_this_round = list()
	/// Artificial staffing for debug purpouses
	var/list/debug_resources = list()

/datum/controller/subsystem/events/Initialize()
	allEvents = subtypesof(/datum/event)

/datum/controller/subsystem/events/fire()
	for(var/datum/event/E in active_events)
		E.process()

	for(var/container in event_containers)
		var/datum/event_container/EC = event_containers[container]
		EC.process()

/datum/controller/subsystem/events/proc/event_complete(datum/event/E)
	if(!E.event_meta)	// datum/event is used here and there for random reasons, maintaining "backwards compatibility"
		log_debug("Event of '[E.type]' with missing meta-data has completed.")
		return

	finished_events += E

	var/theseverity

	if(!E.severity)
		theseverity = EVENT_LEVEL_MODERATE

	if(!E.severity == EVENT_LEVEL_MUNDANE && !E.severity == EVENT_LEVEL_MODERATE && !E.severity == EVENT_LEVEL_MAJOR)
		theseverity = EVENT_LEVEL_MODERATE //just to be careful

	if(E.severity)
		theseverity = E.severity

	// Add the event back to the list of available events
	var/datum/event_container/EC = event_containers[theseverity]
	var/datum/event_meta/EM = E.event_meta
	EC.available_events |= EM

	log_debug("Event '[EM.skeleton.name]' has completed at [station_time_timestamp()].")

/datum/controller/subsystem/events/proc/delay_events(severity, delay)
	var/datum/event_container/EC = event_containers[severity]
	EC.next_event_time += delay

/datum/controller/subsystem/events/proc/Interact(mob/living/user)

	var/html = GetInteractWindow()

	var/datum/browser/popup = new(user, "event_manager", "Event Manager", window_x, window_y)
	popup.set_content(html)
	popup.open()

/datum/controller/subsystem/events/proc/RoundEnd()
	if(!report_at_round_end)
		return

	to_chat(world, "<br><br><br><font size=3><b>Random Events This Round:</b></font>")
	for(var/datum/event/E in active_events|finished_events)
		var/datum/event_meta/EM = E.event_meta
		if(EM.skeleton.name == "Nothing")
			continue
		var/message = "'[EM.skeleton.name]' began at [station_time_timestamp("hh:mm:ss", E.startedAt)] "
		if(E.isRunning)
			message += "and is still running."
		else
			if(E.endedAt - E.startedAt > 5 MINUTES) // Only mention end time if the entire duration was more than 5 minutes
				message += "and ended at [station_time_timestamp("hh:mm:ss", E.endedAt)]."
			else
				message += "and ran to completion."

		to_chat(world, message)

/datum/controller/subsystem/events/proc/GetInteractWindow()
	var/html = "<A align='right' href='byond://?src=[UID()];refresh=1'>Refresh</A>"
	html += "<A align='right' href='byond://?src=[UID()];resource=1'>Resources</A>"
	if(selected_event_container)
		var/event_time = max(0, selected_event_container.next_event_time - world.time)
		var/list/total_resources = get_total_resources()
		html += "<A align='right' href='byond://?src=[UID()];back=1'>Back</A><br>"
		html += "Time till start: [round(event_time / 600, 0.1)]<br>"
		html += "<div class='block'>"
		html += "<h2>Available [GLOB.severity_to_string[selected_event_container.severity]] Events (queued & running events will not be displayed)</h2>"
		html += "<table [table_options]>"
		html += "<tr [head_options]><td [row_options2]>Name </td><td>Weight </td><td>MinWeight </td><td>MaxWeight </td><td>OneShot </td><td>Enabled </td><td>[SPAN_ALERT("CurrWeight ")]</td><td>Remove</td></tr>"
		for(var/datum/event_meta/EM in selected_event_container.available_events)
			if(!EM.skeleton)
				continue
			html += "<tr>"
			html += "<td>[EM.skeleton.name]</td>"
			html += "<td><A align='right' href='byond://?src=[UID()];set_weight=\ref[EM]'>[EM.weight]</A></td>"
			html += "<td>[EM.min_weight]</td>"
			html += "<td>[EM.max_weight == INFINITY ? "No max" : EM.max_weight]</td>"
			html += "<td><A align='right' href='byond://?src=[UID()];toggle_oneshot=\ref[EM]'>[EM.one_shot]</A></td>"
			html += "<td><A align='right' href='byond://?src=[UID()];toggle_enabled=\ref[EM]'>[EM.enabled]</A></td>"
			html += "<td>[SPAN_ALERT("[EM.get_weight(total_resources)]")]</td>"
			html += "<td><A align='right' href='byond://?src=[UID()];remove=\ref[EM];EC=\ref[selected_event_container]'>Remove</A></td>"
			html += "</tr>"
		html += "</table>"
		html += "</div>"

		html += "<div class='block'>"
		html += "<h2>Add Event</h2>"
		html += "<table [table_options]>"
		html += "<tr [head_options]><td [row_options2]>Name</td><td [row_options2]>Type</td><td [row_options1]>Weight</td><td [row_options1]>OneShot</td></tr>"
		html += "<tr>"
		html += "<td><A align='right' href='byond://?src=[UID()];set_name=\ref[new_event]'>[new_event?.skeleton?.name ? new_event?.skeleton?.name : "Enter Event"]</A></td>"
		html += "<td><A align='right' href='byond://?src=[UID()];set_type=\ref[new_event]'>[new_event?.skeleton?.type ? new_event?.skeleton?.type : "Select Type"]</A></td>"
		html += "<td><A align='right' href='byond://?src=[UID()];set_weight=\ref[new_event]'>[new_event.weight ? new_event.weight : 0]</A></td>"
		html += "<td><A align='right' href='byond://?src=[UID()];toggle_oneshot=\ref[new_event]'>[new_event.one_shot]</A></td>"
		html += "</tr>"
		html += "</table>"
		html += "<A align='right' href='byond://?src=[UID()];add=\ref[selected_event_container]'>Add</A><br>"
		html += "</div>"
	else
		html += "<A align='right' href='byond://?src=[UID()];toggle_report=1'>Round End Report: [report_at_round_end ? "On": "Off"]</A><br>"
		html += "<div class='block'>"
		html += "<h2>Event Start</h2>"

		html += "<table [table_options]>"
		html += "<tr [head_options]><td [row_options1]>Severity</td><td [row_options1]>Starts At</td><td [row_options1]>Starts In</td><td [row_options3]>Adjust Start</td><td [row_options1]>Pause</td><td [row_options1]>Interval Mod</td></tr>"
		for(var/severity = EVENT_LEVEL_MUNDANE to EVENT_LEVEL_DISASTER)
			var/datum/event_container/EC = event_containers[severity]
			var/next_event_at = max(0, EC.next_event_time - world.time)
			html += "<tr>"
			html += "<td>[GLOB.severity_to_string[severity]]</td>"
			html += "<td>[station_time_timestamp("hh:mm:ss", max(EC.next_event_time, world.time))]</td>"
			html += "<td>[round(next_event_at / 600, 0.1)]</td>"
			html += "<td>"
			html +=   "<A align='right' href='byond://?src=[UID()];dec_timer=2;event=\ref[EC]'>--</A>"
			html +=   "<A align='right' href='byond://?src=[UID()];dec_timer=1;event=\ref[EC]'>-</A>"
			html +=   "<A align='right' href='byond://?src=[UID()];inc_timer=1;event=\ref[EC]'>+</A>"
			html +=   "<A align='right' href='byond://?src=[UID()];inc_timer=2;event=\ref[EC]'>++</A>"
			html += "</td>"
			html += "<td>"
			html +=   "<A align='right' href='byond://?src=[UID()];pause=\ref[EC]'>[EC.delayed ? "Resume" : "Pause"]</A>"
			html += "</td>"
			html += "<td>"
			html +=   "<A align='right' href='byond://?src=[UID()];interval=\ref[EC]'>[EC.delay_modifier]</A>"
			html += "</td>"
			html += "</tr>"
		html += "</table>"
		html += "</div>"

		html += "<div class='block'>"
		html += "<h2>Next Event</h2>"
		html += "<table [table_options]>"
		html += "<tr [head_options]><td [row_options1]>Severity</td><td [row_options2]>Name</td><td [row_options3]>Event Rotation</td><td>Clear</td></tr>"
		for(var/severity in EVENT_LEVEL_MUNDANE to EVENT_LEVEL_DISASTER)
			var/datum/event_container/EC = event_containers[severity]
			var/datum/event_meta/EM = EC.next_event
			html += "<tr>"
			html += "<td>[GLOB.severity_to_string[severity]]</td>"
			html += "<td><A align='right' href='byond://?src=[UID()];select_event=\ref[EC]'>[EM ? EM.skeleton.name : "Random"]</A></td>"
			html += "<td><A align='right' href='byond://?src=[UID()];view_events=\ref[EC]'>View</A></td>"
			html += "<td><A align='right' href='byond://?src=[UID()];clear=\ref[EC]'>Clear</A></td>"
			html += "</tr>"
		html += "</table>"
		html += "</div>"

		html += "<div class='block'>"
		html += "<h2>Running Events</h2>"
		html += "Estimated times, affected by master controller delays."
		html += "<table [table_options]>"
		html += "<tr [head_options]><td [row_options1]>Severity</td><td [row_options2]>Name</td><td [row_options1]>Ends At</td><td [row_options1]>Ends In</td><td [row_options3]>Stop</td></tr>"
		for(var/datum/event/E in active_events)
			if(!E)
				continue
			var/ends_at = E.startedAt + (E.lastProcessAt() * 20)	// A best estimate, based on how often the manager processes
			var/ends_in = max(0, round((ends_at - world.time) / 600, 0.1))
			var/no_end = E.noAutoEnd
			html += "<tr>"
			html += "<td>[GLOB.severity_to_string[E.severity]]</td>"
			html += "<td>[E.name] [ADMIN_VV(E, "VV")]</td>"
			html += "<td>[no_end ? "N/A" : station_time_timestamp("hh:mm:ss", ends_at)]</td>"
			html += "<td>[no_end ? "N/A" : ends_in]</td>"
			html += "<td><A align='right' href='byond://?src=[UID()];stop=\ref[E]'>Stop</A></td>"
			html += "</tr>"
		html += "</table>"
		html += "</div>"

	return html

/datum/controller/subsystem/events/Topic(href, href_list)
	if(..())
		return

	if(!check_rights(R_EVENT))
		return

	if(href_list["toggle_report"])
		report_at_round_end = !report_at_round_end
		log_and_message_admins("has [report_at_round_end ? "enabled" : "disabled"] the round end event report.")
	else if(href_list["dec_timer"])
		var/datum/event_container/EC = locate(href_list["event"])
		var/decrease = (60 * RaiseToPower(10, text2num(href_list["dec_timer"])))
		EC.next_event_time -= decrease
		log_and_message_admins("decreased timer for [GLOB.severity_to_string[EC.severity]] events by [decrease/600] minute(s).")
	else if(href_list["inc_timer"])
		var/datum/event_container/EC = locate(href_list["event"])
		var/increase = (60 * RaiseToPower(10, text2num(href_list["inc_timer"])))
		EC.next_event_time += increase
		log_and_message_admins("increased timer for [GLOB.severity_to_string[EC.severity]] events by [increase/600] minute(s).")
	else if(href_list["select_event"])
		var/datum/event_container/EC = locate(href_list["select_event"])
		var/datum/event_meta/EM = EC.SelectEvent()
		if(EM)
			log_and_message_admins("has queued the [GLOB.severity_to_string[EC.severity]] event '[EM.skeleton.name]'.")
	else if(href_list["pause"])
		var/datum/event_container/EC = locate(href_list["pause"])
		EC.delayed = !EC.delayed
		log_and_message_admins("has [EC.delayed ? "paused" : "resumed"] countdown for [GLOB.severity_to_string[EC.severity]] events.")
	else if(href_list["interval"])
		var/delay = input("Enter delay modifier. A value less than one means events fire more often, higher than one less often.", "Set Interval Modifier") as num|null
		if(delay && delay > 0)
			var/datum/event_container/EC = locate(href_list["interval"])
			EC.delay_modifier = delay
			log_and_message_admins("has set the interval modifier for [GLOB.severity_to_string[EC.severity]] events to [EC.delay_modifier].")
	else if(href_list["stop"])
		if(alert("Stopping an event may have unintended side-effects. Continue?","Stopping Event!","Yes","No") != "Yes")
			return
		var/datum/event/E = locate(href_list["stop"])
		var/datum/event_meta/EM = E.event_meta
		log_and_message_admins("has stopped the [GLOB.severity_to_string[EM.skeleton.severity]] event '[EM.skeleton.name]'.")
		E.kill()
	else if(href_list["view_events"])
		selected_event_container = locate(href_list["view_events"])
	else if(href_list["back"])
		selected_event_container = null
	else if(href_list["set_name"])
		var/name = clean_input("Enter event name.", "Set Name")
		if(name)
			var/datum/event_meta/EM = locate(href_list["set_name"])
			EM.skeleton.name = name
	else if(href_list["set_type"])
		var/type = input("Select event type.", "Select") as null|anything in allEvents
		if(type)
			var/datum/event_meta/EM = locate(href_list["set_type"])
			EM.change_event(type)
	else if(href_list["set_weight"])
		var/weight = input("Enter weight. A higher value means higher chance for the event of being selected.", "Set Weight") as num|null
		if(weight && weight > 0)
			var/datum/event_meta/EM = locate(href_list["set_weight"])
			EM.weight = weight
			if(EM != new_event)
				log_and_message_admins("has changed the weight of the [GLOB.severity_to_string[EM.skeleton.severity]] event '[EM.skeleton.name]' to [EM.weight].")
	else if(href_list["toggle_oneshot"])
		var/datum/event_meta/EM = locate(href_list["toggle_oneshot"])
		EM.one_shot = !EM.one_shot
		if(EM != new_event)
			log_and_message_admins("has [EM.one_shot ? "set" : "unset"] the oneshot flag for the [GLOB.severity_to_string[EM.skeleton.severity]] event '[EM.skeleton.name]'.")
	else if(href_list["toggle_enabled"])
		var/datum/event_meta/EM = locate(href_list["toggle_enabled"])
		EM.enabled = !EM.enabled
		log_and_message_admins("has [EM.enabled ? "enabled" : "disabled"] the [GLOB.severity_to_string[EM.skeleton.severity]] event '[EM.skeleton.name]'.")
	else if(href_list["remove"])
		if(alert("This will remove the event from rotation. Continue?","Removing Event!","Yes","No") != "Yes")
			return
		var/datum/event_meta/EM = locate(href_list["remove"])
		var/datum/event_container/EC = locate(href_list["EC"])
		EC.available_events -= EM
		log_and_message_admins("has removed the [GLOB.severity_to_string[EM.skeleton.severity]] event '[EM.skeleton.name]'.")
	else if(href_list["add"])
		if(!new_event.skeleton.name || !new_event.skeleton.type)
			return
		if(alert("This will add a new event to the rotation. Continue?","Add Event!","Yes","No") != "Yes")
			return
		new_event.skeleton.severity = selected_event_container.severity
		selected_event_container.available_events += new_event
		log_and_message_admins("has added \a [GLOB.severity_to_string[new_event.skeleton.severity]] event '[new_event.skeleton.name]' of type [new_event.skeleton.type] with weight [new_event.weight].")
		new_event = new
	else if(href_list["clear"])
		var/datum/event_container/EC = locate(href_list["clear"])
		if(EC.next_event)
			log_and_message_admins("has dequeued the [GLOB.severity_to_string[EC.severity]] event '[EC.next_event.skeleton.name]'.")
			EC.next_event = null
	else if(href_list["resource"])
		GetResourceWindow()

	Interact(usr)

/datum/controller/subsystem/events/proc/GetResourceWindow()
	var/html = "<A align='right' href='byond://?src=[UID()];refresh=1'>Refresh</A>"
	var/list/total_resources = get_total_resources()
	html += "<div class='block'>"
	html += "<h2>Total Resources</h2>"
	html += "<table [table_options]>"
	html += "<tr [head_options]><td [row_options2]>Name <td [row_options3]>Weight</tr>"
	for(var/resource in total_resources)
		html += "<tr>"
		html += "<td>[resource]</td>"
		html += "<td>[total_resources[resource]]</td>"
		html += "</tr>"
	html += "</table>"
	html += "</div>"
	var/list/net_resources = number_active_with_role()
	html += "<div class='block'>"
	html += "<h2>Net Resources</h2>"
	html += "<table [table_options]>"
	html += "<tr [head_options]><td [row_options2]>Name <td [row_options3]>Weight</tr>"
	for(var/resource in net_resources)
		html += "<tr>"
		html += "<td>[resource]</td>"
		html += "<td>[net_resources[resource]]</td>"
		html += "</tr>"
	html += "</table>"
	html += "</div>"

	var/datum/browser/popup = new(usr, "resources", "Resources", window_x, window_y)
	popup.set_content(html)
	popup.open()