mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-25 09:41:29 +00:00
98ddced488
* Adds Explorer spawnability, removes Cyberaid gateways
* deletes some REALLY old bloat maps and deletes Gateway.dm
* Fixes runtime, and removes more stuff like gateway config... cause we dont have a gateway anymore
* removes all mention of /obj/machine/gateway
* Goodbye test_tiny and evil_santa 😈
* removed a literal fucking pamphlet
* changes map area name from Gateway to Expedetition
* changes the access from ACCESS_GATEWAY to ACCESS_EXPEDITION
* Revert "Goodbye test_tiny and evil_santa 😈"
This reverts commit eda775ecd5.
* ok deletes evil_santa only
* Fixes a runtime
* Adds new visuals for new area and explorer spawn marker
* Unhides explorers from the pref menu
* adds spawns and fixes the gateways for all maps, adds Expedition room to Cere
* improves and cleans up the expedition room maps, also clothes for Explorers
* GET OUT OF HERE EXAMPLE.
* byebye button
94 lines
2.8 KiB
Plaintext
94 lines
2.8 KiB
Plaintext
/mob/dead/observer/DblClickOn(atom/A, params)
|
|
if(client.click_intercept)
|
|
// Not doing a click intercept here, because otherwise we double-tap with the `ClickOn` proc.
|
|
// But we return here since we don't want to do regular dblclick handling
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(modifiers["middle"]) // Let ghosts point without teleporting
|
|
return
|
|
|
|
if(can_reenter_corpse && mind && mind.current)
|
|
if(A == mind.current || (mind.current in A)) // double click your corpse or whatever holds it
|
|
reenter_corpse() // (cloning scanner, body bag, closet, mech, etc)
|
|
return // seems legit.
|
|
|
|
// Follow !!ALL OF THE THINGS!!
|
|
if(istype(A, /atom/movable) && A != src)
|
|
ManualFollow(A)
|
|
|
|
// Otherwise jump
|
|
else
|
|
forceMove(get_turf(A))
|
|
update_parallax_contents()
|
|
|
|
/mob/dead/observer/ClickOn(atom/A, params)
|
|
if(client.click_intercept)
|
|
client.click_intercept.InterceptClickOn(src, params, A)
|
|
return
|
|
if(world.time <= next_move)
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(check_rights(R_ADMIN, 0)) // Admin click shortcuts
|
|
var/mob/M
|
|
if(modifiers["shift"] && modifiers["ctrl"])
|
|
client.debug_variables(A)
|
|
return
|
|
if(modifiers["ctrl"])
|
|
M = get_mob_in_atom_with_warning(A)
|
|
if(M)
|
|
client.holder.show_player_panel(M)
|
|
return
|
|
if(modifiers["shift"] && modifiers["middle"])
|
|
M = get_mob_in_atom_with_warning(A)
|
|
if(M)
|
|
client.freeze(M)
|
|
return
|
|
if(modifiers["middle"])
|
|
MiddleClickOn(A)
|
|
return
|
|
if(modifiers["shift"])
|
|
ShiftClickOn(A)
|
|
return
|
|
if(modifiers["alt"])
|
|
AltClickNoInteract(src, A)
|
|
return
|
|
// You are responsible for checking config.ghost_interaction when you override this function
|
|
// Not all of them require checking, see below
|
|
A.attack_ghost(src)
|
|
|
|
// We don't need a fucking toggle.
|
|
/mob/dead/observer/ShiftClickOn(atom/A)
|
|
examinate(A)
|
|
|
|
/atom/proc/attack_ghost(mob/user)
|
|
if(SEND_SIGNAL(src, COMSIG_ATOM_ATTACK_GHOST, user) & COMPONENT_CANCEL_ATTACK_CHAIN)
|
|
return TRUE
|
|
|
|
// health + cyborg analyzer for ghosts
|
|
/mob/living/attack_ghost(mob/dead/observer/user)
|
|
if(!istype(user)) // Make sure user is actually an observer. Revenents also use attack_ghost, but do not have the health_scan var.
|
|
return
|
|
if(user.client && user.health_scan)
|
|
if(issilicon(src) || ismachineperson(src))
|
|
robot_healthscan(user, src)
|
|
else if(ishuman(src))
|
|
healthscan(user, src, 1, TRUE)
|
|
return ..()
|
|
|
|
// ---------------------------------------
|
|
// And here are some good things for free:
|
|
// Now you can click through portals, wormholes, and teleporters while observing. -Sayu
|
|
|
|
/obj/machinery/teleport/hub/attack_ghost(mob/user as mob)
|
|
var/obj/machinery/teleport/station/S = power_station
|
|
if(S)
|
|
var/obj/machinery/computer/teleporter/com = S.teleporter_console
|
|
if(com && com.target)
|
|
user.forceMove(get_turf(com.target))
|
|
|
|
/obj/effect/portal/attack_ghost(mob/user as mob)
|
|
if(target)
|
|
user.forceMove(get_turf(target))
|