mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-27 18:01:51 +00:00
2a842644d5
* port ADMIN_VERB and friends * some renaming * dumb * one more rename * never search and replace this codebase * fix TM issues, more renaming * add a static analysis to shore up user verbs * fix double message on roundstart * remove macro we're not using yet * convert remaining playsounds verbs * convert more verbs i missed somehow * why is this a completely different signature than everything else * fix ui_interact arg * fix logging view and others * buncha issues caught in TM * fix mentor tickets ui * fix bug report viewing * moron
80 lines
2.4 KiB
Plaintext
80 lines
2.4 KiB
Plaintext
|
|
//////////////////////////
|
|
//Movable Screen Objects//
|
|
// By RemieRichards //
|
|
//////////////////////////
|
|
|
|
|
|
//Movable Screen Object
|
|
//Not tied to the grid, places it's center where the cursor is
|
|
|
|
/atom/movable/screen/movable
|
|
var/snap2grid = FALSE
|
|
var/x_off = -16
|
|
var/y_off = -16
|
|
// add a green overlay
|
|
mouse_drag_pointer = 'icons/mouse_icons/screen_drag.dmi'
|
|
|
|
|
|
//Snap Screen Object
|
|
//Tied to the grid, snaps to the nearest turf
|
|
|
|
/atom/movable/screen/movable/snap
|
|
snap2grid = TRUE
|
|
|
|
/atom/movable/screen/movable/MouseDrop(over_object, src_location, over_location, src_control, over_control, params)
|
|
var/position = mouse_params_to_position(params)
|
|
if(!position)
|
|
return
|
|
|
|
screen_loc = position
|
|
|
|
/// Takes mouse parmas as input, returns a string representing the appropriate mouse position
|
|
/atom/movable/screen/movable/proc/mouse_params_to_position(params)
|
|
|
|
var/list/modifiers = params2list(params)
|
|
|
|
//No screen-loc information? abort.
|
|
if(!LAZYACCESS(modifiers, SCREEN_LOC))
|
|
return
|
|
|
|
var/client/our_client = usr.client
|
|
var/list/offset = screen_loc_to_offset(LAZYACCESS(modifiers, SCREEN_LOC))
|
|
|
|
if(snap2grid) //Discard Pixel Values
|
|
offset[1] = FLOOR(offset[1], world.icon_size) // drops any pixel offset
|
|
offset[2] = FLOOR(offset[2], world.icon_size) // drops any pixel offset
|
|
else //Normalise Pixel Values (So the object drops at the center of the mouse, not 16 pixels off)
|
|
offset[1] += x_off
|
|
offset[2] += y_off
|
|
return offset_to_screen_loc(offset[1], offset[2], our_client?.view)
|
|
|
|
//Debug procs
|
|
USER_VERB(test_movable_ui, R_DEBUG, "Spawn Movable UI Object", "Spawn Movable UI Object", VERB_CATEGORY_DEBUG)
|
|
var/atom/movable/screen/movable/M = new()
|
|
M.name = "Movable UI Object"
|
|
M.icon_state = "block"
|
|
M.maptext = "Movable"
|
|
M.maptext_width = 64
|
|
|
|
var/screen_l = input(client, "Where on the screen? (Formatted as 'X,Y' e.g: '1,1' for bottom left)","Spawn Movable UI Object") as text
|
|
if(!screen_l)
|
|
return
|
|
|
|
M.screen_loc = screen_l
|
|
client.screen += M
|
|
|
|
USER_VERB(test_snap_ui, R_DEBUG, "Spawn Snap UI Object", "Spawn Snap UI Object", VERB_CATEGORY_DEBUG)
|
|
var/atom/movable/screen/movable/snap/S = new()
|
|
S.name = "Snap UI Object"
|
|
S.icon_state = "block"
|
|
S.maptext = "Snap"
|
|
S.maptext_width = 64
|
|
|
|
var/screen_l = input(client, "Where on the screen? (Formatted as 'X,Y' e.g: '1,1' for bottom left)","Spawn Snap UI Object") as text
|
|
if(!screen_l)
|
|
return
|
|
|
|
S.screen_loc = screen_l
|
|
client.screen += S
|