mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-03 14:12:29 +00:00
6a876e1994
* Standardizes cleaning item functionality into "cleaning_act" proc * Culling commented-out code * Damp rag now checks for humans before cleaning * Change proc scoping, moved mop reagent check out of cleaning.dm * Adds can_clean and post_clean procs to handle mopping, removes ismop parameter * Adds can_clean() to cleaning objects/mobs * cleaning_act() now carries message strings as params * Refactored cleaning_act() for earlier returns and less redundancy * cleaning_act now runs on the target atom, instead of the cleaning object * Changed turf checks to overrides, rescoped clean_turf, lots of tidying * Removed cleaner param from post_clean, since it'll always be src * Code review tidying * Tidying.......... * Removed clean_turf and put its functionality in turf/simulated/cleaning_act(), added new param to keep track of original targeted object * Moved cleaning.dm from datums to code/game/objects * Added early return, defined cleanspeed in seconds
122 lines
3.8 KiB
Plaintext
122 lines
3.8 KiB
Plaintext
/obj/item/mop
|
|
desc = "The world of janitalia wouldn't be complete without a mop."
|
|
name = "mop"
|
|
icon = 'icons/obj/janitor.dmi'
|
|
icon_state = "mop"
|
|
force = 3
|
|
throwforce = 5
|
|
throw_speed = 3
|
|
throw_range = 7
|
|
w_class = WEIGHT_CLASS_NORMAL
|
|
attack_verb = list("mopped", "bashed", "bludgeoned", "whacked")
|
|
resistance_flags = FLAMMABLE
|
|
var/mopping = 0
|
|
var/mopcount = 0
|
|
var/mopcap = 5
|
|
var/mopspeed = 30
|
|
|
|
/obj/item/mop/New()
|
|
..()
|
|
create_reagents(mopcap)
|
|
GLOB.janitorial_equipment += src
|
|
|
|
/obj/item/mop/Destroy()
|
|
GLOB.janitorial_equipment -= src
|
|
return ..()
|
|
|
|
/obj/item/mop/proc/wet_mop(obj/o, mob/user)
|
|
if(o.reagents.total_volume < 1)
|
|
to_chat(user, "[o] is out of water!</span>")
|
|
if(!istype(o, /obj/item/reagent_containers/glass/bucket))
|
|
janicart_insert(user, o)
|
|
return
|
|
|
|
o.reagents.trans_to(src, 5)
|
|
to_chat(user, "<span class='notice'>You wet [src] in [o].</span>")
|
|
playsound(loc, 'sound/effects/slosh.ogg', 25, 1)
|
|
|
|
/obj/item/mop/afterattack(atom/A, mob/user, proximity)
|
|
if(!proximity)
|
|
return
|
|
if(istype(A, /obj/item/reagent_containers/glass/bucket) || istype(A, /obj/structure/janitorialcart) || istype(A, /obj/structure/mopbucket))
|
|
return
|
|
if(reagents.total_volume < 1)
|
|
to_chat(user, "<span class='warning'>Your mop is dry!</span>")
|
|
return
|
|
A.cleaning_act(user, src, mopspeed, text_verb = "mop", text_description = ".")
|
|
|
|
/obj/item/mop/can_clean()
|
|
if(reagents.has_reagent("water", 1) || reagents.has_reagent("cleaner", 1) || reagents.has_reagent("holywater", 1))
|
|
return TRUE
|
|
else
|
|
return FALSE
|
|
|
|
/obj/item/mop/post_clean(atom/target, mob/user)
|
|
var/turf/T = get_turf(target)
|
|
if(issimulatedturf(T))
|
|
reagents.reaction(T, REAGENT_TOUCH, 10) //10 is the multiplier for the reaction effect. probably needed to wet the floor properly.
|
|
reagents.remove_any(1) //reaction() doesn't use up the reagents
|
|
|
|
/obj/effect/attackby(obj/item/I, mob/user, params)
|
|
if(istype(I, /obj/item/mop) || istype(I, /obj/item/soap))
|
|
return
|
|
else
|
|
return ..()
|
|
|
|
/obj/item/mop/proc/janicart_insert(mob/user, obj/structure/janitorialcart/J)
|
|
J.mymop = src
|
|
J.put_in_cart(src, user)
|
|
|
|
/obj/item/mop/wash(mob/user, atom/source)
|
|
reagents.add_reagent("water", 5)
|
|
to_chat(user, "<span class='notice'>You wet [src] in [source].</span>")
|
|
playsound(loc, 'sound/effects/slosh.ogg', 25, 1)
|
|
return 1
|
|
|
|
/obj/item/mop/advanced
|
|
desc = "The most advanced tool in a custodian's arsenal. Just think of all the viscera you will clean up with this!"
|
|
name = "advanced mop"
|
|
mopcap = 10
|
|
icon_state = "advmop"
|
|
item_state = "mop"
|
|
origin_tech = "materials=3;engineering=3"
|
|
force = 6
|
|
throwforce = 8
|
|
throw_range = 4
|
|
mopspeed = 20
|
|
var/refill_enabled = TRUE //Self-refill toggle for when a janitor decides to mop with something other than water.
|
|
var/refill_rate = 1 //Rate per process() tick mop refills itself
|
|
var/refill_reagent = "water" //Determins what reagent to use for refilling, just in case someone wanted to make a HOLY MOP OF PURGING
|
|
|
|
/obj/item/mop/advanced/New()
|
|
..()
|
|
START_PROCESSING(SSobj, src)
|
|
|
|
/obj/item/mop/advanced/attack_self(mob/user)
|
|
refill_enabled = !refill_enabled
|
|
if(refill_enabled)
|
|
START_PROCESSING(SSobj, src)
|
|
else
|
|
STOP_PROCESSING(SSobj, src)
|
|
to_chat(user, "<span class='notice'>You set the condenser switch to the '[refill_enabled ? "ON" : "OFF"]' position.</span>")
|
|
playsound(user, 'sound/machines/click.ogg', 30, 1)
|
|
|
|
/obj/item/mop/advanced/process()
|
|
|
|
if(reagents.total_volume < mopcap)
|
|
reagents.add_reagent(refill_reagent, refill_rate)
|
|
|
|
/obj/item/mop/advanced/examine(mob/user)
|
|
. = ..()
|
|
. += "<span class='notice'>The condenser switch is set to <b>[refill_enabled ? "ON" : "OFF"]</b>.</span>"
|
|
|
|
/obj/item/mop/advanced/Destroy()
|
|
if(refill_enabled)
|
|
STOP_PROCESSING(SSobj, src)
|
|
return ..()
|
|
|
|
/obj/item/mop/advanced/cyborg
|
|
|
|
/obj/item/mop/advanced/cyborg/janicart_insert(mob/user, obj/structure/janitorialcart/J)
|
|
return
|