mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-25 08:51:41 +00:00
91be8af21b
* Fixing some minor typos for cyborg upgrade flavour text Throws in some missing apostrophes, capitalisation, and the letter "s." * Briefcase Full of Cash buff Increases the amount of cash in the Syndicate Briefcase Full of Cash from 600 Cr to 1000 Cr * Reverts double-feature PR * Reverts a broken revert * Reverting again because Ebba told me to * And reverting yet again * Machine Analyzer Renamed "cyborg analyzer" to "machine analyzer". It now scans machines too. * Refactor Everything is now in scanners.dm yaaaay! * Update code/game/objects/items/devices/scanners.dm Co-authored-by: DGamerL <108773801+DGamerL@users.noreply.github.com> * Update code/game/objects/items/devices/scanners.dm Co-authored-by: DGamerL <108773801+DGamerL@users.noreply.github.com> * Update code/game/objects/items/devices/scanners.dm Co-authored-by: DGamerL <108773801+DGamerL@users.noreply.github.com> * Helper proc woooo * Update code/game/objects/items/devices/scanners.dm Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> * Update code/game/objects/items/devices/scanners.dm Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> * renaming stuff * Update code/modules/research/designs/medical_designs.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update code/modules/research/designs/medical_designs.dm Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com> * Update scanners.dm * Update scanners.dm --------- Co-authored-by: DGamerL <108773801+DGamerL@users.noreply.github.com> Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com> Co-authored-by: Henri215 <77684085+Henri215@users.noreply.github.com>
120 lines
3.6 KiB
Plaintext
120 lines
3.6 KiB
Plaintext
/mob/dead/observer/DblClickOn(atom/A, params)
|
|
if(client.click_intercept)
|
|
// Not doing a click intercept here, because otherwise we double-tap with the `ClickOn` proc.
|
|
// But we return here since we don't want to do regular dblclick handling
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(modifiers["middle"]) // Let ghosts point without teleporting
|
|
return
|
|
|
|
if(can_reenter_corpse && mind && mind.current)
|
|
if(A == mind.current || (mind.current in A)) // double click your corpse or whatever holds it
|
|
reenter_corpse() // (cloning scanner, body bag, closet, mech, etc)
|
|
return // seems legit.
|
|
|
|
// Follow !!ALL OF THE THINGS!!
|
|
if(istype(A, /atom/movable) && A != src)
|
|
ManualFollow(A)
|
|
|
|
// Otherwise jump
|
|
else
|
|
forceMove(get_turf(A))
|
|
update_parallax_contents()
|
|
|
|
/mob/dead/observer/ClickOn(atom/A, params)
|
|
if(client.click_intercept)
|
|
client.click_intercept.InterceptClickOn(src, params, A)
|
|
return
|
|
if(world.time <= next_move)
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(check_rights(R_ADMIN, 0)) // Admin click shortcuts
|
|
var/mob/M
|
|
if(modifiers["shift"] && modifiers["ctrl"])
|
|
client.debug_variables(A)
|
|
return
|
|
if(modifiers["ctrl"])
|
|
M = get_mob_in_atom_with_warning(A)
|
|
if(M)
|
|
client.holder.show_player_panel(M)
|
|
return
|
|
if(modifiers["shift"] && modifiers["middle"])
|
|
M = get_mob_in_atom_with_warning(A)
|
|
if(M)
|
|
client.freeze(M)
|
|
return
|
|
if(modifiers["middle"])
|
|
MiddleClickOn(A)
|
|
return
|
|
if(modifiers["shift"])
|
|
ShiftClickOn(A)
|
|
return
|
|
if(modifiers["alt"])
|
|
AltClickNoInteract(src, A)
|
|
return
|
|
// You are responsible for checking config.ghost_interaction when you override this function
|
|
// Not all of them require checking, see below
|
|
A.attack_ghost(src)
|
|
|
|
// We don't need a fucking toggle.
|
|
/mob/dead/observer/ShiftClickOn(atom/A)
|
|
examinate(A)
|
|
|
|
/mob/dead/observer/AltClickOn(atom/A)
|
|
AltClickNoInteract(src, A)
|
|
|
|
/mob/dead/observer/AltShiftClickOn(atom/A)
|
|
return
|
|
|
|
/mob/dead/observer/CtrlShiftClickOn(atom/A)
|
|
return
|
|
|
|
/mob/dead/observer/MiddleShiftClickOn(atom/A)
|
|
return
|
|
|
|
/mob/dead/observer/MiddleShiftControlClickOn(atom/A)
|
|
return
|
|
|
|
/atom/proc/attack_ghost(mob/user)
|
|
if(SEND_SIGNAL(src, COMSIG_ATOM_ATTACK_GHOST, user) & COMPONENT_CANCEL_ATTACK_CHAIN)
|
|
return TRUE
|
|
|
|
// health + machine analyzer for ghosts
|
|
/mob/living/attack_ghost(mob/dead/observer/user)
|
|
if(!istype(user)) // Make sure user is actually an observer. Revenents also use attack_ghost, but do not have the health_scan var.
|
|
return
|
|
if(user.client && user.health_scan)
|
|
if(issilicon(src) || ismachineperson(src))
|
|
robot_healthscan(user, src)
|
|
else if(ishuman(src))
|
|
healthscan(user, src, 1, TRUE)
|
|
return ..()
|
|
|
|
// ---------------------------------------
|
|
// And here are some good things for free:
|
|
// Now you can click through portals, wormholes, and teleporters while observing. -Sayu
|
|
|
|
/obj/machinery/teleport/hub/attack_ghost(mob/user as mob)
|
|
var/obj/machinery/teleport/station/S = power_station
|
|
if(S)
|
|
var/obj/machinery/computer/teleporter/com = S.teleporter_console
|
|
if(com && com.target)
|
|
user.forceMove(get_turf(com.target))
|
|
|
|
/obj/effect/portal/attack_ghost(mob/user as mob)
|
|
if(target)
|
|
user.forceMove(get_turf(target))
|
|
|
|
/obj/machinery/atmospherics/attack_ghost(mob/dead/observer/user)
|
|
if(!istype(user)) // Make sure user is actually an observer. Revenents also use attack_ghost, but do not have the toggle gas analyzer var.
|
|
return
|
|
if(user.gas_analyzer)
|
|
if(istype(src, /obj/machinery/atmospherics/pipe))
|
|
var/obj/machinery/atmospherics/pipe/T = src
|
|
atmosanalyzer_scan(T.parent.air, user, T)
|
|
else if(istype(src, /obj/machinery/atmospherics/unary))
|
|
var/obj/machinery/atmospherics/unary/T = src
|
|
atmosanalyzer_scan(T.air_contents, user, T)
|