mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-30 03:12:53 +00:00
525c68d617
* refactor: Attack chain, initial setup. * migrate curtain to make dreamchecker happy * update thurible * don't call attacked_by separately for legacy attack chain * remove duplicate proc * condense similar code, put allowances for legacy code in new procs * update docs, include diagram source * add comment on how to update diagram * fix admonition * mindflayer updates * remove commented out code * clarify all steps * after_attack should be overridable * whoops * retrofit recent changes * duh, can't restrict this yet because of tool_acts * i hate ore bags with the fire of a thousand suns * return correct value for object attack logic * Various cleanups. We don't want to attempt to pull stuff out of `/obj/item/attackby`, because those pieces are part of the related objects' migrations, not `/obj/item` itself. Attempting to do this causes knockon effects where things expected to call e.g. `/obj/item/storage/attackby` in the call chain were not ferried over to the new item interaction code, because the related objects hadn't actually been migrated over yet. I've used refactoring /obj/vehicle as the example for migrating `attackby` methods instead. * simplify some argument names * fuck it * make it do the thing * Rename CI module call * Prove that CI works * improve test output * aaand fix it again * fix curtain tool interactions * fix compile error * fix compile error * Better docs, introduce migration plan tool.
82 lines
2.5 KiB
Plaintext
82 lines
2.5 KiB
Plaintext
//Also contains /obj/structure/closet/body_bag because I doubt anyone would think to look for bodybags in /object/structures
|
|
|
|
/obj/item/bodybag
|
|
name = "body bag"
|
|
desc = "A folded bag designed for the storage and transportation of cadavers."
|
|
icon = 'icons/obj/bodybag.dmi'
|
|
icon_state = "bodybag_folded"
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
|
|
/obj/item/bodybag/attack_self__legacy__attackchain(mob/user)
|
|
var/obj/structure/closet/body_bag/R = new /obj/structure/closet/body_bag(user.loc)
|
|
R.add_fingerprint(user)
|
|
qdel(src)
|
|
|
|
/obj/structure/closet/body_bag
|
|
name = "body bag"
|
|
desc = "A plastic bag designed for the storage and transportation of cadavers."
|
|
icon = 'icons/obj/bodybag.dmi'
|
|
icon_state = "bodybag"
|
|
enable_door_overlay = FALSE
|
|
door_anim_time = 0
|
|
density = FALSE
|
|
integrity_failure = 0
|
|
open_sound = 'sound/items/zip.ogg'
|
|
close_sound = 'sound/items/zip.ogg'
|
|
open_sound_volume = 15
|
|
close_sound_volume = 15
|
|
var/item_path = /obj/item/bodybag
|
|
|
|
/obj/structure/closet/body_bag/attackby__legacy__attackchain(obj/item/I, mob/user, params)
|
|
if(is_pen(I))
|
|
var/t = rename_interactive(user, I)
|
|
if(isnull(t))
|
|
return
|
|
cut_overlays()
|
|
if(t)
|
|
add_overlay("bodybag_label")
|
|
return
|
|
if(istype(I, /obj/item/wirecutters))
|
|
to_chat(user, "<span class='notice'>You cut the tag off the bodybag.</span>")
|
|
name = initial(name)
|
|
cut_overlays()
|
|
return
|
|
return ..()
|
|
|
|
/obj/structure/closet/body_bag/welder_act(mob/user, obj/item/I)
|
|
return // Can't weld a body bag shut
|
|
|
|
/obj/structure/closet/body_bag/close()
|
|
if(..())
|
|
density = FALSE
|
|
return TRUE
|
|
return FALSE
|
|
|
|
/obj/structure/closet/body_bag/update_overlays()
|
|
. = ..()
|
|
if(name != initial(name))
|
|
. += "bodybag_label"
|
|
|
|
/obj/structure/closet/body_bag/MouseDrop(over_object, src_location, over_location)
|
|
if(over_object == usr && (in_range(src, usr) || usr.contents.Find(src)))
|
|
if(!ishuman(usr) || opened || length(contents))
|
|
return FALSE
|
|
visible_message("<span class='notice'>[usr] folds up [src].</span>")
|
|
new item_path(get_turf(src))
|
|
qdel(src)
|
|
return
|
|
. = ..()
|
|
|
|
/obj/structure/closet/body_bag/relaymove(mob/user)
|
|
if(user.stat)
|
|
return
|
|
|
|
// Make it possible to escape from bodybags in morgues and crematoriums
|
|
if(loc && (isturf(loc) || istype(loc, /obj/structure/morgue) || istype(loc, /obj/structure/crematorium)))
|
|
if(!open())
|
|
to_chat(user, "<span class='notice'>It won't budge!</span>")
|
|
|
|
/obj/structure/closet/body_bag/shove_impact(mob/living/target, mob/living/attacker)
|
|
// no, you can't shove people into a body bag
|
|
return FALSE
|