mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-23 08:41:43 +00:00
129a57bd9b
Ports Goon Lighting from /vg/station. Summary - This adds smooth edges to all lighting in order to increase the aesthetic appeal of the lighting system. It works by using a matrix to change the appearance of the lighting overlay sprite, which has been changed to be a base for the matrix to modify. Ported from /vg/station with the help of @PJB3005. This lighting system is a hybrid between Mloc's lighting rewrite and Tobba's Goonlights. Notable changes: - Darksight now matters on mobs. The lighting overlays are not alpha=255 when they are completely dark, meaning you can still see the floor- assuming you can view the turf at all, because it retains the luminousity setting. - This means Tajaran have 100% night vision again as they are intended to. Humans can see in a 3x3 square centered around themselves. - No, I'm not changing this, if it's even possible. This is how BYOND's lighting is meant to work. If you have any complaints about game balance, please feel free to make a pull request to change see_in_dark values, which will be seperately evaluated. - The lighting controller now runs at world.tick_lag, to emulate the realtime function of StonedMC. So far with my testing, this hasn't caused any noticable performance decreases- the lighting system is obviously more expensive than our previous iteration, however, it's not the next ZAS ;) Technical Details: - /atom/movable/lighting_overlay/proc/get_clamped_lum has been removed, succeeded by /turf/proc/get_lumcount. They behave identically. - Turf lighting is actually controlled by four "corner" datums, which feed information into the overlay. - The way opacity is factored into the system has changed. Anything that doesn't use set_opacity is not going to work to block light. - /area/lighting_use_dynamic has been renamed to /area/dynamic_lighting, for consistency with /turf/dynamic_lighting. - Lighting is no longer seperately initialized for away missions. It is handled in ChangeTurf() as it should be. Known & Unfixable issues: - There is a 5-10 second delay from starting the round to the lights turning on. Attribute it to "the powernet being spun up" if you would like to- but it's actually just how long it takes the lighting system to update every single turf on the map. - When you walk with a light on you, the light will actually jump ahead of you before you visually get to the tile. This is because of the movement gliding on mobs, realtime lighting actually goes faster than the glide takes to complete, so it appears that your lights are moving faster than you. Thank you krausy~ Animated Goonlights This adds an animate() call to the update_overlays() proc. This makes it so that any light changes will smoothly transition between the changes instead of instantly changing their appearance. Also fixes a few issues pointed out on Github. Change lighting animation (turns out the old one totally breaks if you toggle a light quickly, whoopsies) Kill LIGHTING_INSTANT_UPDATES isturf
103 lines
3.0 KiB
Plaintext
103 lines
3.0 KiB
Plaintext
/turf
|
|
var/dynamic_lighting = TRUE
|
|
luminosity = 1
|
|
|
|
var/tmp/lighting_corners_initialised = FALSE
|
|
|
|
var/tmp/list/datum/light_source/affecting_lights // List of light sources affecting this turf.
|
|
var/tmp/atom/movable/lighting_overlay/lighting_overlay // Our lighting overlay.
|
|
var/tmp/list/datum/lighting_corner/corners
|
|
var/tmp/has_opaque_atom = FALSE // Not to be confused with opacity, this will be TRUE if there's any opaque atom on the tile.
|
|
|
|
/turf/New()
|
|
. = ..()
|
|
|
|
if(opacity)
|
|
has_opaque_atom = TRUE
|
|
|
|
// Causes any affecting light sources to be queued for a visibility update, for example a door got opened.
|
|
/turf/proc/reconsider_lights()
|
|
for(var/datum/light_source/L in affecting_lights)
|
|
L.vis_update()
|
|
|
|
/turf/proc/lighting_clear_overlay()
|
|
if(lighting_overlay)
|
|
qdel(lighting_overlay)
|
|
|
|
for(var/datum/lighting_corner/C in corners)
|
|
C.update_active()
|
|
|
|
// Builds a lighting overlay for us, but only if our area is dynamic.
|
|
/turf/proc/lighting_build_overlay()
|
|
if(lighting_overlay)
|
|
return
|
|
|
|
var/area/A = loc
|
|
if(A.dynamic_lighting)
|
|
if(!lighting_corners_initialised)
|
|
generate_missing_corners()
|
|
|
|
new /atom/movable/lighting_overlay(src)
|
|
|
|
for(var/datum/lighting_corner/C in corners)
|
|
if(!C.active) // We would activate the corner, calculate the lighting for it.
|
|
for(var/L in C.affecting)
|
|
var/datum/light_source/S = L
|
|
S.recalc_corner(C)
|
|
|
|
C.active = TRUE
|
|
|
|
// Used to get a scaled lumcount.
|
|
/turf/proc/get_lumcount(var/minlum = 0, var/maxlum = 1)
|
|
if(!lighting_overlay)
|
|
return 1
|
|
|
|
var/totallums = 0
|
|
for(var/datum/lighting_corner/L in corners)
|
|
totallums += max(L.lum_r, L.lum_g, L.lum_b)
|
|
|
|
totallums /= 4 // 4 corners, max channel selected, return the average
|
|
|
|
totallums =(totallums - minlum) /(maxlum - minlum)
|
|
|
|
return CLAMP01(totallums)
|
|
|
|
// Can't think of a good name, this proc will recalculate the has_opaque_atom variable.
|
|
/turf/proc/recalc_atom_opacity()
|
|
has_opaque_atom = FALSE
|
|
for(var/atom/A in src.contents + src) // Loop through every movable atom on our tile PLUS ourselves (we matter too...)
|
|
if(A.opacity)
|
|
has_opaque_atom = TRUE
|
|
|
|
// If an opaque movable atom moves around we need to potentially update visibility.
|
|
/turf/Entered(var/atom/movable/Obj, var/atom/OldLoc)
|
|
. = ..()
|
|
|
|
if(Obj && Obj.opacity)
|
|
has_opaque_atom = TRUE // Make sure to do this before reconsider_lights(), incase we're on instant updates. Guaranteed to be on in this case.
|
|
reconsider_lights()
|
|
|
|
/turf/Exited(var/atom/movable/Obj, var/atom/newloc)
|
|
. = ..()
|
|
|
|
if(Obj && Obj.opacity)
|
|
recalc_atom_opacity() // Make sure to do this before reconsider_lights(), incase we're on instant updates.
|
|
reconsider_lights()
|
|
|
|
/turf/proc/get_corners()
|
|
if(has_opaque_atom)
|
|
return null // Since this proc gets used in a for loop, null won't be looped though.
|
|
|
|
return corners
|
|
|
|
/turf/proc/generate_missing_corners()
|
|
lighting_corners_initialised = TRUE
|
|
if(!corners)
|
|
corners = list(null, null, null, null)
|
|
|
|
for(var/i = 1 to 4)
|
|
if(corners[i]) // Already have a corner on this direction.
|
|
continue
|
|
|
|
corners[i] = new /datum/lighting_corner(src, LIGHTING_CORNER_DIAGONAL[i])
|