mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-20 07:12:55 +00:00
6df2c2e3d2
* Ghost bar initial changes * more changes * we ball again brothers * we are (once again) SO back * Update code/modules/admin/verbs/debug.dm Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> * Update code/_onclick/hud/alert.dm Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> * Update code/_onclick/hud/alert.dm Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/game/objects/items/weapons/cards_ids.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * deck of cards and shittt * global placement * Update code/modules/ruins/ghost_bar.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * readded * hotfix * zamn * fixes * greyfix * last of the fixes * can't stop me baby * bam --------- Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com>
58 lines
1.9 KiB
Plaintext
58 lines
1.9 KiB
Plaintext
/datum/spawners_menu
|
|
var/mob/dead/observer/owner
|
|
|
|
/datum/spawners_menu/New(mob/dead/observer/new_owner)
|
|
if(!istype(new_owner))
|
|
qdel(src)
|
|
owner = new_owner
|
|
|
|
/datum/spawners_menu/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = FALSE, datum/ui_state/state = GLOB.observer_state, datum/tgui/master_ui = null)
|
|
ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
|
|
if(!ui)
|
|
ui = new(user, src, ui_key, "SpawnersMenu", "Spawners Menu", 700, 600, master_ui, state = state)
|
|
ui.open()
|
|
|
|
/datum/spawners_menu/ui_data(mob/user)
|
|
var/list/data = list()
|
|
data["spawners"] = list()
|
|
for(var/spawner in GLOB.mob_spawners)
|
|
var/is_perm_spawner = FALSE
|
|
var/list/this = list()
|
|
this["name"] = spawner
|
|
this["desc"] = ""
|
|
this["important_info"] = ""
|
|
this["fluff"] = ""
|
|
this["uids"] = list()
|
|
for(var/spawner_obj in GLOB.mob_spawners[spawner])//each spawner can contain multiple actual spawners, we use only one desc/info
|
|
this["uids"] += "\ref[spawner_obj]"
|
|
if(!this["desc"]) //haven't set descriptions yet
|
|
if(istype(spawner_obj, /obj/effect/mob_spawn))
|
|
var/obj/effect/mob_spawn/MS = spawner_obj
|
|
this["desc"] = MS.description
|
|
this["important_info"] = MS.important_info
|
|
this["fluff"] = MS.flavour_text
|
|
if(MS.permanent)
|
|
is_perm_spawner = TRUE
|
|
else
|
|
var/obj/O = spawner_obj
|
|
this["desc"] = O.desc
|
|
this["amount_left"] = is_perm_spawner ? "Infinite uses" : LAZYLEN(GLOB.mob_spawners[spawner])
|
|
data["spawners"] += list(this)
|
|
return data
|
|
|
|
/datum/spawners_menu/ui_act(action, params)
|
|
if(..())
|
|
return
|
|
var/spawners = replacetext(params["ID"], ",", ";")
|
|
var/list/possible_spawners = params2list(spawners)
|
|
var/obj/effect/mob_spawn/MS = locate(pick(possible_spawners))
|
|
if(!MS || !istype(MS))
|
|
CRASH("A ghost tried to interact with an invalid spawner, or the spawner didn't exist.")
|
|
switch(action)
|
|
if("jump")
|
|
owner.forceMove(get_turf(MS))
|
|
. = TRUE
|
|
if("spawn")
|
|
MS.attack_ghost(owner)
|
|
. = TRUE
|