mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-08-20 18:47:20 +01:00
d90a70ecda
* IT WORKS UP UNTIL THIS POINT * Consolidates SLOT_FLAG and SLOT_HUD into one * Remove cover_both_ears * SLOT_HUD to ITEM_SLOT * Remove clothing_trait changes for the time being * Remove accidental copy-paste * Re-add no-slip var * More failure to copy-paste correctly * Leftover flag * Combine left and right slot flags where possible * UNGOOF MY DEFINES, PHAND IS NOT A THING * Minor spacing changes * Some more fixes from merge * Seperates ITEM SLOT AMOUNT into two defines * ON SECOND THOUGHT LETS NOT DO THAT. * Addresses Contra's review * Thank you GREP * Rename ITEM_SLOT_FEET to ITEM_SLOT_SHOES * Added a comment to the bitmasks in clothing defines * Rename ITEM_SLOT_TIE to ITEM_SLOT_ACCESSORY * These are for a seperate PR. * Magboot fixes * Requested changes * Re-add accidental removal * Wrong flags * Update code/__DEFINES/clothing_defines.dm Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com> Signed-off-by: Chap <erwin@lombok.demon.nl> * Requested changes * Merge fixes * Fix double headset * Fixes multiple accessories --------- Signed-off-by: Chap <erwin@lombok.demon.nl> Co-authored-by: Adrer <adrermail@gmail.com> Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com>
94 lines
2.7 KiB
Plaintext
94 lines
2.7 KiB
Plaintext
/obj/item/clothing/ears/headphones
|
|
name = "headphones"
|
|
desc = "Unce unce unce unce."
|
|
icon_state = "headphones0"
|
|
item_state = "headphones0"
|
|
actions_types = list(/datum/action/item_action/change_headphones_song, /datum/action/item_action/toggle_music_notes)
|
|
var/datum/song/headphones/song
|
|
var/on = FALSE
|
|
|
|
/obj/item/clothing/ears/headphones/Initialize(mapload)
|
|
. = ..()
|
|
song = new(src, "piano") // Piano is the default instrument but all instruments are allowed
|
|
song.instrument_range = 0
|
|
song.allowed_instrument_ids = SSinstruments.synthesizer_instrument_ids
|
|
// To update the icon
|
|
RegisterSignal(src, COMSIG_SONG_START, PROC_REF(start_playing))
|
|
RegisterSignal(src, COMSIG_SONG_END, PROC_REF(stop_playing))
|
|
|
|
/obj/item/clothing/ears/headphones/Destroy()
|
|
QDEL_NULL(song)
|
|
return ..()
|
|
|
|
/obj/item/clothing/ears/headphones/ui_action_click(mob/user, actiontype)
|
|
if(actiontype == /datum/action/item_action/change_headphones_song)
|
|
ui_interact(user)
|
|
else if(actiontype == /datum/action/item_action/toggle_music_notes)
|
|
toggle_visual_notes(user)
|
|
|
|
for(var/X in actions)
|
|
var/datum/action/A = X
|
|
A.UpdateButtons()
|
|
|
|
/obj/item/clothing/ears/headphones/proc/toggle_visual_notes(mob/user)
|
|
on = !on
|
|
update_icon(UPDATE_ICON_STATE)
|
|
user.regenerate_icons()
|
|
|
|
/obj/item/clothing/ears/headphones/ui_data(mob/user)
|
|
return song.ui_data(user)
|
|
|
|
/obj/item/clothing/ears/headphones/ui_interact(mob/user)
|
|
if(should_stop_playing(user) || user.incapacitated())
|
|
return
|
|
song.ui_interact(user)
|
|
|
|
/obj/item/clothing/ears/headphones/ui_act(action, params)
|
|
if(..())
|
|
return
|
|
return song.ui_act(action, params)
|
|
|
|
/obj/item/clothing/ears/headphones/update_icon_state()
|
|
var/mob/living/carbon/human/user = loc
|
|
if(istype(user))
|
|
user.update_action_buttons_icon()
|
|
user.update_inv_ears()
|
|
icon_state = item_state = "headphones[on]"
|
|
|
|
/obj/item/clothing/ears/headphones/item_action_slot_check(slot)
|
|
if(slot & ITEM_SLOT_BOTH_EARS)
|
|
return TRUE
|
|
|
|
/**
|
|
* Called by a component signal when our song starts playing.
|
|
*/
|
|
/obj/item/clothing/ears/headphones/proc/start_playing()
|
|
on = TRUE
|
|
update_icon(UPDATE_ICON_STATE)
|
|
|
|
/**
|
|
* Called by a component signal when our song stops playing.
|
|
*/
|
|
/obj/item/clothing/ears/headphones/proc/stop_playing()
|
|
on = FALSE
|
|
update_icon(UPDATE_ICON_STATE)
|
|
|
|
/**
|
|
* Whether the headphone's song should stop playing
|
|
*
|
|
* Arguments:
|
|
* * user - The user
|
|
*/
|
|
/obj/item/clothing/ears/headphones/proc/should_stop_playing(mob/living/carbon/human/user)
|
|
return !(src in user) || !istype(user) || !((src == user.l_ear) || (src == user.r_ear))
|
|
|
|
// special subtype so it uses the correct item type
|
|
/datum/song/headphones
|
|
|
|
/datum/song/headphones/should_stop_playing(mob/user)
|
|
. = ..()
|
|
if(.)
|
|
return TRUE
|
|
var/obj/item/clothing/ears/headphones/I = parent
|
|
return I.should_stop_playing(user)
|