mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-08-24 04:27:35 +01:00
ContrabangandGitHub
3f87165a03
* CI change * world.dm * .dme world.dm * subsystem renaming * .dme for subsystems * ai_laws.dm * armor.dm * emote.dm * logging.dm * spell.dm * air_alarm.dm * crew.dm * decal.dm * emissive_blocker.dm * footstep.dm * spawner.dm * fire.dm * carbon.dm * living.dm * mob.dm * movement.dm * thermal_drill.dm * plasmamen.dm * lavaland.dm * chaplain.dm * lightning.dm * magnet.dm * mimic.dm * wizard.dm * morph.dm * vampire.dm * click.dm * self.dm * radiation_storm.dm * airlock.dm * autolathe.dm * mulebot.dm * nuclearbomb.dm * particle_accelerator.dm * smartfridge.dm * syndicatebomb.dm * vending.dm * wires.dm * sound.dm * mining.dm * syndicate_space_base.dm * monkey.dm * guardian.dm * bomb.dm * standard.dm * nuclear.dm * pinpointer.dm * access.dm * departments.dm * job.dm * science.dm * buttons.dm * cloning.dm * igniter.dm * wishgranter.dm * atmos_control.dm * message.dm * power_monitor.dm * mecha.dm * combat.dm * mining_tools.dm * meteors.dm * spiders.dm * contraband.dm * aliens.dm * uplinks.dm * voice.dm * intercom.dm * lights.dm * robot_items.dm * mineral.dm * dice.dm * extinguisher.dm * paint.dm * signs.dm * staff.dm * smokebomb.dm * boxes.dm * random.dm * janicart.dm * statue.dm * cargo.dm * asteroid.dm * headslug.dm * fulton.dm * atmospherics.dm * pump.dm * corpse.dm * oldstation.dm * gps.dm * preferences.dm * clothing.dm * ears.dm * glasses.dm * boxing.dm * color.dm * renames ninja gear files * recipes.dm * error_handler.dm * anomaly.dm * floorcluwne.dm * undead.dm * overmind.dm * shield.dm * bottle.dm * organ.dm * piano.dm * plasma_fist.dm * language.dm * mob_defines.dm * mob_helpers.dm * damage_procs.dm * _defines.dm * empress.dm and queen.dm * brain.dm * organ file renaming * subsystems.dm * constructs.dm * bot.dm * pet.dm * nature.dm * magic.dm * colors.dm * drugs.dm * medicine.dm * toxins.dm * shuttle.dm * surgery.dm * moves a bunch of define files * traits.dm * names.dm * other_mobs.dm * flags.dm * some final define files * well turns out contractor_pinpointer.dm was taken * I forgot to remove this file * how in the hell did this get unticked * I DID INCLUDE IT, but there was a "w" there * swaps the world definitions * camera renamed to SScamera * examine -> alien_examine
86 lines
3.2 KiB
Plaintext
86 lines
3.2 KiB
Plaintext
/datum/wires/syndicatebomb
|
|
randomize = TRUE
|
|
holder_type = /obj/machinery/syndicatebomb
|
|
wire_count = 5
|
|
proper_name = "Syndicate bomb"
|
|
window_x = 320
|
|
window_y = 22
|
|
|
|
/datum/wires/syndicatebomb/New(atom/_holder)
|
|
wires = list(WIRE_BOMB_DELAY, WIRE_EXPLODE, WIRE_BOMB_UNBOLT,WIRE_BOMB_PROCEED, WIRE_BOMB_ACTIVATE)
|
|
return ..()
|
|
|
|
/datum/wires/syndicatebomb/interactable(mob/user)
|
|
var/obj/machinery/syndicatebomb/P = holder
|
|
if(P.open_panel)
|
|
return TRUE
|
|
return FALSE
|
|
|
|
/datum/wires/syndicatebomb/on_pulse(wire)
|
|
var/obj/machinery/syndicatebomb/B = holder
|
|
switch(wire)
|
|
if(WIRE_EXPLODE)
|
|
if(B.active)
|
|
holder.visible_message("<span class='danger'>[bicon(B)] An alarm sounds! It's go-</span>")
|
|
B.explode_now = TRUE
|
|
if(WIRE_BOMB_UNBOLT)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The bolts spin in place for a moment.</span>")
|
|
if(WIRE_BOMB_DELAY)
|
|
if(B.delayedbig)
|
|
holder.visible_message("<span class='notice'>[bicon(B)] The bomb has already been delayed.</span>")
|
|
else
|
|
holder.visible_message("<span class='notice'>[bicon(B)] The bomb chirps.</span>")
|
|
playsound(B, 'sound/machines/chime.ogg', 30, 1)
|
|
B.detonation_timer += 300
|
|
B.delayedbig = TRUE
|
|
if(WIRE_BOMB_PROCEED)
|
|
holder.visible_message("<span class='danger'>[bicon(B)] The bomb buzzes ominously!</span>")
|
|
playsound(B, 'sound/machines/buzz-sigh.ogg', 30, 1)
|
|
var/seconds = B.seconds_remaining()
|
|
if(seconds >= 61) // Long fuse bombs can suddenly become more dangerous if you tinker with them.
|
|
B.detonation_timer = world.time + 600
|
|
else if(seconds >= 21)
|
|
B.detonation_timer -= 100
|
|
else if(seconds >= 11) // Both to prevent negative timers and to have a little mercy.
|
|
B.detonation_timer = world.time + 100
|
|
if(WIRE_BOMB_ACTIVATE)
|
|
if(!B.active && !B.defused)
|
|
holder.visible_message("<span class='danger'>[bicon(B)] You hear the bomb start ticking!</span>")
|
|
B.activate()
|
|
B.update_icon()
|
|
else if(B.delayedlittle)
|
|
holder.visible_message("<span class='notice'>[bicon(B)] Nothing happens.</span>")
|
|
else
|
|
holder.visible_message("<span class='notice'>[bicon(B)] The bomb seems to hesitate for a moment.</span>")
|
|
B.detonation_timer += 100
|
|
B.delayedlittle = TRUE
|
|
..()
|
|
|
|
/datum/wires/syndicatebomb/on_cut(wire, mend)
|
|
var/obj/machinery/syndicatebomb/B = holder
|
|
switch(wire)
|
|
if(WIRE_EXPLODE)
|
|
if(mend)
|
|
B.defused = FALSE // Cutting and mending all the wires of an inactive bomb will thus cure any sabotage.
|
|
else
|
|
if(B.active)
|
|
holder.visible_message("<span class='danger'>[bicon(B)] An alarm sounds! It's go-</span>")
|
|
B.explode_now = TRUE
|
|
else
|
|
B.defused = TRUE
|
|
if(WIRE_BOMB_UNBOLT)
|
|
if(!mend && B.anchored)
|
|
holder.visible_message("<span class='notice'>[bicon(B)] The bolts lift out of the ground!</span>")
|
|
playsound(B, 'sound/effects/stealthoff.ogg', 30, 1)
|
|
B.anchored = FALSE
|
|
if(WIRE_BOMB_PROCEED)
|
|
if(!mend && B.active)
|
|
holder.visible_message("<span class='danger'>[bicon(B)] An alarm sounds! It's go-</span>")
|
|
B.explode_now = TRUE
|
|
if(WIRE_BOMB_ACTIVATE)
|
|
if(!mend && B.active)
|
|
holder.visible_message("<span class='notice'>[bicon(B)] The timer stops! The bomb has been defused!</span>")
|
|
B.defused = TRUE
|
|
B.update_icon()
|
|
..()
|