mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-24 00:12:07 +00:00
65ab4a5d89
* areas * progress... * death hatred and murder * get current master maps * hoooly shit i can load up the maps * it compiles now * map changes * fixes some unintended stuff * make the .dme right * fix mixed space+tab indents * more space-tab fixes * CI, please show me more than 1 CI fail at a time * UPDATE PATHS!!! * none of the stations had it anyways, but fixed * mint wasnt actually deleted, my bad * epic random CI fail for no reason * i beg you, CI * dont delete anything * okay THAT should work now * okay get master maps and rerun * okay THEN run update paths * actually done now * oops
69 lines
3.1 KiB
Plaintext
69 lines
3.1 KiB
Plaintext
/datum/event/prison_break
|
|
startWhen = 5
|
|
announceWhen = 75
|
|
|
|
var/releaseWhen = 60
|
|
var/list/area/areas = list() //List of areas to affect. Filled by start()
|
|
|
|
var/eventDept = "Security" //Department name in announcement
|
|
var/list/areaName = list("Brig") //Names of areas mentioned in AI and Engineering announcements
|
|
var/list/areaType = list(/area/station/security/prison, /area/station/security/brig, /area/station/security/permabrig) //Area types to include.
|
|
var/list/areaNotType = list() //Area types to specifically exclude.
|
|
|
|
/datum/event/prison_break/virology
|
|
eventDept = "Medical"
|
|
areaName = list("Virology")
|
|
areaType = list(/area/station/medical/virology, /area/station/medical/virology/lab)
|
|
|
|
/datum/event/prison_break/xenobiology
|
|
eventDept = "Science"
|
|
areaName = list("Xenobiology")
|
|
areaType = list(/area/station/science/xenobiology)
|
|
areaNotType = list(/area/station/science/xenobiology/xenoflora, /area/station/science/xenobiology/xenoflora_storage)
|
|
|
|
/datum/event/prison_break/station
|
|
eventDept = "Station"
|
|
areaName = list("Brig","Virology","Xenobiology")
|
|
areaType = list(/area/station/security/prison, /area/station/security/brig, /area/station/security/permabrig, /area/station/medical/virology, /area/station/medical/virology/lab, /area/station/science/xenobiology)
|
|
areaNotType = list(/area/station/science/xenobiology/xenoflora, /area/station/science/xenobiology/xenoflora_storage)
|
|
|
|
|
|
/datum/event/prison_break/setup()
|
|
announceWhen = rand(75, 105)
|
|
releaseWhen = rand(60, 90)
|
|
|
|
src.endWhen = src.releaseWhen+2
|
|
|
|
|
|
/datum/event/prison_break/announce()
|
|
if(areas && areas.len > 0)
|
|
GLOB.minor_announcement.Announce("[pick("Gr3y.T1d3 virus","Malignant trojan")] detected in [station_name()] [(eventDept == "Security")? "imprisonment":"containment"] subroutines. Secure any compromised areas immediately. Station AI involvement is recommended.", "[eventDept] Alert")
|
|
|
|
/datum/event/prison_break/start()
|
|
for(var/area/A in world)
|
|
if(is_type_in_list(A,areaType) && !is_type_in_list(A,areaNotType))
|
|
areas += A
|
|
|
|
if(areas && areas.len > 0)
|
|
var/my_department = "[station_name()] firewall subroutines"
|
|
var/rc_message = "An unknown malicious program has been detected in the [english_list(areaName)] lighting and airlock control systems at [station_time_timestamp()]. Systems will be fully compromised within approximately three minutes. Direct intervention is required immediately.<br>"
|
|
for(var/obj/machinery/message_server/MS in GLOB.machines)
|
|
MS.send_rc_message("Engineering", my_department, rc_message, "", "", 2)
|
|
for(var/mob/living/silicon/ai/A in GLOB.player_list)
|
|
to_chat(A, "<span class='danger'>Malicious program detected in the [english_list(areaName)] lighting and airlock control systems by [my_department].</span>")
|
|
|
|
else
|
|
stack_trace("Could not initiate grey-tide. Unable to find suitable containment area.")
|
|
kill()
|
|
|
|
/datum/event/prison_break/tick()
|
|
if(activeFor == releaseWhen)
|
|
if(areas && areas.len > 0)
|
|
for(var/area/A in areas)
|
|
for(var/obj/machinery/light/L in A)
|
|
L.flicker(10)
|
|
|
|
/datum/event/prison_break/end()
|
|
for(var/area/A in shuffle(areas))
|
|
A.prison_break()
|