mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-08-21 11:07:12 +01:00
f68676267c
* Adds no-harm check to ai retaliate, adjusts clown AI * Update code/modules/mob/living/basic/retaliate/clown.dm Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com> Signed-off-by: PollardTheDragon <144391971+PollardTheDragon@users.noreply.github.com> --------- Signed-off-by: PollardTheDragon <144391971+PollardTheDragon@users.noreply.github.com> Co-authored-by: Contrabang <91113370+Contrabang@users.noreply.github.com>
43 lines
1.5 KiB
Plaintext
43 lines
1.5 KiB
Plaintext
/**
|
|
* Attached to a mob with an AI controller, passes things which have damaged it to a blackboard.
|
|
* The AI controller is responsible for doing anything with that information.
|
|
* Differs from the element as it passes new entries through a callback.
|
|
*/
|
|
/datum/component/ai_retaliate_advanced
|
|
/// Callback to a mob for custom behaviour
|
|
var/datum/callback/post_retaliate_callback
|
|
|
|
/datum/component/ai_retaliate_advanced/Initialize(datum/callback/post_retaliate_callback)
|
|
if(!ismob(parent))
|
|
return ELEMENT_INCOMPATIBLE
|
|
|
|
src.post_retaliate_callback = post_retaliate_callback
|
|
parent.AddElement(/datum/element/relay_attackers)
|
|
|
|
ADD_TRAIT(parent, TRAIT_SUBTREE_REQUIRED_OPERATIONAL_DATUM, type)
|
|
|
|
/datum/component/ai_retaliate_advanced/Destroy(force)
|
|
post_retaliate_callback = null
|
|
return ..()
|
|
|
|
/datum/component/ai_retaliate_advanced/RegisterWithParent()
|
|
RegisterSignal(parent, COMSIG_ATOM_WAS_ATTACKED, PROC_REF(on_attacked))
|
|
|
|
/datum/component/ai_retaliate_advanced/UnregisterFromParent()
|
|
UnregisterSignal(parent, COMSIG_ATOM_WAS_ATTACKED)
|
|
|
|
/// Add an attacking atom to a blackboard list of things which attacked us
|
|
/datum/component/ai_retaliate_advanced/proc/on_attacked(mob/victim, atom/attacker)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!victim.ai_controller)
|
|
return
|
|
|
|
if(isanimal_or_basicmob(attacker)) // Don't retaliate on nuzzles
|
|
var/mob/living/M = attacker
|
|
if(M.a_intent == INTENT_HELP)
|
|
return
|
|
|
|
victim.ai_controller.insert_blackboard_key_lazylist(BB_BASIC_MOB_RETALIATE_LIST, attacker)
|
|
post_retaliate_callback?.InvokeAsync(attacker)
|