mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-25 17:51:17 +00:00
0b838dc3c4
* Preliminary changes for 516 * Also removes the goon folder * Fixes a BUNCH of UIs * update our things * debug proc * le maintainer verb * fix strip panel * browseroutput => chat_panel * prettier, remove obsolete bat * tidu tgui say css * href purge * 515 compat * 515 compat 2 * more required chores * comments * fully working 515 * bungle * correct this * fixes 515 support * prettier * new CI * fixes old href styles sneaking in * update docs to reflect href changes * more href fixes (thanks cdui) * MORE href nonsense * even more hrefs (seriously wtf) * Update code/modules/admin/permissionverbs/permissionedit.dm * error on fail --------- Co-authored-by: AffectedArc07 <25063394+AffectedArc07@users.noreply.github.com>
44 lines
2.2 KiB
Plaintext
44 lines
2.2 KiB
Plaintext
/// Process asset cache client topic calls for "asset_cache_confirm_arrival=[INT]"
|
|
/client/proc/asset_cache_confirm_arrival(job_id)
|
|
var/asset_cache_job = round(text2num(job_id))
|
|
//because we skip the limiter, we have to make sure this is a valid arrival and not somebody tricking us into letting them append to a list without limit.
|
|
if(asset_cache_job > 0 && asset_cache_job <= last_asset_job && !(completed_asset_jobs["[asset_cache_job]"]))
|
|
completed_asset_jobs["[asset_cache_job]"] = TRUE
|
|
last_completed_asset_job = max(last_completed_asset_job, asset_cache_job)
|
|
else
|
|
return asset_cache_job || TRUE
|
|
|
|
|
|
/// Process asset cache client topic calls for "asset_cache_preload_data=[HTML+JSON_STRING]
|
|
/client/proc/asset_cache_preload_data(data)
|
|
var/json = data
|
|
var/list/preloaded_assets = json_decode(json)
|
|
for(var/preloaded_asset in preloaded_assets)
|
|
if(copytext(preloaded_asset, findlasttext(preloaded_asset, ".") + 1) in list("js", "jsm", "htm", "html"))
|
|
preloaded_assets -= preloaded_asset
|
|
continue
|
|
sent_assets |= preloaded_assets
|
|
|
|
|
|
/// Updates the client side stored json file used to keep track of what assets the client has between restarts/reconnects.
|
|
/client/proc/asset_cache_update_json()
|
|
if(world.time - connection_time < 10 SECONDS) //don't override the existing data file on a new connection
|
|
return
|
|
|
|
src << browse(json_encode(sent_assets), "file=asset_data.json&display=0")
|
|
|
|
/// Blocks until all currently sending browse and browse_rs assets have been sent.
|
|
/// Due to byond limitations, this proc will sleep for 1 client round trip even if the client has no pending asset sends.
|
|
/// This proc will return an untrue value if it had to return before confirming the send, such as timeout or the client going away.
|
|
/client/proc/browse_queue_flush(timeout = 5 SECONDS)
|
|
var/job = ++last_asset_job
|
|
var/t = 0
|
|
var/timeout_time = timeout
|
|
src << browse({"<script>window.location.href='byond://?asset_cache_confirm_arrival=[job]'</script>"}, "window=asset_cache_browser&file=asset_cache_send_verify.htm")
|
|
|
|
while(!completed_asset_jobs["[job]"] && t < timeout_time) // Reception is handled in Topic()
|
|
stoplag(1) // Lock up the caller until this is received.
|
|
t++
|
|
if(t < timeout_time)
|
|
return TRUE
|