Convert alarm_manager into SSalarm subsystem.

- Switch to using MC_TICK_CHECK and replace all references.
- Optimize stat panel display by caching the active alarms.

code/controllers/subsystems/alarm.dm

@@ -1,42 +1,45 @@
 
 // We manually initialize the alarm handlers instead of looping over all existing types
-// to make it possible to write: camera.triggerAlarm() rather than alarm_manager.managers[datum/alarm_handler/camera].triggerAlarm() or a variant thereof.
+// to make it possible to write: camera_alarm.triggerAlarm() rather than SSalarm.managers[datum/alarm_handler/camera].triggerAlarm() or a variant thereof.
 /var/global/datum/alarm_handler/atmosphere/atmosphere_alarm	= new()
 /var/global/datum/alarm_handler/camera/camera_alarm			= new()
 /var/global/datum/alarm_handler/fire/fire_alarm				= new()
 /var/global/datum/alarm_handler/motion/motion_alarm			= new()
 /var/global/datum/alarm_handler/power/power_alarm			= new()
 
-// Alarm Manager, the manager for alarms.
-var/datum/controller/process/alarm/alarm_manager
+SUBSYSTEM_DEF(alarm)
+	name = "Alarm"
+	wait = 2 SECONDS
+	priority = FIRE_PRIORITY_ALARM
+	init_order = INIT_ORDER_ALARM
+	var/list/datum/alarm/all_handlers
+	var/tmp/list/currentrun = null
+	var/static/list/active_alarm_cache = list()
 
-/datum/controller/process/alarm
-	var/list/datum/alarm/all_handlers = list()
-
-/datum/controller/process/alarm/setup()
-	name = "alarm"
-	schedule_interval = 20 // every 2 seconds
+/datum/controller/subsystem/alarm/Initialize()
 	all_handlers = list(atmosphere_alarm, camera_alarm, fire_alarm, motion_alarm, power_alarm)
-	alarm_manager = src
+	. = ..()
 
-/datum/controller/process/alarm/doWork()
-	for(last_object in all_handlers)
-		var/datum/alarm_handler/AH = last_object
+/datum/controller/subsystem/alarm/fire(resumed = FALSE)
+	if(!resumed)
+		src.currentrun = all_handlers.Copy()
+		active_alarm_cache.Cut()
+
+	var/list/currentrun = src.currentrun // Cache for sanic speed
+	while (currentrun.len)
+		var/datum/alarm_handler/AH = currentrun[currentrun.len]
+		currentrun.len--
 		AH.process()
-		SCHECK
+		active_alarm_cache += AH.alarms
 
-/datum/controller/process/alarm/proc/active_alarms()
-	var/list/all_alarms = new
-	for(var/datum/alarm_handler/AH in all_handlers)
-		var/list/alarms = AH.alarms
-		all_alarms += alarms
+		if (MC_TICK_CHECK)
+			return
 
-	return all_alarms
+/datum/controller/subsystem/alarm/proc/active_alarms()
+	return active_alarm_cache.Copy()
 
-/datum/controller/process/alarm/proc/number_of_active_alarms()
-	var/list/alarms = active_alarms()
-	return alarms.len
+/datum/controller/subsystem/alarm/proc/number_of_active_alarms()
+	return active_alarm_cache.len
 
-/datum/controller/process/alarm/statProcess()
-	..()
-	stat(null, "[number_of_active_alarms()] alarm\s")
+/datum/controller/subsystem/alarm/stat_entry()
+	..("[number_of_active_alarms()] alarm\s")

code/controllers/verbs.dm

@@ -100,7 +100,6 @@
 	options["LEGACY: transfer_controller"] = transfer_controller
 	options["LEGACY: gas_data"] = gas_data
 	options["LEGACY: plant_controller"] = plant_controller
-	options["LEGACY: alarm_manager"] = alarm_manager
 
 	var/pick = input(mob, "Choose a controller to debug/view variables of.", "VV controller:") as null|anything in options
 	if(!pick)