mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-23 00:31:57 +00:00
b419782526
tgstation/tgstation#27881 There is now a second bluespace shelter capsule, which is much more fancy & expensive. Note, this still does not make them generally available. Changes Summary: - Added "Shelter Beta" - It comes with a built in kitchen, toilet, shower, three course meal, and an artifact™️! There are plenty of secrets to behold.. - Added black carpeting. This can be created by the personal crafting menu and having any crayon + a carpet with you. - Added fancy wooden and fancy black wooden tables. These are craftable by hitting wooden table parts with regular and black carpet, respectively. - You can now unanchor, deconstruct and color shower curtains. Use any kind of crayon to color them, and screwdriver to unanchor them. Once they are unanchored, you may use wirecutters to change them back into materials- All of which are used in a new crafting recipe for creating them. - Display cases moderately refactored. - Added survival pod windows/windoors for the new luxury pod.
57 lines
1.9 KiB
Plaintext
57 lines
1.9 KiB
Plaintext
/datum/map_template/shelter
|
|
var/shelter_id
|
|
var/description
|
|
var/blacklisted_turfs
|
|
var/whitelisted_turfs
|
|
var/banned_areas
|
|
|
|
/datum/map_template/shelter/New()
|
|
. = ..()
|
|
blacklisted_turfs = typecacheof(list(/turf/simulated/wall, /turf/simulated/mineral, /turf/simulated/shuttle/wall))
|
|
whitelisted_turfs = list()
|
|
banned_areas = typecacheof(/area/shuttle)
|
|
|
|
/datum/map_template/shelter/proc/check_deploy(turf/deploy_location)
|
|
var/affected = get_affected_turfs(deploy_location, centered=TRUE)
|
|
for(var/turf/T in affected)
|
|
var/area/A = get_area(T)
|
|
if(is_type_in_typecache(A, banned_areas))
|
|
return SHELTER_DEPLOY_BAD_AREA
|
|
|
|
var/banned = is_type_in_typecache(T, blacklisted_turfs)
|
|
var/permitted = is_type_in_typecache(T, whitelisted_turfs)
|
|
if(banned && !permitted)
|
|
return SHELTER_DEPLOY_BAD_TURFS
|
|
|
|
for(var/obj/O in T)
|
|
if(O.density && O.anchored)
|
|
return SHELTER_DEPLOY_ANCHORED_OBJECTS
|
|
return SHELTER_DEPLOY_ALLOWED
|
|
|
|
/datum/map_template/shelter/alpha
|
|
name = "Shelter Alpha"
|
|
shelter_id = "shelter_alpha"
|
|
description = "A cosy self-contained pressurized shelter, with \
|
|
built-in navigation, entertainment, medical facilities and a \
|
|
sleeping area! Order now, and we'll throw in a TINY FAN, \
|
|
absolutely free!"
|
|
mappath = "_maps/map_files/templates/shelter_1.dmm"
|
|
|
|
/datum/map_template/shelter/alpha/New()
|
|
. = ..()
|
|
whitelisted_turfs = typecacheof(/turf/simulated/mineral)
|
|
|
|
/datum/map_template/shelter/beta
|
|
name = "Shelter Beta"
|
|
shelter_id = "shelter_beta"
|
|
description = "An extremly luxurious shelter, containing all \
|
|
the amenities of home, including carpeted floors, hot and cold \
|
|
running water, a gourmet three course meal, cooking facilities, \
|
|
and a deluxe companion to keep you from getting lonely during \
|
|
an ash storm."
|
|
mappath = "_maps/map_files/templates/shelter_2.dmm"
|
|
|
|
/datum/map_template/shelter/beta/New()
|
|
. = ..()
|
|
whitelisted_turfs = typecacheof(/turf/simulated/mineral)
|