mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-01-14 19:41:53 +00:00
79bad427c8
* refactor: Movement cross/uncross implementation.
* wrong var name
* fix unit tests dropping PDAs into nowhere
* Add documentation.
* remove unused constants
* say which procs are off limits
* fix simpleanimal z change runtime
* helps not to leave merge conflicts
* kill me
* fix typecast
* fix projectile/table collision
* treadmills don't cause MC to crash anymore
* connect_loc is appropriate here
* fix windoors and teleporters
* fix bonfires and clarify docs
* fix proximity sensors
Tested with sensors in crates, sensors in modsuits
Tested new proximity component with firing projectiles at singularity
Tested new proximity component with portable flashes
Tested new proximity component with facehuggers
* lint
* fix: polarized access helper false positives
* Revert "fix: polarized access helper false positives"
This reverts commit 9814f98cf6.
* hopefully the right change for mindflayer steam
* Changes following cameras
* fix glass table collision
* appears to fix doorspam
* fix ore bags not picking up ore
* fix signatures of /Exited
* remove debug log
* remove duplicate signal registrar
* fix emptying bags into locations
* I don't trust these nested Move calls
* use connect_loc for upgraded resonator fields
* use moveToNullspace
* fix spiderweb crossing
* fix pass checking for windows from a tile off
* fix bluespace closet/transparency issues
* fix mechs not interacting with doors and probably other things
* fix debug
* fix telepete
* add some docs
* stop trying to shoehorn prox monitor into cards
* I should make sure things build
* kill override signal warning
* undef signal
* not many prox monitors survive going off like this
* small fixes to storage
* make moving wormholes respect signals
* use correct signals for pulse demon
* fix pulse heart too
* fix smoke signals
* may have fucked singulo projectile swerve
* fix singulo projectile arcing
* remove duplicate define
* just look at it
* hopefully last cleanups of incorrect signal usage
* fix squeaking
* may god have mercy on my soul
* Apply suggestions from code review
Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com>
Signed-off-by: warriorstar-orion <orion@snowfrost.garden>
* lewc review
* Apply suggestions from code review
Co-authored-by: Burzah <116982774+Burzah@users.noreply.github.com>
Signed-off-by: warriorstar-orion <orion@snowfrost.garden>
* burza review
* fix bad args for grenade assemblies
* Update code/__DEFINES/is_helpers.dm
Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com>
Signed-off-by: warriorstar-orion <orion@snowfrost.garden>
---------
Signed-off-by: warriorstar-orion <orion@snowfrost.garden>
Co-authored-by: DGamerL <daan.lyklema@gmail.com>
Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com>
Co-authored-by: Burzah <116982774+Burzah@users.noreply.github.com>
68 lines
2.5 KiB
Plaintext
68 lines
2.5 KiB
Plaintext
/// This component behaves similar to connect_loc, hooking into a signal on a tracked object's turf
|
|
/// It has the ability to react to that signal on behalf of a separate listener however
|
|
/// This has great use, primarily for components, but it carries with it some overhead
|
|
/// So we do it separately as it needs to hold state which is very likely to lead to bugs if it remains as an element.
|
|
/datum/component/connect_loc_behalf
|
|
dupe_mode = COMPONENT_DUPE_UNIQUE
|
|
|
|
/// An assoc list of signal -> procpath to register to the loc this object is on.
|
|
var/list/connections
|
|
var/atom/movable/tracked
|
|
var/atom/tracked_loc
|
|
|
|
/datum/component/connect_loc_behalf/Initialize(atom/movable/tracked, list/connections)
|
|
. = ..()
|
|
if(!istype(tracked))
|
|
return COMPONENT_INCOMPATIBLE
|
|
src.connections = connections
|
|
src.tracked = tracked
|
|
|
|
/datum/component/connect_loc_behalf/RegisterWithParent()
|
|
RegisterSignal(tracked, COMSIG_MOVABLE_MOVED, PROC_REF(on_moved))
|
|
RegisterSignal(tracked, COMSIG_PARENT_QDELETING, PROC_REF(handle_tracked_qdel))
|
|
update_signals()
|
|
|
|
/datum/component/connect_loc_behalf/UnregisterFromParent()
|
|
unregister_signals()
|
|
UnregisterSignal(tracked, list(
|
|
COMSIG_MOVABLE_MOVED,
|
|
COMSIG_PARENT_QDELETING,
|
|
))
|
|
|
|
tracked = null
|
|
|
|
/datum/component/connect_loc_behalf/proc/handle_tracked_qdel()
|
|
SIGNAL_HANDLER // COMSIG_PARENT_QDELETING
|
|
qdel(src)
|
|
|
|
/datum/component/connect_loc_behalf/proc/update_signals()
|
|
unregister_signals()
|
|
//You may ask yourself, isn't this just silencing an error?
|
|
//The answer is yes, but there's no good cheap way to fix it
|
|
//What happens is the tracked object or hell the listener gets say, deleted, which makes targets[old_loc] return a null
|
|
//The null results in a bad index, because of course it does
|
|
//It's not a solvable problem though, since both actions, the destroy and the move, are sourced from the same signal send
|
|
//And sending a signal should be agnostic of the order of listeners
|
|
//So we need to either pick the order agnositic, or destroy safe
|
|
//And I picked destroy safe. Let's hope this is the right path!
|
|
if(isnull(tracked.loc))
|
|
return
|
|
|
|
tracked_loc = tracked.loc
|
|
|
|
for(var/signal in connections)
|
|
parent.RegisterSignal(tracked_loc, signal, connections[signal])
|
|
|
|
/datum/component/connect_loc_behalf/proc/unregister_signals()
|
|
if(isnull(tracked_loc))
|
|
return
|
|
|
|
parent.UnregisterSignal(tracked_loc, connections)
|
|
|
|
tracked_loc = null
|
|
|
|
/datum/component/connect_loc_behalf/proc/on_moved(sigtype, atom/movable/tracked, atom/old_loc)
|
|
SIGNAL_HANDLER // COMSIG_MOVABLE_MOVED
|
|
update_signals()
|
|
|