mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-10 09:31:52 +00:00
346a1b8142
* Initial commit Fixes up surgery.dm Adds some tool behavior * More basic changes * Checkpointing: this is a little gross right now * Add signal COMPONENT_CANCEL_ATTACK_CHAIN * Cleans up surgery initiator * Mostly gets surgery (and canceling it) working * Add abstract proxy surgery steps Also adds them to organ manipulation * Clean up most existing surgeries * Rework organ openness, adds define for aborting a beginstep * surgery works again, also implements retry defines * fix surgery computer * add limb repair to synth implant removal * retry implant checks * Clean up abductor surgeries as well as some other things * A lot - Reworks organ manipulation to use a series of surgery steps instead - Fixes some runtimes with open hands - Lets mito zero out the germ level while treating necrosis - Adds a debug surgery tool * add debug surgery tool, note some TODOs for later * Add conditional check for surgeries repeating * update surgery retry logic to make it more of a bonus * Lets abductors automatically retry any failed surgery steps * Rework robotic surgery to use abstract/proxy steps * Bunch of bugfixes and more! - Limb reattachment works properly now, you can just slap a limb onto a person - If the limb isn't robotic, it'll be useless until the surgery is finished with a hemostat, though it might be enough to get the patient out of the OR. * Remove more now-implicit checks * Slight reorganization * more fixes across the board * Remove unused variable * Trying not to lose my mind here - Does away with can_run() entirely - Cleans up visible messages in code - begin steps should now all have ..() afterwards - slime bone surgery should be fixed now - more docs * Robotic surgery is stoppable with a crowbar, all surgery can_start now checks parent * Fix some broken robotic typepaths * Typepath fixes, do away with some last TODOs * Forgor * Last cleanups before we go gold * jk lol * Make early surgery termination clearer * More "last" cleanups * Fixes tool flags, surgery initiation - Fixes surgery not being startable by sharp objects - Moves surgical tool flags to item traits * Clean up surgery cancellation, especially for borgos * I think this should GC better * Apply suggestions from code review Co-authored-by: Sirryan2002 <80364400+Sirryan2002@users.noreply.github.com> * Status is now step number * Add a 20% chance to find nothing during organ manipulation * Improve documentation, make forced_surgery a normal arg * Charlie's reviews * Why are abductors like this * Little more verification, ensuring limb augmentation and organ manip healing work properly * Fix torso organ manip being unfinishable * Fix cavity implants, open-hand/any item steps * Make sharp objects not try to start an operation with help intent * Comments, quick target fix * Re-order list so advanced bruise pack is pulled first * Make surgical gripper function like an open hand * Make mito only use one unit per organ for now * Check if user is on operable surface before trying to operate * Reduce admin logging * Fix some bugs that appeared during the testmerge - you can no longer start robotic surgeries with a scalpel (lol) - you can now cancel surgeries on the first step after I fixed some bugs that I introduced (woo hoo) - Synthetic limb attachment is now combined into a single startable surgery step, though still retains the fun flavor of both * Swats some more bugs - (hopefully) fixes a huge source of runtimes where we tried to check if we could run surgeries before checking if the surgery used an organ - In doing so, moves the logic for determining if a surgery can start to the mob-level - Fixes robotic reattachment surgery not working * multi-bug drifting??? - Fixes a bug where a branching surgery with an any tool option could possibly override a step with a matching tool - Fixes some intermediate surgeries failing due to not having specified possible_locs * A few more fixes - Fixes any surgery tool steps again - Fixes cavity surgery again * Hopefully fixes getting stuck in robotic organ manip * Remove extra parent call * Steel review * Steel review * Fix spacing for possible locs * Roundstart traits * Advanced surgical traits and other hal fixes Co-authored-by: Sirryan2002 <80364400+Sirryan2002@users.noreply.github.com>
232 lines
9.7 KiB
Plaintext
232 lines
9.7 KiB
Plaintext
//Procedures in this file: Inernal wound patching, Implant removal.
|
|
//////////////////////////////////////////////////////////////////
|
|
// INTERNAL WOUND PATCHING //
|
|
//////////////////////////////////////////////////////////////////
|
|
|
|
/datum/surgery/infection
|
|
name = "External Infection Treatment"
|
|
steps = list(/datum/surgery_step/generic/cut_open, /datum/surgery_step/generic/cauterize)
|
|
possible_locs = list(BODY_ZONE_CHEST, BODY_ZONE_HEAD, BODY_ZONE_PRECISE_GROIN, BODY_ZONE_L_ARM, BODY_ZONE_R_ARM, BODY_ZONE_L_LEG, BODY_ZONE_R_LEG, BODY_ZONE_PRECISE_R_HAND, BODY_ZONE_PRECISE_L_HAND, BODY_ZONE_PRECISE_R_FOOT, BODY_ZONE_PRECISE_L_FOOT)
|
|
|
|
/datum/surgery/bleeding
|
|
name = "Internal Bleeding"
|
|
steps = list(
|
|
/datum/surgery_step/generic/cut_open,
|
|
/datum/surgery_step/generic/clamp_bleeders,
|
|
/datum/surgery_step/generic/retract_skin,
|
|
/datum/surgery_step/proxy/open_organ,
|
|
/datum/surgery_step/generic/cauterize
|
|
)
|
|
possible_locs = list(BODY_ZONE_CHEST, BODY_ZONE_HEAD, BODY_ZONE_PRECISE_GROIN, BODY_ZONE_L_ARM, BODY_ZONE_R_ARM, BODY_ZONE_L_LEG, BODY_ZONE_R_LEG, BODY_ZONE_PRECISE_R_HAND, BODY_ZONE_PRECISE_L_HAND, BODY_ZONE_PRECISE_R_FOOT, BODY_ZONE_PRECISE_L_FOOT)
|
|
|
|
/datum/surgery/debridement
|
|
name = "Debridement"
|
|
steps = list(
|
|
/datum/surgery_step/generic/cut_open,
|
|
/datum/surgery_step/generic/clamp_bleeders,
|
|
/datum/surgery_step/generic/retract_skin,
|
|
/datum/surgery_step/proxy/open_organ,
|
|
/datum/surgery_step/fix_dead_tissue,
|
|
/datum/surgery_step/treat_necrosis,
|
|
/datum/surgery_step/generic/cauterize
|
|
)
|
|
possible_locs = list(BODY_ZONE_CHEST, BODY_ZONE_HEAD, BODY_ZONE_PRECISE_GROIN, BODY_ZONE_L_ARM, BODY_ZONE_R_ARM, BODY_ZONE_L_LEG, BODY_ZONE_R_LEG, BODY_ZONE_PRECISE_R_HAND, BODY_ZONE_PRECISE_L_HAND, BODY_ZONE_PRECISE_R_FOOT, BODY_ZONE_PRECISE_L_FOOT)
|
|
requires_organic_bodypart = TRUE
|
|
|
|
/datum/surgery/bleeding/can_start(mob/user, mob/living/carbon/target)
|
|
. = ..()
|
|
if(!.)
|
|
return FALSE
|
|
var/obj/item/organ/external/affected = target.get_organ(user.zone_selected)
|
|
if(affected.status & ORGAN_INT_BLEEDING)
|
|
return TRUE
|
|
return FALSE
|
|
|
|
/datum/surgery/debridement/can_start(mob/user, mob/living/carbon/target)
|
|
. = ..()
|
|
if(!.)
|
|
return FALSE
|
|
var/obj/item/organ/external/affected = target.get_organ(user.zone_selected)
|
|
if(!(affected.status & ORGAN_DEAD))
|
|
return FALSE
|
|
return TRUE
|
|
|
|
|
|
/datum/surgery_step/fix_vein
|
|
name = "mend internal bleeding"
|
|
allowed_tools = list(
|
|
TOOL_FIXOVEIN = 100,
|
|
/obj/item/stack/cable_coil = 90
|
|
)
|
|
can_infect = TRUE
|
|
blood_level = SURGERY_BLOODSPREAD_HANDS
|
|
|
|
time = 3.2 SECONDS
|
|
|
|
/datum/surgery_step/fix_vein/begin_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
if(!(affected.status & ORGAN_INT_BLEEDING))
|
|
to_chat(user, "<span class='notice'>The veins in [affected] seem to be in perfect shape!</span>")
|
|
return SURGERY_BEGINSTEP_SKIP
|
|
|
|
user.visible_message(
|
|
"[user] starts patching the damaged vein in [target]'s [affected.name] with \the [tool].",
|
|
"You start patching the damaged vein in [target]'s [affected.name] with \the [tool]."
|
|
)
|
|
target.custom_pain("The pain in your [affected.name] is unbearable!")
|
|
return ..()
|
|
|
|
|
|
/datum/surgery_step/fix_vein/end_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
user.visible_message(
|
|
"<span class='notice'> [user] has patched the damaged vein in [target]'s [affected.name] with \the [tool].</span>",
|
|
"<span class='notice'> You have patched the damaged vein in [target]'s [affected.name] with \the [tool].</span>"
|
|
)
|
|
|
|
affected.fix_internal_bleeding()
|
|
if(ishuman(user) && prob(40))
|
|
var/mob/living/carbon/human/U = user
|
|
U.bloody_hands(target, 0)
|
|
|
|
return SURGERY_STEP_CONTINUE
|
|
|
|
/datum/surgery_step/fix_vein/fail_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
user.visible_message(
|
|
"<span class='warning'> [user]'s hand slips, smearing [tool] in the incision in [target]'s [affected.name]!</span>",
|
|
"<span class='warning'> Your hand slips, smearing [tool] in the incision in [target]'s [affected.name]!</span>"
|
|
)
|
|
affected.receive_damage(5, 0)
|
|
|
|
return SURGERY_STEP_RETRY
|
|
|
|
/datum/surgery_step/fix_dead_tissue //Debridement
|
|
name = "remove dead tissue"
|
|
allowed_tools = list(
|
|
TOOL_SCALPEL = 100,
|
|
/obj/item/kitchen/knife = 90,
|
|
/obj/item/shard = 60
|
|
)
|
|
|
|
can_infect = TRUE
|
|
blood_level = SURGERY_BLOODSPREAD_HANDS
|
|
|
|
time = 1.6 SECONDS
|
|
|
|
/datum/surgery_step/fix_dead_tissue/begin_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
user.visible_message(
|
|
"[user] starts cutting away necrotic tissue in [target]'s [affected.name] with \the [tool].",
|
|
"You start cutting away necrotic tissue in [target]'s [affected.name] with \the [tool]."
|
|
)
|
|
target.custom_pain("The pain in [affected.name] is unbearable!")
|
|
return ..()
|
|
|
|
/datum/surgery_step/fix_dead_tissue/end_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
user.visible_message(
|
|
"<span class='notice'> [user] has cut away necrotic tissue in [target]'s [affected.name] with \the [tool].</span>",
|
|
"<span class='notice'> You have cut away necrotic tissue in [target]'s [affected.name] with \the [tool].</span>"
|
|
)
|
|
affected.open = ORGAN_ORGANIC_OPEN
|
|
|
|
return SURGERY_STEP_CONTINUE
|
|
|
|
/datum/surgery_step/fix_dead_tissue/fail_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
user.visible_message(
|
|
"<span class='warning'> [user]'s hand slips, slicing an artery inside [target]'s [affected.name] with \the [tool]!</span>",
|
|
"<span class='warning'> Your hand slips, slicing an artery inside [target]'s [affected.name] with \the [tool]!</span>"
|
|
)
|
|
affected.receive_damage(20)
|
|
|
|
return SURGERY_STEP_RETRY
|
|
|
|
/datum/surgery_step/treat_necrosis
|
|
name = "treat necrosis"
|
|
allowed_tools = list(
|
|
/obj/item/reagent_containers/dropper = 100,
|
|
/obj/item/reagent_containers/glass/bottle = 90,
|
|
/obj/item/reagent_containers/food/drinks/drinkingglass = 85,
|
|
/obj/item/reagent_containers/food/drinks/bottle = 80,
|
|
/obj/item/reagent_containers/glass/beaker = 75,
|
|
/obj/item/reagent_containers/spray = 60,
|
|
/obj/item/reagent_containers/glass/bucket = 50
|
|
)
|
|
|
|
can_infect = FALSE
|
|
blood_level = SURGERY_BLOODSPREAD_NONE
|
|
|
|
time = 2.4 SECONDS
|
|
|
|
|
|
/datum/surgery_step/treat_necrosis/tool_check(mob/user, obj/item/tool)
|
|
. = ..()
|
|
var/obj/item/reagent_containers/container = tool
|
|
if(!container.reagents.has_reagent("mitocholide"))
|
|
user.visible_message(
|
|
"[user] looks at \the [tool] and ponders.",
|
|
"You are not sure if \the [tool] contains the mitocholide necessary to treat the necrosis.")
|
|
return FALSE
|
|
|
|
/datum/surgery_step/treat_necrosis/begin_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
|
|
if(!(affected.status & ORGAN_DEAD))
|
|
to_chat(user, "<span class='warning'>The [affected] seems to already be in fine condition!")
|
|
return SURGERY_BEGINSTEP_SKIP
|
|
|
|
user.visible_message(
|
|
"[user] starts applying medication to the affected tissue in [target]'s [affected.name] with \the [tool].",
|
|
"You start applying medication to the affected tissue in [target]'s [affected.name] with \the [tool]."
|
|
)
|
|
target.custom_pain("Something in your [affected.name] is causing you a lot of pain!")
|
|
return ..()
|
|
|
|
/datum/surgery_step/treat_necrosis/end_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
|
|
var/obj/item/reagent_containers/container = tool
|
|
var/mitocholide = FALSE
|
|
|
|
if(container.reagents.has_reagent("mitocholide"))
|
|
mitocholide = TRUE
|
|
|
|
var/trans = container.reagents.trans_to(target, container.amount_per_transfer_from_this)
|
|
if(trans > 0)
|
|
container.reagents.reaction(target, REAGENT_INGEST) //technically it's contact, but the reagents are being applied to internal tissue
|
|
|
|
if(mitocholide)
|
|
affected.status &= ~ORGAN_DEAD
|
|
affected.germ_level = 0
|
|
target.update_body()
|
|
|
|
user.visible_message(
|
|
"<span class='notice'> [user] applies [trans] units of the solution to affected tissue in [target]'s [affected.name]</span>",
|
|
"<span class='notice'> You apply [trans] units of the solution to affected tissue in [target]'s [affected.name] with \the [tool].</span>"
|
|
)
|
|
|
|
return SURGERY_STEP_CONTINUE
|
|
|
|
/datum/surgery_step/treat_necrosis/fail_step(mob/living/user, mob/living/carbon/human/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
var/obj/item/organ/external/affected = target.get_organ(target_zone)
|
|
|
|
if(!istype(tool, /obj/item/reagent_containers))
|
|
return SURGERY_STEP_INCOMPLETE
|
|
|
|
var/obj/item/reagent_containers/container = tool
|
|
|
|
var/trans = container.reagents.trans_to(target, container.amount_per_transfer_from_this)
|
|
container.reagents.reaction(target, REAGENT_INGEST) //technically it's contact, but the reagents are being applied to internal tissue
|
|
|
|
user.visible_message(
|
|
"<span class='warning'> [user]'s hand slips, applying [trans] units of the solution to the wrong place in [target]'s [affected.name] with the [tool]!</span>",
|
|
"<span class='warning'> Your hand slips, applying [trans] units of the solution to the wrong place in [target]'s [affected.name] with the [tool]!</span>"
|
|
)
|
|
|
|
//no damage or anything, just wastes medicine
|
|
|
|
return SURGERY_STEP_RETRY
|