mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2025-12-19 14:51:27 +00:00
48d7b00a0d
* no more spaces * Matthew 10:22 * fixes * dgamerl review * Update code/modules/hydroponics/plant_genes.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/mob/living/simple_animal/bot/ed209bot.dm * Update code/modules/mob/mob.dm * Update code/modules/mob/mob.dm * Update code/modules/mob/mob.dm * Update code/modules/mob/mob.dm * Update code/modules/mob/mob.dm * Update code/modules/pda/PDA.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * fuck * bah * Update tools/ci/check_grep2.py Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * oops * guh --------- Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com>
125 lines
3.5 KiB
Plaintext
125 lines
3.5 KiB
Plaintext
/turf
|
|
var/dynamic_lighting = TRUE
|
|
luminosity = 1
|
|
|
|
var/tmp/lighting_corners_initialised = FALSE
|
|
|
|
var/tmp/list/datum/light_source/affecting_lights // List of light sources affecting this turf.
|
|
var/tmp/atom/movable/lighting_object/lighting_object // Our lighting object.
|
|
var/tmp/list/datum/lighting_corner/corners
|
|
var/tmp/has_opaque_atom = FALSE // Not to be confused with opacity, this will be TRUE if there's any opaque atom on the tile.
|
|
|
|
// Causes any affecting light sources to be queued for a visibility update, for example a door got opened.
|
|
/turf/proc/reconsider_lights()
|
|
var/datum/light_source/L
|
|
var/thing
|
|
for(thing in affecting_lights)
|
|
L = thing
|
|
L.vis_update()
|
|
|
|
/turf/proc/lighting_clear_overlay()
|
|
if(lighting_object)
|
|
qdel(lighting_object, TRUE)
|
|
|
|
var/datum/lighting_corner/C
|
|
var/thing
|
|
for(thing in corners)
|
|
if(!thing)
|
|
continue
|
|
C = thing
|
|
C.update_active()
|
|
|
|
// Builds a lighting object for us, but only if our area is dynamic.
|
|
/turf/proc/lighting_build_overlay()
|
|
if(lighting_object)
|
|
qdel(lighting_object,force=TRUE) //Shitty fix for lighting objects persisting after death
|
|
|
|
var/area/A = loc
|
|
if(!IS_DYNAMIC_LIGHTING(A) && !light_sources)
|
|
return
|
|
|
|
if(!lighting_corners_initialised)
|
|
generate_missing_corners()
|
|
|
|
new/atom/movable/lighting_object(src)
|
|
|
|
var/thing
|
|
var/datum/lighting_corner/C
|
|
var/datum/light_source/S
|
|
for(thing in corners)
|
|
if(!thing)
|
|
continue
|
|
C = thing
|
|
if(!C.active) // We would activate the corner, calculate the lighting for it.
|
|
for(thing in C.affecting)
|
|
S = thing
|
|
S.recalc_corner(C)
|
|
C.active = TRUE
|
|
|
|
// Used to get a scaled lumcount.
|
|
/turf/proc/get_lumcount(minlum = 0, maxlum = 1)
|
|
if(!lighting_object)
|
|
return 1
|
|
|
|
var/totallums = 0
|
|
var/thing
|
|
var/datum/lighting_corner/L
|
|
for(thing in corners)
|
|
if(!thing)
|
|
continue
|
|
L = thing
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
|
|
totallums /= 12 // 4 corners, each with 3 channels, get the average.
|
|
|
|
totallums = (totallums - minlum) / (maxlum - minlum)
|
|
|
|
return CLAMP01(totallums)
|
|
|
|
// Returns a boolean whether the turf is on soft lighting.
|
|
// Soft lighting being the threshold at which point the overlay considers
|
|
// itself as too dark to allow sight and see_in_dark becomes useful.
|
|
// So basically if this returns true the tile is unlit black.
|
|
/turf/proc/is_softly_lit()
|
|
if(!lighting_object)
|
|
return FALSE
|
|
|
|
return !lighting_object.luminosity
|
|
|
|
// Can't think of a good name, this proc will recalculate the has_opaque_atom variable.
|
|
/turf/proc/recalc_atom_opacity()
|
|
has_opaque_atom = opacity
|
|
if(!has_opaque_atom)
|
|
for(var/atom/A in src.contents) // Loop through every movable atom on our tile PLUS ourselves (we matter too...)
|
|
if(A.opacity)
|
|
has_opaque_atom = TRUE
|
|
break
|
|
|
|
/turf/Exited(atom/movable/Obj, atom/newloc)
|
|
. = ..()
|
|
|
|
if(Obj && Obj.opacity)
|
|
recalc_atom_opacity() // Make sure to do this before reconsider_lights(), incase we're on instant updates.
|
|
reconsider_lights()
|
|
|
|
/turf/proc/change_area(area/old_area, area/new_area)
|
|
if(SSlighting.initialized)
|
|
if(new_area.dynamic_lighting != old_area.dynamic_lighting)
|
|
if(new_area.dynamic_lighting)
|
|
lighting_build_overlay()
|
|
else
|
|
lighting_clear_overlay()
|
|
|
|
/turf/proc/generate_missing_corners()
|
|
if(!IS_DYNAMIC_LIGHTING(src) && !light_sources)
|
|
return
|
|
lighting_corners_initialised = TRUE
|
|
if(!corners)
|
|
corners = list(null, null, null, null)
|
|
|
|
for(var/i = 1 to 4)
|
|
if(corners[i]) // Already have a corner on this direction.
|
|
continue
|
|
|
|
corners[i] = new/datum/lighting_corner(src, GLOB.LIGHTING_CORNER_DIAGONAL[i])
|