Ports Modular Computers from Baystation

This is just the initial parts. Additional work will probably be necessary.

code/modules/modular_computers/NTNet/NTNRC/conversation.dm

@@ -0,0 +1,63 @@
+/datum/ntnet_conversation/
+	var/title = "Untitled Conversation"
+	var/datum/computer_file/program/chatclient/operator // "Administrator" of this channel. Creator starts as channel's operator,
+	var/list/messages = list()
+	var/list/clients = list()
+	var/password
+
+/datum/ntnet_conversation/New()
+	if(ntnet_global)
+		ntnet_global.chat_channels.Add(src)
+	..()
+
+/datum/ntnet_conversation/proc/add_message(var/message, var/username)
+	message = "[stationtime2text()] [username]: [message]"
+	messages.Add(message)
+	trim_message_list()
+
+/datum/ntnet_conversation/proc/add_status_message(var/message)
+	messages.Add("[stationtime2text()] -!- [message]")
+	trim_message_list()
+
+/datum/ntnet_conversation/proc/trim_message_list()
+	if(messages.len <= 50)
+		return
+	for(var/message in messages)
+		messages -= message
+		if(messages <= 50)
+			return
+
+/datum/ntnet_conversation/proc/add_client(var/datum/computer_file/program/chatclient/C)
+	if(!istype(C))
+		return
+	clients.Add(C)
+	add_status_message("[C.username] has joined the channel.")
+	// No operator, so we assume the channel was empty. Assign this user as operator.
+	if(!operator)
+		changeop(C)
+
+/datum/ntnet_conversation/proc/remove_client(var/datum/computer_file/program/chatclient/C)
+	if(!istype(C) || !(C in clients))
+		return
+	clients.Remove(C)
+	add_status_message("[C.username] has left the channel.")
+
+	// Channel operator left, pick new operator
+	if(C == operator)
+		operator = null
+		if(clients.len)
+			var/datum/computer_file/program/chatclient/newop = pick(clients)
+			changeop(newop)
+
+
+/datum/ntnet_conversation/proc/changeop(var/datum/computer_file/program/chatclient/newop)
+	if(istype(newop))
+		operator = newop
+		add_status_message("Channel operator status transferred to [newop.username].")
+
+/datum/ntnet_conversation/proc/change_title(var/newtitle, var/datum/computer_file/program/chatclient/client)
+	if(operator != client)
+		return 0 // Not Authorised
+
+	add_status_message("[client.username] has changed channel title from [title] to [newtitle]")
+	title = newtitle

code/modules/modular_computers/NTNet/NTNet.dm

@@ -0,0 +1,147 @@
+var/global/datum/ntnet/ntnet_global = new()
+
+
+// This is the NTNet datum. There can be only one NTNet datum in game at once. Modular computers read data from this.
+/datum/ntnet/
+	var/list/relays = list()
+	var/list/logs = list()
+	var/list/available_station_software = list()
+	var/list/available_antag_software = list()
+	var/list/chat_channels = list()
+	var/list/fileservers = list()
+	// Amount of logs the system tries to keep in memory. Keep below 999 to prevent byond from acting weirdly.
+	// High values make displaying logs much laggier.
+	var/setting_maxlogcount = 100
+
+	// These only affect wireless. LAN (consoles) are unaffected since it would be possible to create scenario where someone turns off NTNet, and is unable to turn it back on since it refuses connections
+	var/setting_softwaredownload = 1
+	var/setting_peertopeer = 1
+	var/setting_communication = 1
+	var/setting_systemcontrol = 1
+	var/setting_disabled = 0					// Setting to 1 will disable all wireless, independently on relays status.
+
+	var/intrusion_detection_enabled = 1 		// Whether the IDS warning system is enabled
+	var/intrusion_detection_alarm = 0			// Set when there is an IDS warning due to malicious (antag) software.
+
+
+// If new NTNet datum is spawned, it replaces the old one.
+/datum/ntnet/New()
+	if(ntnet_global && (ntnet_global != src))
+		ntnet_global = src // There can be only one.
+	for(var/obj/machinery/ntnet_relay/R in machines)
+		relays.Add(R)
+		R.NTNet = src
+	build_software_lists()
+	add_log("NTNet logging system activated.")
+
+// Simplified logging: Adds a log. log_string is mandatory parameter, source is optional.
+/datum/ntnet/proc/add_log(var/log_string, var/obj/item/weapon/computer_hardware/network_card/source = null)
+	var/log_text = "[stationtime2text()] - "
+	if(source)
+		log_text += "[source.get_network_tag()] - "
+	else
+		log_text += "*SYSTEM* - "
+	log_text += log_string
+	logs.Add(log_text)
+
+	if(logs.len > setting_maxlogcount)
+		// We have too many logs, remove the oldest entries until we get into the limit
+		for(var/L in logs)
+			if(logs.len > setting_maxlogcount)
+				logs.Remove(L)
+			else
+				break
+
+// Checks whether NTNet operates. If parameter is passed checks whether specific function is enabled.
+/datum/ntnet/proc/check_function(var/specific_action = 0)
+	if(!relays || !relays.len) // No relays found. NTNet is down
+		return 0
+
+	var/operating = 0
+
+	// Check all relays. If we have at least one working relay, network is up.
+	for(var/obj/machinery/ntnet_relay/R in relays)
+		if(R.is_operational())
+			operating = 1
+			break
+
+	if(setting_disabled)
+		return 0
+
+	if(specific_action == NTNET_SOFTWAREDOWNLOAD)
+		return (operating && setting_softwaredownload)
+	if(specific_action == NTNET_PEERTOPEER)
+		return (operating && setting_peertopeer)
+	if(specific_action == NTNET_COMMUNICATION)
+		return (operating && setting_communication)
+	if(specific_action == NTNET_SYSTEMCONTROL)
+		return (operating && setting_systemcontrol)
+	return operating
+
+// Builds lists that contain downloadable software.
+/datum/ntnet/proc/build_software_lists()
+	available_station_software = list()
+	available_antag_software = list()
+	for(var/F in typesof(/datum/computer_file/program))
+		var/datum/computer_file/program/prog = new F
+		// Invalid type (shouldn't be possible but just in case), invalid filetype (not executable program) or invalid filename (unset program)
+		if(!prog || !istype(prog) || prog.filename == "UnknownProgram" || prog.filetype != "PRG")
+			continue
+		// Check whether the program should be available for station/antag download, if yes, add it to lists.
+		if(prog.available_on_ntnet)
+			available_station_software.Add(prog)
+		if(prog.available_on_syndinet)
+			available_antag_software.Add(prog)
+
+// Attempts to find a downloadable file according to filename var
+/datum/ntnet/proc/find_ntnet_file_by_name(var/filename)
+	for(var/datum/computer_file/program/P in available_station_software)
+		if(filename == P.filename)
+			return P
+	for(var/datum/computer_file/program/P in available_antag_software)
+		if(filename == P.filename)
+			return P
+
+// Resets the IDS alarm
+/datum/ntnet/proc/resetIDS()
+	intrusion_detection_alarm = 0
+
+/datum/ntnet/proc/toggleIDS()
+	resetIDS()
+	intrusion_detection_enabled = !intrusion_detection_enabled
+
+// Removes all logs
+/datum/ntnet/proc/purge_logs()
+	logs = list()
+	add_log("-!- LOGS DELETED BY SYSTEM OPERATOR -!-")
+
+// Updates maximal amount of stored logs. Use this instead of setting the number, it performs required checks.
+/datum/ntnet/proc/update_max_log_count(var/lognumber)
+	if(!lognumber)
+		return 0
+	// Trim the value if necessary
+	lognumber = between(MIN_NTNET_LOGS, lognumber, MAX_NTNET_LOGS)
+	setting_maxlogcount = lognumber
+	add_log("Configuration Updated. Now keeping [setting_maxlogcount] logs in system memory.")
+
+/datum/ntnet/proc/toggle_function(var/function)
+	if(!function)
+		return
+	function = text2num(function)
+	switch(function)
+		if(NTNET_SOFTWAREDOWNLOAD)
+			setting_softwaredownload = !setting_softwaredownload
+			add_log("Configuration Updated. Wireless network firewall now [setting_softwaredownload ? "allows" : "disallows"] connection to software repositories.")
+		if(NTNET_PEERTOPEER)
+			setting_peertopeer = !setting_peertopeer
+			add_log("Configuration Updated. Wireless network firewall now [setting_peertopeer ? "allows" : "disallows"] peer to peer network traffic.")
+		if(NTNET_COMMUNICATION)
+			setting_communication = !setting_communication
+			add_log("Configuration Updated. Wireless network firewall now [setting_communication ? "allows" : "disallows"] instant messaging and similar communication services.")
+		if(NTNET_SYSTEMCONTROL)
+			setting_systemcontrol = !setting_systemcontrol
+			add_log("Configuration Updated. Wireless network firewall now [setting_systemcontrol ? "allows" : "disallows"] remote control of station's systems.")
+
+
+
+

code/modules/modular_computers/NTNet/NTNet_relay.dm

@@ -0,0 +1,130 @@
+// Relays don't handle any actual communication. Global NTNet datum does that, relays only tell the datum if it should or shouldn't work.
+/obj/machinery/ntnet_relay
+	name = "NTNet Quantum Relay"
+	desc = "A very complex router and transmitter capable of connecting electronic devices together. Looks fragile."
+	use_power = 2
+	active_power_usage = 20000 //20kW, apropriate for machine that keeps massive cross-Zlevel wireless network operational.
+	idle_power_usage = 100
+	icon_state = "bus"
+	anchored = 1
+	density = 1
+	var/datum/ntnet/NTNet = null // This is mostly for backwards reference and to allow varedit modifications from ingame.
+	var/enabled = 1				// Set to 0 if the relay was turned off
+	var/dos_failure = 0			// Set to 1 if the relay failed due to (D)DoS attack
+	var/list/dos_sources = list()	// Backwards reference for qdel() stuff
+
+	// Denial of Service attack variables
+	var/dos_overload = 0		// Amount of DoS "packets" in this relay's buffer
+	var/dos_capacity = 500		// Amount of DoS "packets" in buffer required to crash the relay
+	var/dos_dissipate = 1		// Amount of DoS "packets" dissipated over time.
+
+
+// TODO: Implement more logic here. For now it's only a placeholder.
+/obj/machinery/ntnet_relay/proc/is_operational()
+	if(stat & (BROKEN | NOPOWER | EMPED))
+		return 0
+	if(dos_failure)
+		return 0
+	if(!enabled)
+		return 0
+	return 1
+
+/obj/machinery/ntnet_relay/update_icon()
+	if(is_operational())
+		icon_state = "bus"
+	else
+		icon_state = "bus_off"
+
+/obj/machinery/ntnet_relay/process()
+	if(is_operational())
+		use_power = 2
+	else
+		use_power = 1
+
+	if(dos_overload)
+		dos_overload = max(0, dos_overload - dos_dissipate)
+
+	// If DoS traffic exceeded capacity, crash.
+	if((dos_overload > dos_capacity) && !dos_failure)
+		dos_failure = 1
+		update_icon()
+		ntnet_global.add_log("Quantum relay switched from normal operation mode to overload recovery mode.")
+	// If the DoS buffer reaches 0 again, restart.
+	if((dos_overload == 0) && dos_failure)
+		dos_failure = 0
+		update_icon()
+		ntnet_global.add_log("Quantum relay switched from overload recovery mode to normal operation mode.")
+	..()
+
+/obj/machinery/ntnet_relay/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	var/list/data = list()
+	data["enabled"] = enabled
+	data["dos_capacity"] = dos_capacity
+	data["dos_overload"] = dos_overload
+	data["dos_crashed"] = dos_failure
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_relay.tmpl", "NTNet Quantum Relay", 500, 300, state = state)
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/obj/machinery/ntnet_relay/attack_hand(var/mob/living/user)
+	ui_interact(user)
+
+/obj/machinery/ntnet_relay/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["restart"])
+		dos_overload = 0
+		dos_failure = 0
+		update_icon()
+		ntnet_global.add_log("Quantum relay manually restarted from overload recovery mode to normal operation mode.")
+	else if(href_list["toggle"])
+		enabled = !enabled
+		ntnet_global.add_log("Quantum relay manually [enabled ? "enabled" : "disabled"].")
+		update_icon()
+
+/obj/machinery/ntnet_relay/New()
+	uid = gl_uid
+	gl_uid++
+	component_parts = list()
+	component_parts += new /obj/item/stack/cable_coil(src,15)
+	component_parts += new /obj/item/weapon/circuitboard/ntnet_relay(src)
+
+	if(ntnet_global)
+		ntnet_global.relays.Add(src)
+		NTNet = ntnet_global
+		ntnet_global.add_log("New quantum relay activated. Current amount of linked relays: [NTNet.relays.len]")
+	..()
+
+/obj/machinery/ntnet_relay/Destroy()
+	if(ntnet_global)
+		ntnet_global.relays.Remove(src)
+		ntnet_global.add_log("Quantum relay connection severed. Current amount of linked relays: [NTNet.relays.len]")
+		NTNet = null
+	for(var/datum/computer_file/program/ntnet_dos/D in dos_sources)
+		D.target = null
+		D.error = "Connection to quantum relay severed"
+	..()
+
+/obj/machinery/ntnet_relay/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
+	if(W.is_screwdriver())
+		playsound(src.loc, 'sound/items/Screwdriver.ogg', 50, 1)
+		panel_open = !panel_open
+		user << "You [panel_open ? "open" : "close"] the maintenance hatch"
+		return
+	if(W.is_crowbar())
+		if(!panel_open)
+			user << "Open the maintenance panel first."
+			return
+		playsound(src.loc, 'sound/items/Crowbar.ogg', 50, 1)
+		user << "You disassemble \the [src]!"
+
+		for(var/atom/movable/A in component_parts)
+			A.forceMove(src.loc)
+		new /obj/structure/frame(src.loc)
+		qdel(src)
+		return
+	..()

code/modules/modular_computers/_description.dm

@@ -0,0 +1,102 @@
+/*
+Program-based computers, designed to replace computer3 project and eventually most consoles on station
+1. Basic information
+Program based computers will allow you to do multiple things from single computer. Each computer will have programs, with more being downloadable from NTNet (stationwide network with wireless coverage)
+if user has apropriate ID card access. It will be possible to hack the computer by using an emag on it - the emag will have to be completely new and will be consumed on use, but it will
+lift ALL locks on ALL installed programs, and allow download of programs even if your ID doesn't have access to them. Computers will have hard drives that can store files.
+Files can be programs (datum/computer_file/program/ subtype) or data files (datum/computer_file/data/ subtypes). Program for sending files will be available that will allow transfer via NTNet.
+NTNet coverage will be limited to station's Z level, but better network card (=more expensive and higher power use) will allow usage everywhere. Hard drives will have limited capacity for files
+which will be related to how good hard drive you buy when purchasing the laptop. For storing more files USB-style drives will be buildable with Protolathe in research.
+2. Available devices
+CONSOLES
+Consoles will come in various pre-fabricated loadouts, each loadout starting with certain set of programs (aka Engineering console, Medical console, etc.), of course, more software may be downloaded.
+Consoles won't usually have integrated battery, but the possibility to install one will exist for critical applications. Consoles are considered hardwired into NTNet network which means they
+will have working coverage on higher speed (Ethernet is faster than Wi-Fi) and won't require wireless coverage to exist.
+LAPTOPS
+Laptops are middle ground between actual portable devices and full consoles. They offer certain level of mobility, as they can be closed, moved somewhere else and then opened again.
+Laptops will by default have internal battery to power them, and may be recharged with rechargers. However, laptops rely on wireless NTNet coverage. Laptop HDDs are also designed with power efficiency
+in mind, which means they sacrifice some storage space for higher battery life. Laptops may be dispensed from computer vendor machine, and may be customised before vending. For people which don't
+want to rely on internal battery, tesla link exists that connects to APC, if one exists.
+TABLETS
+Tablets are smallest available devices, designed with full mobility in mind. Tablets have only weak CPU which means the software they can run is somewhat limited. They are also designed with high
+battery life in mind, which means the hardware focuses on power efficiency rather than high performance. This is most visible with hard drives which have quite small storage capacity.
+Tablets can't be equipped with tesla link, which means they have to be recharged manually.
+3. Computer Hardware
+Computers will come with basic hardware installed, with upgrades being selectable when purchasing the device.
+Hard Drive: Stores data, mandatory for the computer to work
+Network Card: Connects to NTNet
+Battery: Internal power source that ensures the computer operates when not connected to APC.
+Extras (those won't be installed by default, but can be bought)
+ID Card Slot: Required for HoP-style programs to work. Access for security record-style programs is read from ID of user [RFID?] without requiring this
+APC Tesla Relay: Wirelessly powers the device from APC. Consoles have it by default. Laptops can buy it.
+Disk Drive: Allows usage of portable data disks.
+Nano Printer: Allows the computer to scan paper contents and save them to file, as well as recycle papers and print stuff on it.
+4. NTNet
+NTNet is stationwide network that allows users to download programs needed for their work. It will be possible to send any files to other active computers using relevant program (NTN Transfer).
+NTNet is under jurisdiction of both Engineering and Research. Engineering is responsible for any repairs if necessary and research is responsible for monitoring. It is similar to PDA messaging.
+Operation requires functional "NTNet Relay" which is by default placed on tcommsat. If the relay is damaged NTNet will be offline until it is replaced. Multiple relays bring extra redundancy,
+if one is destroyed the second will take over. If all relays are gone it stops working, simple as that. NTNet may be altered via administration console available to Research Director. It is
+possible to enable/disable Software Downloading, P2P file transfers and Communication (IC version of IRC, PDA messages for more than two people)
+5. Software
+Software would almost exclusively use NanoUI modules. Few exceptions are text editor (uses similar screen as TCS IDE used for editing and classic HTML for previewing as Nano looks differently)
+and similar programs which for some reason require HTML UI. Most software will be highly dependent on NTNet to work as laptops are not physically connected to the station's network.
+What i plan to add:
+Note: XXXXDB programs will use ingame_manuals to display basic help for players, similar to how books, etc. do
+Basic - Software in this bundle is automagically preinstalled in every new computer
+	NTN Transfer - Allows P2P transfer of files to other computers that run this.
+	Configurator - Allows configuration of computer's hardware, basically status screen.
+	File Browser - Allows you to browse all files stored on the computer. Allows renaming/deleting of files.
+	TXT Editor - Allows you editing data files in text editor mode.
+	NanoPrint - Allows you to operate NanoPrinter hardware to print text files.
+	NTNRC Chat - NTNet Relay Chat client. Allows PDA-messaging style messaging for more than two users. Person which created the conversation is Host and has administrative privilegies (kicking, etc.)
+	NTNet News - Allows reading news from newscaster network.
+Engineering - Requires "Engineering" access on ID card (ie. CE, Atmostech, Engineer)
+	Alarm Monitor - Allows monitoring alarms, same as the stationbound one.
+	Power Monitor - Power monitoring computer, connects to sensors in same way as regular one does.
+	Atmospheric Control - Allows access to the Atmospherics Monitor Console that operates air alarms. Requires extra access: "Atmospherics"
+	RCON Remote Control Console - Allows access to the RCON Remote Control Console. Requires extra access: "Power Equipment"
+	EngiDB - Allows accessing NTNet information repository for information about engineering-related things.
+Medical - Requires "Medbay" access on ID card (ie. CMO, Doctor,..)
+	Medical Records Uplink - Allows editing/reading of medical records. Printing requires NanoPrinter hardware.
+	MediDB - Allows accessing NTNet information repository for information about medical procedures
+	ChemDB - Requires extra access: "Chemistry" - Downloads basic information about recipes from NTNet
+Research - Requires "Research and Development" access on ID card (ie. RD, Roboticist, etc.)
+	Research Server Monitor - Allows monitoring of research levels on RnD servers. (read only)
+	Robotics Monitor Console - Allows monitoring of robots and exosuits. Lockdown/Self-Destruct options are unavailable [balance reasons for malf/traitor AIs]. Requires extra access: "Robotics"
+	NTNRC Administration Console - Allows administrative access to NTNRC. This includes bypassing any channel passwords and enabling "invisible" mode for spying on conversations. Requires extra access: "Research Director"
+	NTNet Administration Console - Allows remote configuration of NTNet Relay - CAUTION: If NTNet is turned off it won't be possible to turn it on again from the computer, as operation requires NTNet to work! Requires extra access: "Research Director"
+	NTNet Monitor - Allows monitoring of NTNet and it's various components, including simplified network logs and system status.
+Security - Requires "Security" access on ID card (ie. HOS, Security officer, Detective)
+	Security Records Uplink - Allows editing/reading of security records. Printing requires Nanoprinter hardware.
+	LawDB - Allows accessing NTNet information repository for security information (corporate regulations)
+	Camera Uplink - Allows viewing cameras around the station.
+Command - Requires "Bridge" access on ID card (all heads)
+	Alertcon Access - Allows changing of alert levels. Red requires activation from two computers with two IDs similar to how those wall mounted devices do.
+	Employment Records Access - Allows reading of employment records. Printing requires NanoPrinter hardware.
+	Communication Console - Allows sending emergency messages to Central.
+	Emergency Shuttle Control Console - Allows calling/recalling the emergency shuttle.
+	Shuttle Control Console - Allows control of various shuttles around the station (mining, research, engineering)
+*REDACTED* - Can be downloaded from SyndiCorp servers, only via emagged devices. These files are very large and limited to laptops/consoles only.
+	SYSCRACK - Allows cracking of secure network terminals, such as, NTNet administration. The sysadmin will probably notice this.
+	SYSOVERRIDE - Allows hacking into any device connected to NTNet. User will notice this and may stop the hack by disconnecting from NTNet first. After hacking various options exist, such as stealing/deleting files.
+	SYSKILL - Tricks NTNet to force-disconnect a device. The sysadmin will probably notice this.
+	SYSDOS - Launches a Denial of Service attack on NTNet relay. Can DoS only one relay at once. Requires NTNet connection. After some time the relay crashes until attack stops. The sysadmin will probably notice this.
+	AIHACK - Hacks an AI, allowing you to upload/remove/modify a law even without relevant circuit board. The AI is alerted once the hack starts, and it takes a while for it to complete. Does not work on AIs with zeroth law.
+	COREPURGE - Deletes all files on the hard drive, including the undeletable ones. Something like software self-destruct for computer.
+6. Security
+Laptops will be password-lockable. If password is set a MD5 hash of it is stored and password is required every time you turn on the laptop.
+Passwords may be decrypted by using special Decrypter (protolathable, RDs office starts with one) device that will slowly decrypt the password.
+Decryption time would be length_of_password * 30 seconds, with maximum being 9 minutes (due to battery life limitations, which is 10+ min).
+If decrypted the password is cleared, so you can keep using your favorite password without people ever actually revealing it (for meta prevention reasons mostly).
+Emagged laptops will have option to enable "Safe Encryption". If safely encrypted laptop is decrypted it loses it's emag status and 50% of files is deleted (randomly selected).
+7. System Administrator
+System Administrator will be new job under Research. It's main specifics will be maintaining of computer systems on station, espicially from software side.
+From IC perspective they'd probably know how to build a console or something given they work with computers, but they are mostly programmers/network experts.
+They will have office in research, which will probably replace (and contain) the server room and part of the toxins storage which is currently oversized.
+They will have access to DOWNLOAD (not run) all programs that exist on NTNet. They'll have fairly good amount of available programs, most of them being
+administrative consoles and other very useful things. They'll also be able to monitor NTNet. There will probably be one or two job slots.
+8. IDS
+With addition of various antag programs, IDS(Intrusion Detection System) will be added to NTNet. This system can be turned on/off via administration console.
+If enabled, this system automatically detects any abnormality and triggers a warning that's visible on the NTNet status screen, as well as generating a security log.
+IDS can be disabled by simple on/off switch in the configuration.
+*/ 

code/modules/modular_computers/computers/item/modular_computer.dm

@@ -0,0 +1,493 @@
+// This is the base type that does all the hardware stuff.
+// Other types expand it - tablets use a direct subtypes, and
+// consoles and laptops use "procssor" item that is held inside machinery piece
+/obj/item/modular_computer
+	name = "Modular Microcomputer"
+	desc = "A small portable microcomputer"
+
+	var/enabled = 0											// Whether the computer is turned on.
+	var/screen_on = 1										// Whether the computer is active/opened/it's screen is on.
+	var/datum/computer_file/program/active_program = null	// A currently active program running on the computer.
+	var/hardware_flag = 0									// A flag that describes this device type
+	var/last_power_usage = 0
+	var/computer_emagged = 0								// Whether the computer is emagged.
+
+	var/base_active_power_usage = 50						// Power usage when the computer is open (screen is active) and can be interacted with. Remember hardware can use power too.
+	var/base_idle_power_usage = 5							// Power usage when the computer is idle and screen is off (currently only applies to laptops)
+
+	// Modular computers can run on various devices. Each DEVICE (Laptop, Console, Tablet,..)
+	// must have it's own DMI file. Icon states must be called exactly the same in all files, but may look differently
+	// If you create a program which is limited to Laptops and Consoles you don't have to add it's icon_state overlay for Tablets too, for example.
+
+	icon = 'icons/obj/computer.dmi'
+	icon_state = "laptop-open"
+	var/icon_state_unpowered = null							// Icon state when the computer is turned off
+	var/icon_state_menu = "menu"							// Icon state overlay when the computer is turned on, but no program is loaded that would override the screen.
+	var/max_hardware_size = 0								// Maximal hardware size. Currently, tablets have 1, laptops 2 and consoles 3. Limits what hardware types can be installed.
+	var/steel_sheet_cost = 5								// Amount of steel sheets refunded when disassembling an empty frame of this computer.
+
+
+	// Important hardware (must be installed for computer to work)
+	var/obj/item/weapon/computer_hardware/network_card/network_card					// Network Card component of this computer. Allows connection to NTNet
+	var/obj/item/weapon/computer_hardware/hard_drive/hard_drive						// Hard Drive component of this computer. Stores programs and files.
+	var/obj/item/weapon/computer_hardware/battery_module/battery_module				// An internal power source for this computer. Can be recharged.
+	// Optional hardware (improves functionality, but is not critical for computer to work)
+	var/obj/item/weapon/computer_hardware/card_slot/card_slot						// ID Card slot component of this computer. Mostly for HoP modification console that needs ID slot for modification.
+	var/obj/item/weapon/computer_hardware/nano_printer/nano_printer					// Nano Printer component of this computer, for your everyday paperwork needs.
+	var/obj/item/weapon/computer_hardware/hard_drive/portable/portable_drive		// Portable data storage
+
+
+// Eject ID card from computer, if it has ID slot with card inside.
+/obj/item/modular_computer/verb/eject_id()
+	set name = "Eject ID"
+	set category = "Object"
+	set src in view(1)
+
+	if(usr.stat || usr.restrained() || usr.lying || !istype(usr, /mob/living))
+		usr << "<span class='warning'>You can't do that.</span>"
+		return
+
+	if(!Adjacent(usr))
+		usr << "<span class='warning'>You can't reach it.</span>"
+		return
+
+	proc_eject_id(usr)
+
+/obj/item/modular_computer/proc/proc_eject_id(mob/user)
+	if(!user)
+		user = usr
+
+	if(!card_slot)
+		user << "\The [src] does not have an ID card slot"
+		return
+
+	if(!card_slot.stored_card)
+		user << "There is no card in \the [src]"
+		return
+
+	card_slot.stored_card.forceMove(get_turf(src))
+	card_slot.stored_card = null
+	user << "You remove the card from \the [src]"
+
+/obj/item/modular_computer/emag_act(var/remaining_charges, var/mob/user)
+	if(computer_emagged)
+		user << "\The [src] was already emagged."
+		return
+	else
+		computer_emagged = 1
+		user << "You emag \the [src]. It's screen briefly shows a \"OVERRIDE ACCEPTED: New software downloads available.\" message."
+		return 1
+
+/obj/item/modular_computer/New()
+	START_PROCESSING(SSobj, src)
+	update_icon()
+	..()
+
+/obj/item/modular_computer/Destroy()
+	kill_program(1)
+	STOP_PROCESSING(SSobj, src)
+	for(var/obj/item/weapon/computer_hardware/CH in src.get_all_components())
+		qdel(CH)
+	..()
+
+/obj/item/modular_computer/update_icon()
+	icon_state = icon_state_unpowered
+
+	overlays.Cut()
+	if(!enabled)
+		return
+	if(active_program)
+		overlays.Add(active_program.program_icon_state ? active_program.program_icon_state : icon_state_menu)
+	else
+		overlays.Add(icon_state_menu)
+
+// Used by child types if they have other power source than battery
+/obj/item/modular_computer/proc/check_power_override()
+	return 0
+
+// Operates NanoUI
+/obj/item/modular_computer/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+	if(!screen_on || !enabled)
+		if(ui)
+			ui.close()
+		return 0
+	if((!battery_module || !battery_module.battery.charge) && !check_power_override())
+		if(ui)
+			ui.close()
+		return 0
+
+	// If we have an active program switch to it now.
+	if(active_program)
+		if(ui) // This is the main laptop screen. Since we are switching to program's UI close it for now.
+			ui.close()
+		active_program.ui_interact(user)
+		return
+
+	// We are still here, that means there is no program loaded. Load the BIOS/ROM/OS/whatever you want to call it.
+	// This screen simply lists available programs and user may select them.
+	if(!hard_drive || !hard_drive.stored_files || !hard_drive.stored_files.len)
+		visible_message("\The [src] beeps three times, it's screen displaying \"DISK ERROR\" warning.")
+		return // No HDD, No HDD files list or no stored files. Something is very broken.
+
+	var/list/data = get_header_data()
+
+	var/list/programs = list()
+	for(var/datum/computer_file/program/P in hard_drive.stored_files)
+		var/list/program = list()
+		program["name"] = P.filename
+		program["desc"] = P.filedesc
+		programs.Add(list(program))
+
+	data["programs"] = programs
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "laptop_mainscreen.tmpl", "NTOS Main Menu", 400, 500)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+// On-click handling. Turns on the computer if it's off and opens the GUI.
+/obj/item/modular_computer/attack_self(mob/user)
+	if(enabled)
+		ui_interact(user)
+	else if((battery_module && battery_module.battery.charge) || check_power_override()) // Battery-run and charged or non-battery but powered by APC.
+		user << "You press the power button and start up \the [src]"
+		enabled = 1
+		update_icon()
+		ui_interact(user)
+	else // Unpowered
+		user << "You press the power button but \the [src] does not respond."
+
+// Process currently calls handle_power(), may be expanded in future if more things are added.
+/obj/item/modular_computer/process()
+	if(!enabled) // The computer is turned off
+		last_power_usage = 0
+		return 0
+
+	if(active_program && active_program.requires_ntnet && !get_ntnet_status(active_program.requires_ntnet_feature)) // Active program requires NTNet to run but we've just lost connection. Crash.
+		kill_program(1)
+		visible_message("<span class='danger'>\The [src]'s screen briefly freezes and then shows \"NETWORK ERROR - NTNet connection lost. Please retry. If problem persists contact your system administrator.\" error.</span>")
+
+	if(active_program)
+		active_program.process_tick()
+		active_program.ntnet_status = get_ntnet_status()
+		active_program.computer_emagged = computer_emagged
+
+	handle_power() // Handles all computer power interaction
+
+// Function used by NanoUI's to obtain data for header. All relevant entries begin with "PC_"
+/obj/item/modular_computer/proc/get_header_data()
+	var/list/data = list()
+
+	if(battery_module)
+		switch(battery_module.battery.percent())
+			if(80 to 200) // 100 should be maximal but just in case..
+				data["PC_batteryicon"] = "batt_100.gif"
+			if(60 to 80)
+				data["PC_batteryicon"] = "batt_80.gif"
+			if(40 to 60)
+				data["PC_batteryicon"] = "batt_60.gif"
+			if(20 to 40)
+				data["PC_batteryicon"] = "batt_40.gif"
+			if(5 to 20)
+				data["PC_batteryicon"] = "batt_20.gif"
+			else
+				data["PC_batteryicon"] = "batt_5.gif"
+		data["PC_batterypercent"] = "[round(battery_module.battery.percent())] %"
+		data["PC_showbatteryicon"] = 1
+	else
+		data["PC_batteryicon"] = "batt_5.gif"
+		data["PC_batterypercent"] = "N/C"
+		data["PC_showbatteryicon"] = battery_module ? 1 : 0
+
+	switch(get_ntnet_status())
+		if(0)
+			data["PC_ntneticon"] = "sig_none.gif"
+		if(1)
+			data["PC_ntneticon"] = "sig_low.gif"
+		if(2)
+			data["PC_ntneticon"] = "sig_high.gif"
+		if(3)
+			data["PC_ntneticon"] = "sig_lan.gif"
+
+	data["PC_stationtime"] = stationtime2text()
+	data["PC_hasheader"] = 1
+	data["PC_showexitprogram"] = active_program ? 1 : 0 // Hides "Exit Program" button on mainscreen
+	return data
+
+// Relays kill program request to currently active program. Use this to quit current program.
+/obj/item/modular_computer/proc/kill_program(var/forced = 0)
+	if(active_program)
+		active_program.kill_program(forced)
+		active_program = null
+	var/mob/user = usr
+	if(user && istype(user))
+		ui_interact(user) // Re-open the UI on this computer. It should show the main screen now.
+	update_icon()
+
+// Returns 0 for No Signal, 1 for Low Signal and 2 for Good Signal. 3 is for wired connection (always-on)
+/obj/item/modular_computer/proc/get_ntnet_status(var/specific_action = 0)
+	if(network_card)
+		return network_card.get_signal(specific_action)
+	else
+		return 0
+
+/obj/item/modular_computer/proc/add_log(var/text)
+	if(!get_ntnet_status())
+		return 0
+	return ntnet_global.add_log(text, network_card)
+
+/obj/item/modular_computer/proc/shutdown_computer()
+	kill_program(1)
+	visible_message("\The [src] shuts down.")
+	enabled = 0
+	update_icon()
+	return
+
+// Handles user's GUI input
+/obj/item/modular_computer/Topic(href, href_list)
+	if(..())
+		return 1
+	if( href_list["PC_exit"] )
+		kill_program()
+		return
+	if( href_list["PC_enable_component"] )
+		var/obj/item/weapon/computer_hardware/H = find_hardware_by_name(href_list["PC_enable_component"])
+		if(H && istype(H) && !H.enabled)
+			H.enabled = 1
+		return
+	if( href_list["PC_disable_component"] )
+		var/obj/item/weapon/computer_hardware/H = find_hardware_by_name(href_list["PC_disable_component"])
+		if(H && istype(H) && H.enabled)
+			H.enabled = 0
+		return
+	if( href_list["PC_shutdown"] )
+		shutdown_computer()
+		return
+	if( href_list["PC_runprogram"] )
+		var/prog = href_list["PC_runprogram"]
+		var/datum/computer_file/program/P = null
+		var/mob/user = usr
+		if(hard_drive)
+			P = hard_drive.find_file_by_name(prog)
+			P.computer = src
+
+		if(!P || !istype(P)) // Program not found or it's not executable program.
+			user << "<span class='danger'>\The [src]'s screen shows \"I/O ERROR - Unable to run program\" warning.</span>"
+			return
+
+		if(!P.is_supported_by_hardware(hardware_flag, 1, user))
+			return
+
+		if(P.requires_ntnet && !get_ntnet_status(P.requires_ntnet_feature)) // The program requires NTNet connection, but we are not connected to NTNet.
+			user << "<span class='danger'>\The [src]'s screen shows \"NETWORK ERROR - Unable to connect to NTNet. Please retry. If problem persists contact your system administrator.\" warning.</span>"
+			return
+		if(P.run_program(user))
+			active_program = P
+			update_icon()
+		return
+
+// Used in following function to reduce copypaste
+/obj/item/modular_computer/proc/power_failure()
+	if(enabled) // Shut down the computer
+		visible_message("<span class='danger'>\The [src]'s screen flickers \"BATTERY CRITICAL\" warning as it shuts down unexpectedly.</span>")
+		kill_program(1)
+		enabled = 0
+		update_icon()
+
+// Handles power-related things, such as battery interaction, recharging, shutdown when it's discharged
+/obj/item/modular_computer/proc/handle_power()
+	if(!battery_module || battery_module.battery.charge <= 0) // Battery-run but battery is depleted.
+		power_failure()
+		return 0
+
+	var/power_usage = screen_on ? base_active_power_usage : base_idle_power_usage
+	if(network_card && network_card.enabled)
+		power_usage += network_card.power_usage
+
+	if(hard_drive && hard_drive.enabled)
+		power_usage += hard_drive.power_usage
+
+	if(battery_module)
+		battery_module.battery.use(power_usage * CELLRATE)
+	last_power_usage = power_usage
+
+/obj/item/modular_computer/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
+	if(istype(W, /obj/item/weapon/card/id)) // ID Card, try to insert it.
+		var/obj/item/weapon/card/id/I = W
+		if(!card_slot)
+			user << "You try to insert \the [I] into \the [src], but it does not have an ID card slot installed."
+			return
+
+		if(card_slot.stored_card)
+			user << "You try to insert \the [I] into \the [src], but it's ID card slot is occupied."
+			return
+		user.drop_from_inventory(I)
+		card_slot.stored_card = I
+		I.forceMove(src)
+		user << "You insert \the [I] into \the [src]."
+		return
+	if(istype(W, /obj/item/weapon/paper))
+		var/obj/item/weapon/paper/P = W
+		if(!nano_printer)
+			return
+		nano_printer.load_paper(P)
+	if(istype(W, /obj/item/weapon/computer_hardware))
+		var/obj/item/weapon/computer_hardware/C = W
+		if(C.hardware_size <= max_hardware_size)
+			try_install_component(user, C)
+		else
+			user << "This component is too large for \the [src]."
+	if(W.is_wrench())
+		var/list/components = get_all_components()
+		if(components.len)
+			user << "Remove all components from \the [src] before disassembling it."
+			return
+		new /obj/item/stack/material/steel( get_turf(src.loc), steel_sheet_cost )
+		src.visible_message("\The [src] has been disassembled by [user].")
+		relay_qdel()
+		qdel(src)
+		return
+
+	if(W.is_screwdriver())
+		var/list/all_components = get_all_components()
+		if(!all_components.len)
+			user << "This device doesn't have any components installed."
+			return
+		var/list/component_names = list()
+		for(var/obj/item/weapon/computer_hardware/H in all_components)
+			component_names.Add(H.name)
+
+		var/choice = input(usr, "Which component do you want to uninstall?", "Computer maintenance", null) as null|anything in component_names
+
+		if(!choice)
+			return
+
+		if(!Adjacent(usr))
+			return
+
+		var/obj/item/weapon/computer_hardware/H = find_hardware_by_name(choice)
+
+		if(!H)
+			return
+
+		uninstall_component(user, H)
+
+		return
+
+	..()
+
+// Used by processor to relay qdel() to machinery type.
+/obj/item/modular_computer/proc/relay_qdel()
+	return
+
+// Attempts to install the hardware into apropriate slot.
+/obj/item/modular_computer/proc/try_install_component(var/mob/living/user, var/obj/item/weapon/computer_hardware/H, var/found = 0)
+	// "USB" flash drive.
+	if(istype(H, /obj/item/weapon/computer_hardware/hard_drive/portable))
+		if(portable_drive)
+			user << "This computer's portable drive slot is already occupied by \the [portable_drive]."
+			return
+		found = 1
+		portable_drive = H
+	else if(istype(H, /obj/item/weapon/computer_hardware/hard_drive))
+		if(hard_drive)
+			user << "This computer's hard drive slot is already occupied by \the [hard_drive]."
+			return
+		found = 1
+		hard_drive = H
+	else if(istype(H, /obj/item/weapon/computer_hardware/network_card))
+		if(network_card)
+			user << "This computer's network card slot is already occupied by \the [network_card]."
+			return
+		found = 1
+		network_card = H
+	else if(istype(H, /obj/item/weapon/computer_hardware/nano_printer))
+		if(nano_printer)
+			user << "This computer's nano printer slot is already occupied by \the [nano_printer]."
+			return
+		found = 1
+		nano_printer = H
+	else if(istype(H, /obj/item/weapon/computer_hardware/card_slot))
+		if(card_slot)
+			user << "This computer's card slot is already occupied by \the [card_slot]."
+			return
+		found = 1
+		card_slot = H
+	else if(istype(H, /obj/item/weapon/computer_hardware/battery_module))
+		if(battery_module)
+			user << "This computer's battery slot is already occupied by \the [battery_module]."
+			return
+		found = 1
+		battery_module = H
+	if(found)
+		user << "You install \the [H] into \the [src]"
+		H.holder2 = src
+		user.drop_from_inventory(H)
+		H.forceMove(src)
+
+// Uninstalls component. Found and Critical vars may be passed by parent types, if they have additional hardware.
+/obj/item/modular_computer/proc/uninstall_component(var/mob/living/user, var/obj/item/weapon/computer_hardware/H, var/found = 0, var/critical = 0)
+	if(portable_drive == H)
+		portable_drive = null
+		found = 1
+	if(hard_drive == H)
+		hard_drive = null
+		found = 1
+		critical = 1
+	if(network_card == H)
+		network_card = null
+		found = 1
+	if(nano_printer == H)
+		nano_printer = null
+		found = 1
+	if(card_slot == H)
+		card_slot = null
+		found = 1
+	if(battery_module == H)
+		battery_module = null
+		found = 1
+	if(found)
+		user << "You remove \the [H] from \the [src]."
+		H.forceMove(get_turf(src))
+		H.holder2 = null
+	if(critical)
+		user << "<span class='danger'>\The [src]'s screen freezes for few seconds and then displays an \"HARDWARE ERROR: Critical component disconnected. Please verify component connection and reboot the device. If the problem persists contact technical support for assistance.\" warning.</span>"
+		kill_program(1)
+		enabled = 0
+		update_icon()
+
+
+// Checks all hardware pieces to determine if name matches, if yes, returns the hardware piece, otherwise returns null
+/obj/item/modular_computer/proc/find_hardware_by_name(var/name)
+	if(portable_drive && (portable_drive.name == name))
+		return portable_drive
+	if(hard_drive && (hard_drive.name == name))
+		return hard_drive
+	if(network_card && (network_card.name == name))
+		return network_card
+	if(nano_printer && (nano_printer.name == name))
+		return nano_printer
+	if(card_slot && (card_slot.name == name))
+		return card_slot
+	if(battery_module && (battery_module.name == name))
+		return battery_module
+	return null
+
+// Returns list of all components
+/obj/item/modular_computer/proc/get_all_components()
+	var/list/all_components = list()
+	if(hard_drive)
+		all_components.Add(hard_drive)
+	if(network_card)
+		all_components.Add(network_card)
+	if(portable_drive)
+		all_components.Add(portable_drive)
+	if(nano_printer)
+		all_components.Add(nano_printer)
+	if(card_slot)
+		all_components.Add(card_slot)
+	if(battery_module)
+		all_components.Add(battery_module)
+	return all_components

code/modules/modular_computers/computers/item/processor.dm

@@ -0,0 +1,115 @@
+// Held by /obj/machinery/modular_computer to reduce amount of copy-pasted code.
+/obj/item/modular_computer/processor
+	name = "processing unit"
+	desc = "You shouldn't see this. If you do, report it."
+	icon = null
+	icon_state = null
+	icon_state_unpowered = null
+	icon_state_menu = null
+	hardware_flag = 0
+
+	var/obj/machinery/modular_computer/machinery_computer = null
+
+// Due to how processes work, we'd receive two process calls - one from machinery type and one from our own type.
+// Since we want this to be in-sync with machinery (as it's hidden type for machinery-based computers) we'll ignore
+// non-relayed process calls.
+/obj/item/modular_computer/processor/process(var/relayed = 0)
+	if(relayed)
+		..()
+	else
+		return
+
+// Power interaction is handled by our machinery part, due to machinery having APC connection.
+/obj/item/modular_computer/processor/handle_power()
+	if(machinery_computer)
+		machinery_computer.handle_power()
+
+/obj/item/modular_computer/processor/New(var/comp)
+	if(!comp || !istype(comp, /obj/machinery/modular_computer))
+		CRASH("Inapropriate type passed to obj/item/modular_computer/processor/New()! Aborting.")
+		return
+	// Obtain reference to machinery computer
+	machinery_computer = comp
+	machinery_computer.cpu = src
+	hardware_flag = machinery_computer.hardware_flag
+	max_hardware_size = machinery_computer.max_hardware_size
+	steel_sheet_cost = machinery_computer.steel_sheet_cost
+
+/obj/item/modular_computer/processor/relay_qdel()
+	qdel(machinery_computer)
+
+/obj/item/modular_computer/processor/find_hardware_by_name(var/N)
+	var/obj/item/weapon/computer_hardware/H = machinery_computer.find_hardware_by_name(N)
+	if(H)
+		return H
+	else
+		return ..()
+
+/obj/item/modular_computer/processor/update_icon()
+	if(machinery_computer)
+		return machinery_computer.update_icon()
+
+/obj/item/modular_computer/processor/get_header_data()
+	var/list/L = ..()
+	if(machinery_computer.tesla_link && machinery_computer.tesla_link.enabled && machinery_computer.powered())
+		L["PC_apclinkicon"] = "charging.gif"
+	return L
+
+// Checks whether the machinery computer doesn't take power from APC network
+/obj/item/modular_computer/processor/check_power_override()
+	if(!machinery_computer)
+		return 0
+	if(!machinery_computer.tesla_link || !machinery_computer.tesla_link.enabled)
+		return 0
+	return machinery_computer.powered()
+
+// This thing is not meant to be used on it's own, get topic data from our machinery owner.
+/obj/item/modular_computer/processor/CanUseTopic(user, state)
+	if(!machinery_computer)
+		return 0
+	return machinery_computer.CanUseTopic(user, state)
+
+/obj/item/modular_computer/processor/shutdown_computer()
+	if(!machinery_computer)
+		return
+	kill_program(1)
+	visible_message("\The [machinery_computer] shuts down.")
+	enabled = 0
+	machinery_computer.update_icon()
+	return
+
+// Tesla links only work on machinery types, so we'll override the default try_install_component() proc
+/obj/item/modular_computer/processor/try_install_component(var/mob/living/user, var/obj/item/weapon/computer_hardware/H, var/found = 0)
+	if(istype(H, /obj/item/weapon/computer_hardware/tesla_link))
+		if(machinery_computer.tesla_link)
+			user << "This computer's tesla link slot is already occupied by \the [machinery_computer.tesla_link]."
+			return
+		var/obj/item/weapon/computer_hardware/tesla_link/L = H
+		L.holder = machinery_computer
+		machinery_computer.tesla_link = L
+		// Consoles don't usually have internal power source, so we can't disable tesla link in them.
+		if(istype(machinery_computer, /obj/machinery/modular_computer/console))
+			L.critical = 1
+		found = 1
+	..(user, H, found)
+
+/obj/item/modular_computer/processor/uninstall_component(var/mob/living/user, var/obj/item/weapon/computer_hardware/H, var/found = 0, var/critical = 0)
+	if(machinery_computer.tesla_link == H)
+		machinery_computer.tesla_link = null
+		var/obj/item/weapon/computer_hardware/tesla_link/L = H
+		L.critical = 0		// That way we can install tesla link from console to laptop and it will be possible to turn it off via config.
+		L.holder = null
+		found = 1
+	..(user, H, found, critical)
+
+/obj/item/modular_computer/processor/get_all_components()
+	var/list/all_components = ..()
+	if(machinery_computer.tesla_link)
+		all_components.Add(machinery_computer.tesla_link)
+	return all_components
+
+// Perform adjacency checks on our machinery counterpart, rather than on ourselves.
+/obj/item/modular_computer/processor/Adjacent(var/atom/neighbor)
+	if(!machinery_computer)
+		return 0
+	return machinery_computer.Adjacent(neighbor) 

code/modules/modular_computers/computers/item/tablet.dm

@@ -0,0 +1,8 @@
+/obj/item/modular_computer/tablet
+	name = "tablet computer"
+	icon = 'icons/obj/modular_tablet.dmi'
+	icon_state = "tablet"
+	icon_state_unpowered = "tablet"
+	icon_state_menu = "menu"
+	hardware_flag = PROGRAM_TABLET
+	max_hardware_size = 1 

code/modules/modular_computers/computers/machinery/modular_computer.dm

@@ -0,0 +1,137 @@
+// Modular Computer - device that runs various programs and operates with hardware
+// DO NOT SPAWN THIS TYPE. Use /laptop/ or /console/ instead.
+/obj/machinery/modular_computer/
+	name = "modular computer"
+	desc = "An advanced computer"
+
+	var/battery_powered = 0											// Whether computer should be battery powered. It is set automatically
+	use_power = 0
+	var/hardware_flag = 0											// A flag that describes this device type
+	var/last_power_usage = 0										// Power usage during last tick
+
+	// Modular computers can run on various devices. Each DEVICE (Laptop, Console, Tablet,..)
+	// must have it's own DMI file. Icon states must be called exactly the same in all files, but may look differently
+	// If you create a program which is limited to Laptops and Consoles you don't have to add it's icon_state overlay for Tablets too, for example.
+
+	icon = null
+	icon_state = null
+	var/icon_state_unpowered = null									// Icon state when the computer is turned off
+	var/screen_icon_state_menu = "menu"								// Icon state overlay when the computer is turned on, but no program is loaded that would override the screen.
+	var/max_hardware_size = 0										// Maximal hardware size. Currently, tablets have 1, laptops 2 and consoles 3. Limits what hardware types can be installed.
+	var/steel_sheet_cost = 10										// Amount of steel sheets refunded when disassembling an empty frame of this computer.
+
+	var/base_active_power_usage = 100								// Power usage when the computer is open (screen is active) and can be interacted with. Remember hardware can use power too.
+	var/base_idle_power_usage = 10									// Power usage when the computer is idle and screen is off (currently only applies to laptops)
+
+	var/obj/item/weapon/computer_hardware/tesla_link/tesla_link		// Tesla Link component of this computer. Allows remote charging from nearest APC.
+
+	var/obj/item/modular_computer/processor/cpu = null				// CPU that handles most logic while this type only handles power and other specific things.
+
+/obj/machinery/modular_computer/emag_act(var/remaining_charges, var/mob/user)
+	return //cpu ? cpu.emag_act(remaining_charges, user) : NO_EMAG_ACT
+
+/obj/machinery/modular_computer/update_icon()
+	icon_state = icon_state_unpowered
+	overlays.Cut()
+
+	if(!cpu || !cpu.enabled)
+		return
+	if(cpu.active_program)
+		overlays.Add(cpu.active_program.program_icon_state ? cpu.active_program.program_icon_state : screen_icon_state_menu)
+	else
+		overlays.Add(screen_icon_state_menu)
+
+// Eject ID card from computer, if it has ID slot with card inside.
+/obj/machinery/modular_computer/verb/eject_id()
+	set name = "Eject ID"
+	set category = "Object"
+	set src in view(1)
+
+	if(cpu)
+		cpu.eject_id()
+
+/obj/machinery/modular_computer/New()
+	..()
+	cpu = new(src)
+
+// On-click handling. Turns on the computer if it's off and opens the GUI.
+/obj/machinery/modular_computer/attack_hand(mob/user)
+	if(cpu)
+		cpu.attack_self(user) // CPU is an item, that's why we route attack_hand to attack_self
+
+// Process currently calls handle_power(), may be expanded in future if more things are added.
+/obj/machinery/modular_computer/process()
+	if(cpu)
+		// Keep names in sync.
+		cpu.name = src.name
+		cpu.process(1)
+
+// Checks all hardware pieces to determine if name matches, if yes, returns the hardware piece, otherwise returns null
+/obj/machinery/modular_computer/proc/find_hardware_by_name(var/N)
+	if(tesla_link && (tesla_link.name == N))
+		return tesla_link
+	return null
+
+// Used in following function to reduce copypaste
+/obj/machinery/modular_computer/proc/power_failure()
+	if(cpu && cpu.enabled) // Shut down the computer
+		visible_message("<span class='danger'>\The [src]'s screen flickers [cpu.battery_module ? "\"BATTERY CRITICAL\"" : "\"EXTERNAL POWER LOSS\""] warning as it shuts down unexpectedly.</span>")
+		if(cpu)
+			cpu.kill_program(1)
+			cpu.enabled = 0
+		battery_powered = 0
+		update_icon()
+	stat |= NOPOWER
+
+// Called by cpu item's process() automatically, handles our power interaction.
+/obj/machinery/modular_computer/proc/handle_power()
+	if(cpu.battery_module && cpu.battery_module.battery.charge <= 0) // Battery-run but battery is depleted.
+		power_failure()
+		return 0
+	else if(!cpu.battery_module && (!powered() || !tesla_link || !tesla_link.enabled)) // Not battery run, but lacking APC connection.
+		power_failure()
+		return 0
+	else if(stat & NOPOWER)
+		stat &= ~NOPOWER
+
+	if(cpu.battery_module && cpu.battery_module.battery.charge)
+		battery_powered = 1
+	else
+		battery_powered = 0
+
+	var/power_usage = cpu.screen_on ? base_active_power_usage : base_idle_power_usage
+	for(var/obj/item/weapon/computer_hardware/CH in src.cpu.get_all_components())
+		if(CH.enabled)
+			power_usage += CH.power_usage
+
+	// Wireless APC connection exists.
+	if(tesla_link && tesla_link.enabled)
+		idle_power_usage = power_usage
+		active_power_usage = idle_power_usage + 100 	// APCLink only charges at 100W rate, but covers any power usage.
+		use_power = 1
+		// Battery is not fully charged. Begin slowly recharging.
+		if(cpu.battery_module && (cpu.battery_module.battery.charge < cpu.battery_module.battery.maxcharge))
+			use_power = 2
+
+		if(cpu.battery_module && powered() && (use_power == 2)) // Battery charging itself
+			cpu.battery_module.battery.give(100 * CELLRATE)
+		else if(cpu.battery_module && !powered()) // Unpowered, but battery covers the usage.
+			cpu.battery_module.battery.use(idle_power_usage * CELLRATE)
+
+	else	// No wireless connection run only on battery.
+		use_power = 0
+		if (cpu.battery_module)
+			cpu.battery_module.battery.use(power_usage * CELLRATE)
+	cpu.last_power_usage = power_usage
+
+// Modular computers can have battery in them, we handle power in previous proc, so prevent this from messing it up for us.
+/obj/machinery/modular_computer/power_change()
+	if(battery_powered)
+		return
+	else
+		..()
+
+/obj/machinery/modular_computer/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
+	if(cpu)
+		return cpu.attackby(W, user)
+	return ..()

code/modules/modular_computers/computers/machinery/modular_console.dm

@@ -0,0 +1,45 @@
+/obj/machinery/modular_computer/console/
+	name = "console"
+	desc = "A stationary computer."
+
+	icon = 'icons/obj/modular_console.dmi'
+	icon_state = "console"
+	icon_state_unpowered = "console"
+	screen_icon_state_menu = "menu"
+	hardware_flag = PROGRAM_CONSOLE
+	var/console_department = "" // Used in New() to set network tag according to our area.
+	anchored = 1
+	density = 1
+	base_idle_power_usage = 100
+	base_active_power_usage = 500
+	max_hardware_size = 3
+	steel_sheet_cost = 20
+
+/obj/machinery/modular_computer/console/buildable/New()
+	..()
+	// User-built consoles start as empty frames.
+	qdel(tesla_link)
+	qdel(cpu.network_card)
+	qdel(cpu.hard_drive)
+
+/obj/machinery/modular_computer/console/New()
+	..()
+	cpu.battery_module = null
+	cpu.network_card = new/obj/item/weapon/computer_hardware/network_card/wired(src)
+	tesla_link = new/obj/item/weapon/computer_hardware/tesla_link(src)
+	tesla_link.enabled = 1
+	tesla_link.critical = 1 // Consoles don't usually come with cells, and this prevents people from disabling their only power source, as they wouldn't be able to enable it again.
+	cpu.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive/super(src) // Consoles generally have better HDDs due to lower space limitations
+	var/area/A = get_area(src)
+	// Attempts to set this console's tag according to our area. Since some areas have stuff like "XX - YY" in their names we try to remove that too.
+	if(A && console_department)
+		cpu.network_card.identification_string = replacetext(replacetext(replacetext("[A.name] [console_department] Console", " ", "_"), "-", ""), "__", "_") // Replace spaces with "_"
+	else if(A)
+		cpu.network_card.identification_string = replacetext(replacetext(replacetext("[A.name] Console", " ", "_"), "-", ""), "__", "_")
+	else if(console_department)
+		cpu.network_card.identification_string = replacetext(replacetext(replacetext("[console_department] Console", " ", "_"), "-", ""), "__", "_")
+	else
+		cpu.network_card.identification_string = "Unknown Console"
+	if(cpu)
+		cpu.screen_on = 1
+	update_icon() 

code/modules/modular_computers/computers/machinery/modular_laptop.dm

@@ -0,0 +1,107 @@
+// Laptop in it's item state, can be carried around.
+
+/obj/item/laptop
+	name		= "laptop computer"
+	desc		= "A portable computer. It is closed."
+	icon		= 'icons/obj/modular_laptop.dmi'
+	icon_state	= "laptop-closed"
+	item_state	= "laptop-inhand"
+	w_class		= 3
+	var/obj/machinery/modular_computer/laptop/stored_computer = null
+
+/obj/item/laptop/verb/open_computer()
+	set name = "Open Laptop"
+	set category = "Object"
+	set src in view(1)
+
+	if(usr.stat || usr.restrained() || usr.lying || !istype(usr, /mob/living))
+		usr << "<span class='warning'>You can't do that.</span>"
+		return
+
+	if(!Adjacent(usr))
+		usr << "You can't reach it."
+		return
+
+	if(!istype(loc,/turf))
+		usr << "[src] is too bulky!  You'll have to set it down."
+		return
+
+	if(!stored_computer)
+		if(contents.len)
+			for(var/obj/O in contents)
+				O.forceMove(src.loc)
+		usr << "\The [src] crumbles to pieces."
+		spawn(5)
+			qdel(src)
+		return
+
+	stored_computer.forceMove(src.loc)
+	stored_computer.stat &= ~MAINT
+	stored_computer.update_icon()
+	if(stored_computer.cpu)
+		stored_computer.cpu.screen_on = 1
+	loc = stored_computer
+	usr << "You open \the [src]."
+
+
+/obj/item/laptop/AltClick()
+	if(Adjacent(usr))
+		open_computer()
+
+// The actual laptop
+/obj/machinery/modular_computer/laptop
+	name = "laptop computer"
+	desc = "A portable computer"
+	var/obj/item/laptop/portable = null						// Portable version of this computer, dropped on alt-click to allow transport. Used by laptops.
+	hardware_flag = PROGRAM_LAPTOP
+	icon_state_unpowered = "laptop-open"					// Icon state when the computer is turned off
+	icon = 'icons/obj/modular_laptop.dmi'
+	icon_state = "laptop-open"
+	base_idle_power_usage = 25
+	base_active_power_usage = 200
+	max_hardware_size = 2
+
+/obj/machinery/modular_computer/laptop/buildable/New()
+	..()
+	// User-built consoles start as empty frames.
+	qdel(tesla_link)
+	qdel(cpu.network_card)
+	qdel(cpu.hard_drive)
+
+// Close the computer. collapsing it into movable item that can't be used.
+/obj/machinery/modular_computer/laptop/verb/close_computer()
+	set name = "Close Laptop"
+	set category = "Object"
+	set src in view(1)
+
+	if(usr.stat || usr.restrained() || usr.lying || !istype(usr, /mob/living))
+		usr << "<span class='warning'>You can't do that.</span>"
+		return
+
+	if(!Adjacent(usr))
+		usr << "<span class='warning'>You can't reach it.</span>"
+		return
+
+	close_laptop(usr)
+
+/obj/machinery/modular_computer/laptop/proc/close_laptop(mob/user = null)
+	if(istype(loc,/obj/item/laptop))
+		return
+	if(!istype(loc,/turf))
+		return
+
+	if(!portable)
+		portable=new
+		portable.stored_computer = src
+
+	portable.forceMove(src.loc)
+	src.forceMove(portable)
+	stat |= MAINT
+	if(user)
+		user << "You close \the [src]."
+	if(cpu)
+		cpu.screen_on = 0
+
+/obj/machinery/modular_computer/laptop/AltClick()
+	if(Adjacent(usr))
+		close_laptop() 

code/modules/modular_computers/file_system/computer_file.dm

@@ -0,0 +1,39 @@
+var/global/file_uid = 0
+
+/datum/computer_file/
+	var/filename = "NewFile" 								// Placeholder. No spacebars
+	var/filetype = "XXX" 									// File full names are [filename].[filetype] so like NewFile.XXX in this case
+	var/size = 1											// File size in GQ. Integers only!
+	var/obj/item/weapon/computer_hardware/hard_drive/holder	// Holder that contains this file.
+	var/unsendable = 0										// Whether the file may be sent to someone via NTNet transfer or other means.
+	var/undeletable = 0										// Whether the file may be deleted. Setting to 1 prevents deletion/renaming/etc.
+	var/uid													// UID of this file
+
+/datum/computer_file/New()
+	..()
+	uid = file_uid
+	file_uid++
+
+/datum/computer_file/Destroy()
+	if(!holder)
+		return ..()
+
+	holder.remove_file(src)
+	// holder.holder is the computer that has drive installed. If we are Destroy()ing program that's currently running kill it.
+	if(holder.holder2 && holder.holder2.active_program == src)
+		holder.holder2.kill_program(1)
+	holder = null
+	..()
+
+// Returns independent copy of this file.
+/datum/computer_file/proc/clone(var/rename = 0)
+	var/datum/computer_file/temp = new type
+	temp.unsendable = unsendable
+	temp.undeletable = undeletable
+	temp.size = size
+	if(rename)
+		temp.filename = filename + "(Copy)"
+	else
+		temp.filename = filename
+	temp.filetype = filetype
+	return temp 

code/modules/modular_computers/file_system/data.dm

@@ -0,0 +1,17 @@
+// /data/ files store data in string format.
+// They don't contain other logic for now.
+/datum/computer_file/data
+	var/stored_data = "" 			// Stored data in string format.
+	filetype = "DAT"
+
+/datum/computer_file/data/clone()
+	var/datum/computer_file/data/temp = ..()
+	temp.stored_data = stored_data
+	return temp
+
+// Calculates file size from amount of characters in saved string
+/datum/computer_file/data/proc/calculate_size(var/block_size = 250)
+	size = max(1, round(length(stored_data) / block_size))
+
+/datum/computer_file/data/logfile
+	filetype = "LOG"

code/modules/modular_computers/file_system/program.dm

@@ -0,0 +1,127 @@
+// /program/ files are executable programs that do things.
+/datum/computer_file/program
+	filetype = "PRG"
+	filename = "UnknownProgram"				// File name. FILE NAME MUST BE UNIQUE IF YOU WANT THE PROGRAM TO BE DOWNLOADABLE FROM NTNET!
+	var/required_access = null				// List of required accesses to *run* the program.
+	var/datum/nano_module/NM = null			// If the program uses NanoModule, put it here and it will be automagically opened. Otherwise implement ui_interact.
+	var/nanomodule_path = null				// Path to nanomodule, make sure to set this if implementing new program.
+	var/running = 0							// Set to 1 when the program is run and back to 0 when it's stopped.
+	var/obj/item/modular_computer/computer	// Device that runs this program.
+	var/filedesc = "Unknown Program"		// User-friendly name of this program.
+	var/extended_desc = "N/A"				// Short description of this program's function.
+	var/program_icon_state = null			// Program-specific screen icon state
+	var/requires_ntnet = 0					// Set to 1 for program to require nonstop NTNet connection to run. If NTNet connection is lost program crashes.
+	var/requires_ntnet_feature = 0			// Optional, if above is set to 1 checks for specific function of NTNet (currently NTNET_SOFTWAREDOWNLOAD, NTNET_PEERTOPEER, NTNET_SYSTEMCONTROL and NTNET_COMMUNICATION)
+	var/ntnet_status = 1					// NTNet status, updated every tick by computer running this program. Don't use this for checks if NTNet works, computers do that. Use this for calculations, etc.
+	var/usage_flags = PROGRAM_ALL			// Bitflags (PROGRAM_CONSOLE, PROGRAM_LAPTOP, PROGRAM_TABLET combination) or PROGRAM_ALL
+	var/network_destination = null			// Optional string that describes what NTNet server/system this program connects to. Used in default logging.
+	var/available_on_ntnet = 1				// Whether the program can be downloaded from NTNet. Set to 0 to disable.
+	var/available_on_syndinet = 0			// Whether the program can be downloaded from SyndiNet (accessible via emagging the computer). Set to 1 to enable.
+	var/computer_emagged = 0				// Set to 1 if computer that's running us was emagged. Computer updates this every Process() tick
+
+/datum/computer_file/program/New(var/obj/item/modular_computer/comp = null)
+	..()
+	if(comp && istype(comp))
+		computer = comp
+
+/datum/computer_file/program/clone()
+	var/datum/computer_file/program/temp = ..()
+	temp.required_access = required_access
+	temp.nanomodule_path = nanomodule_path
+	temp.filedesc = filedesc
+	temp.program_icon_state = program_icon_state
+	temp.requires_ntnet = requires_ntnet
+	temp.requires_ntnet_feature = requires_ntnet_feature
+	temp.usage_flags = usage_flags
+	return temp
+
+// Attempts to create a log in global ntnet datum. Returns 1 on success, 0 on fail.
+/datum/computer_file/program/proc/generate_network_log(var/text)
+	if(computer)
+		return computer.add_log(text)
+	return 0
+
+/datum/computer_file/program/proc/is_supported_by_hardware(var/hardware_flag = 0, var/loud = 0, var/mob/user = null)
+	if(!(hardware_flag & usage_flags))
+		if(loud && computer && user)
+			user << "<span class='danger'>\The [computer] flashes an \"Hardware Error - Incompatible software\" warning.</span>"
+		return 0
+	return 1
+
+// Called by Process() on device that runs us, once every tick.
+/datum/computer_file/program/proc/process_tick()
+	return 1
+
+// Check if the user can run program. Only humans can operate computer. Automatically called in run_program()
+// User has to wear their ID or have it inhand for ID Scan to work.
+// Can also be called manually, with optional parameter being access_to_check to scan the user's ID
+/datum/computer_file/program/proc/can_run(var/mob/living/user, var/loud = 0, var/access_to_check)
+	// Defaults to required_access
+	if(!access_to_check)
+		access_to_check = required_access
+	if(!access_to_check) // No required_access, allow it.
+		return 1
+
+	var/obj/item/weapon/card/id/I = user.GetIdCard()
+	if(!I)
+		if(loud)
+			user << "<span class='danger'>\The [computer] flashes an \"RFID Error - Unable to scan ID\" warning.</span>"
+		return 0
+
+	if(access_to_check in I.access)
+		return 1
+	else if(loud)
+		user << "<span class='danger'>\The [computer] flashes an \"Access Denied\" warning.</span>"
+
+// This attempts to retrieve header data for NanoUIs. If implementing completely new device of different type than existing ones
+// always include the device here in this proc. This proc basically relays the request to whatever is running the program.
+/datum/computer_file/program/proc/get_header_data()
+	if(computer)
+		return computer.get_header_data()
+	return list()
+
+// This is performed on program startup. May be overriden to add extra logic. Remember to include ..() call. Return 1 on success, 0 on failure.
+// When implementing new program based device, use this to run the program.
+/datum/computer_file/program/proc/run_program(var/mob/living/user)
+	if(can_run(user, 1))
+		if(nanomodule_path)
+			NM = new nanomodule_path(computer)	// Computer is passed here as it's (probably!) physical object. Some UI's perform get_turf() and passing program datum wouldn't go well with this.
+			NM.program = src					// Set the program reference to separate variable, instead.
+		if(requires_ntnet && network_destination)
+			generate_network_log("Connection opened to [network_destination].")
+		running = 1
+		return 1
+	return 0
+
+// Use this proc to kill the program. Designed to be implemented by each program if it requires on-quit logic, such as the NTNRC client.
+/datum/computer_file/program/proc/kill_program(var/forced = 0)
+	running = 0
+	if(network_destination)
+		generate_network_log("Connection to [network_destination] closed.")
+	if(NM)
+		qdel(NM)
+		NM = null
+	return 1
+
+// This is called every tick when the program is enabled. Ensure you do parent call if you override it. If parent returns 1 continue with UI initialisation.
+// It returns 0 if it can't run or if NanoModule was used instead. I suggest using NanoModules where applicable.
+/datum/computer_file/program/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+	if(!running) // Our program was closed. Close the ui if it exists.
+		if(ui)
+			ui.close()
+		return computer.ui_interact(user)
+	if(istype(NM))
+		NM.ui_interact(user, ui_key, null, force_open)
+		return 0
+	return 1
+
+
+// CONVENTIONS, READ THIS WHEN CREATING NEW PROGRAM AND OVERRIDING THIS PROC:
+// Topic calls are automagically forwarded from NanoModule this program contains.
+// Calls beginning with "PRG_" are reserved for programs handling.
+// Calls beginning with "PC_" are reserved for computer handling (by whatever runs the program)
+// ALWAYS INCLUDE PARENT CALL ..() OR DIE IN FIRE.
+/datum/computer_file/program/Topic(href, href_list)
+	if(computer)
+		computer.Topic(href, href_list)
+	..()

code/modules/modular_computers/file_system/programs/_engineering.dm

@@ -0,0 +1,48 @@
+// These programs are associated with engineering.
+
+/datum/computer_file/program/power_monitor
+	filename = "powermonitor"
+	filedesc = "Power Monitoring"
+	nanomodule_path = /datum/nano_module/power_monitor/
+	program_icon_state = "power_monitor"
+	extended_desc = "This program connects to sensors around the station to provide information about electrical systems"
+	required_access = access_engine
+	requires_ntnet = 1
+	network_destination = "power monitoring system"
+	size = 9
+
+/datum/computer_file/program/alarm_monitor
+	filename = "alarmmonitor"
+	filedesc = "Alarm Monitoring"
+	nanomodule_path = /datum/nano_module/alarm_monitor/engineering
+	program_icon_state = "alarm_monitor"
+	extended_desc = "This program provides visual interface for station's alarm system."
+	requires_ntnet = 1
+	network_destination = "alarm monitoring network"
+	size = 5
+
+/datum/computer_file/program/atmos_control
+	filename = "atmoscontrol"
+	filedesc = "Atmosphere Control"
+	nanomodule_path = /datum/nano_module/atmos_control
+	program_icon_state = "atmos_control"
+	extended_desc = "This program allows remote control of air alarms around the station"
+	required_access = access_atmospherics
+	requires_ntnet = 1
+	network_destination = "atmospheric control system"
+	requires_ntnet_feature = NTNET_SYSTEMCONTROL
+	usage_flags = PROGRAM_LAPTOP | PROGRAM_CONSOLE
+	size = 17
+
+/datum/computer_file/program/rcon_console
+	filename = "rconconsole"
+	filedesc = "RCON Remote Control"
+	nanomodule_path = /datum/nano_module/rcon
+	program_icon_state = "generic"
+	extended_desc = "This program allows remote control of power distribution systems around the station."
+	required_access = access_engine
+	requires_ntnet = 1
+	network_destination = "RCON remote control system"
+	requires_ntnet_feature = NTNET_SYSTEMCONTROL
+	usage_flags = PROGRAM_LAPTOP | PROGRAM_CONSOLE
+	size = 19 

code/modules/modular_computers/file_system/programs/_medical.dm

@@ -0,0 +1,10 @@
+/datum/computer_file/program/suit_sensors
+	filename = "sensormonitor"
+	filedesc = "Suit Sensors Monitoring"
+	nanomodule_path = /datum/nano_module/crew_monitor
+	program_icon_state = "crew"
+	extended_desc = "This program connects to life signs monitoring system to provide basic information on crew health."
+	required_access = access_medical
+	requires_ntnet = 1
+	network_destination = "crew lifesigns monitoring system"
+	size = 11 

code/modules/modular_computers/file_system/programs/antagonist/dos.dm

@@ -0,0 +1,104 @@
+/datum/computer_file/program/ntnet_dos
+	filename = "ntn_dos"
+	filedesc = "DoS Traffic Generator"
+	program_icon_state = "hostile"
+	extended_desc = "This advanced script can perform denial of service attacks against NTNet quantum relays. The system administrator will probably notice this. Multiple devices can run this program together against same relay for increased effect"
+	size = 20
+	requires_ntnet = 1
+	available_on_ntnet = 0
+	available_on_syndinet = 1
+	nanomodule_path = /datum/nano_module/computer_dos/
+	var/obj/machinery/ntnet_relay/target = null
+	var/dos_speed = 0
+	var/error = ""
+	var/executed = 0
+
+/datum/computer_file/program/ntnet_dos/process_tick()
+	dos_speed = 0
+	switch(ntnet_status)
+		if(1)
+			dos_speed = NTNETSPEED_LOWSIGNAL * 10
+		if(2)
+			dos_speed = NTNETSPEED_HIGHSIGNAL * 10
+		if(3)
+			dos_speed = NTNETSPEED_ETHERNET * 10
+	if(target && executed)
+		target.dos_overload += dos_speed
+		if(target.is_operational())
+			target.dos_sources.Remove(src)
+			target = null
+			error = "Connection to destination relay lost."
+
+/datum/computer_file/program/ntnet_dos/kill_program(var/forced)
+	target.dos_sources.Remove(src)
+	target = null
+	executed = 0
+
+	..(forced)
+
+/datum/nano_module/computer_dos
+	name = "DoS Traffic Generator"
+
+/datum/nano_module/computer_dos/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global)
+		return
+	var/datum/computer_file/program/ntnet_dos/PRG = program
+	var/list/data = list()
+	if(!istype(PRG))
+		return
+	data = PRG.get_header_data()
+
+	if(PRG.error)
+		data["error"] = PRG.error
+	else if(PRG.target && PRG.executed)
+		data["target"] = 1
+		data["speed"] = PRG.dos_speed
+
+		// This is mostly visual, generate some strings of 1s and 0s
+		// Probability of 1 is equal of completion percentage of DoS attack on this relay.
+		// Combined with UI updates this adds quite nice effect to the UI
+		var/percentage = PRG.target.dos_overload * 100 / PRG.target.dos_capacity
+		var/list/strings[0]
+		for(var/j, j<10, j++)
+			var/string = ""
+			for(var/i, i<20, i++)
+				string = "[string][prob(percentage)]"
+			strings.Add(string)
+		data["dos_strings"] = strings
+	else
+		var/list/relays[0]
+		for(var/obj/machinery/ntnet_relay/R in ntnet_global.relays)
+			relays.Add(R.uid)
+		data["relays"] = relays
+		data["focus"] = PRG.target ? PRG.target.uid : null
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_dos.tmpl", "DoS Traffic Generator", 400, 250, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/computer_file/program/ntnet_dos/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_target_relay"])
+		for(var/obj/machinery/ntnet_relay/R in ntnet_global.relays)
+			if("[R.uid]" == href_list["PRG_target_relay"])
+				target = R
+		return
+	if(href_list["PRG_reset"])
+		target.dos_sources.Remove(src)
+		target = null
+		executed = 0
+		error = ""
+		return
+	if(href_list["PRG_execute"])
+		if(target)
+			executed = 1
+			target.dos_sources.Add(src)
+			if(ntnet_global.intrusion_detection_enabled)
+				ntnet_global.add_log("IDS WARNING - Excess traffic flood targeting relay [target.uid] detected from device: [computer.network_card.get_network_tag()]")
+				ntnet_global.intrusion_detection_alarm = 1
+		return

code/modules/modular_computers/file_system/programs/antagonist/revelation.dm

@@ -0,0 +1,77 @@
+/datum/computer_file/program/revelation
+	filename = "revelation"
+	filedesc = "Revelation"
+	program_icon_state = "hostile"
+	extended_desc = "This virus can destroy hard drive of system it is executed on. It may be obfuscated to look like another non-malicious program. Once armed, it will destroy the system upon next execution."
+	size = 13
+	requires_ntnet = 0
+	available_on_ntnet = 0
+	available_on_syndinet = 1
+	nanomodule_path = /datum/nano_module/revelation/
+	var/armed = 0
+
+/datum/computer_file/program/revelation/run_program(var/mob/living/user)
+	. = ..(user)
+	if(armed)
+		activate()
+
+/datum/computer_file/program/revelation/proc/activate()
+	if(computer)
+		computer.visible_message("<span class='notice'>\The [computer]'s screen brightly flashes and loud electrical buzzing is heard.</span>")
+		computer.enabled = 0
+		computer.update_icon()
+		qdel(computer.hard_drive)
+		if(computer.battery_module && prob(25))
+			qdel(computer.battery_module)
+			computer.visible_message("<span class='notice'>\The [computer]'s battery explodes in rain of sparks.</span>")
+			var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+			s.set_up(10, 1, computer.loc)
+			s.start()
+		if(istype(computer, /obj/item/modular_computer/processor))
+			var/obj/item/modular_computer/processor/P = computer
+			if(P.machinery_computer.tesla_link && prob(50))
+				qdel(P.machinery_computer.tesla_link)
+				computer.visible_message("<span class='notice'>\The [computer]'s tesla link explodes in rain of sparks.</span>")
+				var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+				s.set_up(10, 1, computer.loc)
+				s.start()
+
+/datum/computer_file/program/revelation/Topic(href, href_list)
+	if(..())
+		return 1
+	else if(href_list["PRG_arm"])
+		armed = !armed
+	else if(href_list["PRG_activate"])
+		activate()
+	else if(href_list["PRG_obfuscate"])
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user, "Enter new program name: "))
+		if(!newname)
+			return
+		filedesc = newname
+
+/datum/computer_file/program/revelation/clone()
+	var/datum/computer_file/program/revelation/temp = ..()
+	temp.armed = armed
+	return temp
+
+/datum/nano_module/revelation
+	name = "Revelation Virus"
+
+/datum/nano_module/revelation/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	var/list/data = list()
+	var/datum/computer_file/program/revelation/PRG = program
+	if(!istype(PRG))
+		return
+
+	data = PRG.get_header_data()
+
+	data["armed"] = PRG.armed
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "revelation.tmpl", "Revelation Virus", 400, 250, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/configurator.dm

@@ -0,0 +1,80 @@
+// This is special hardware configuration program.
+// It is to be used only with modular computers.
+// It allows you to toggle components of your device.
+
+/datum/computer_file/program/computerconfig
+	filename = "compconfig"
+	filedesc = "Computer Configuration Tool"
+	extended_desc = "This program allows configuration of computer's hardware"
+	program_icon_state = "generic"
+	unsendable = 1
+	undeletable = 1
+	size = 4
+	available_on_ntnet = 0
+	requires_ntnet = 0
+	nanomodule_path = /datum/nano_module/computer_configurator/
+
+/datum/nano_module/computer_configurator
+	name = "NTOS Computer Configuration Tool"
+	var/obj/machinery/modular_computer/stationary = null
+	var/obj/item/modular_computer/movable = null
+
+/datum/nano_module/computer_configurator/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(program)
+		stationary = program.computer
+		movable = program.computer
+
+	if(!istype(stationary))
+		stationary = null
+	if(!istype(movable))
+		movable = null
+
+	// No computer connection, we can't get data from that.
+	if(!movable && !stationary)
+		return 0
+
+	var/list/data = list()
+
+	if(program)
+		data = program.get_header_data()
+
+	var/list/hardware = list()
+	if(stationary)
+		if(stationary.cpu)
+			movable = stationary.cpu
+			hardware.Add(stationary.tesla_link)
+		else
+			return
+
+	if(movable)
+		hardware.Add(movable.network_card)
+		hardware.Add(movable.hard_drive)
+		hardware.Add(movable.card_slot)
+		hardware.Add(movable.nano_printer)
+		hardware.Add(movable.battery_module)
+		data["disk_size"] = movable.hard_drive.max_capacity
+		data["disk_used"] = movable.hard_drive.used_capacity
+		data["power_usage"] = movable.last_power_usage
+		data["battery_exists"] = movable.battery_module ? 1 : 0
+		if(movable.battery_module)
+			data["battery_rating"] = movable.battery_module.battery.maxcharge
+			data["battery_percent"] = round(movable.battery_module.battery.percent())
+
+	var/list/all_entries[0]
+	for(var/obj/item/weapon/computer_hardware/H in hardware)
+		all_entries.Add(list(list(
+		"name" = H.name,
+		"desc" = H.desc,
+		"enabled" = H.enabled,
+		"critical" = H.critical,
+		"powerusage" = H.power_usage
+		)))
+
+	data["hardware"] = all_entries
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "laptop_configuration.tmpl", "NTOS Configuration Utility", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/file_browser.dm

@@ -0,0 +1,227 @@
+/datum/computer_file/program/filemanager
+	filename = "filemanager"
+	filedesc = "NTOS File Manager"
+	extended_desc = "This program allows management of files."
+	program_icon_state = "generic"
+	size = 8
+	requires_ntnet = 0
+	available_on_ntnet = 0
+	undeletable = 1
+	nanomodule_path = /datum/nano_module/computer_filemanager/
+	var/open_file
+	var/error
+
+/datum/computer_file/program/filemanager/Topic(href, href_list)
+	if(href_list["PRG_openfile"])
+		open_file = href_list["PRG_openfile"]
+	if(href_list["PRG_newtextfile"])
+		var/newname = sanitize(input(usr, "Enter file name or leave blank to cancel:", "File rename"))
+		if(!newname)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = new/datum/computer_file/data()
+		F.filename = newname
+		F.filetype = "TXT"
+		HDD.store_file(F)
+	if(href_list["PRG_deletefile"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/file = HDD.find_file_by_name(href_list["PRG_deletefile"])
+		if(!file || file.undeletable)
+			return
+		HDD.remove_file(file)
+	if(href_list["PRG_usbdeletefile"])
+		var/obj/item/weapon/computer_hardware/hard_drive/RHDD = computer.portable_drive
+		if(!RHDD)
+			return
+		var/datum/computer_file/file = RHDD.find_file_by_name(href_list["PRG_usbdeletefile"])
+		if(!file || file.undeletable)
+			return
+		RHDD.remove_file(file)
+	if(href_list["PRG_closefile"])
+		open_file = null
+		error = null
+	if(href_list["PRG_clone"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/F = HDD.find_file_by_name(href_list["PRG_clone"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(1)
+		HDD.store_file(C)
+	if(href_list["PRG_rename"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/file = HDD.find_file_by_name(href_list["PRG_rename"])
+		if(!file || !istype(file))
+			return
+		var/newname = sanitize(input(usr, "Enter new file name:", "File rename", file.filename))
+		if(file && newname)
+			file.filename = newname
+	if(href_list["PRG_edit"])
+		if(!open_file)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = HDD.find_file_by_name(open_file)
+		if(!F || !istype(F))
+			return
+		// 16384 is the limit for file length in characters. Currently, papers have value of 2048 so this is 8 times as long, since we can't edit parts of the file independently.
+		var/newtext = sanitize(html_decode(input(usr, "Editing file [open_file]. You may use most tags used in paper formatting:", "Text Editor", F.stored_data) as message), 16384)
+		if(F)
+			var/datum/computer_file/data/backup = F.clone()
+			HDD.remove_file(F)
+			F.stored_data = newtext
+			F.calculate_size()
+			// We can't store the updated file, it's probably too large. Print an error and restore backed up version.
+			// This is mostly intended to prevent people from losing texts they spent lot of time working on due to running out of space.
+			// They will be able to copy-paste the text from error screen and store it in notepad or something.
+			if(!HDD.store_file(F))
+				error = "I/O error: Unable to overwrite file. Hard drive is probably full. You may want to backup your changes before closing this window:<br><br>[F.stored_data]<br><br>"
+				HDD.store_file(backup)
+	if(href_list["PRG_printfile"])
+		if(!open_file)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = HDD.find_file_by_name(open_file)
+		if(!F || !istype(F))
+			return
+		if(!computer.nano_printer)
+			error = "Missing Hardware: Your computer does not have required hardware to complete this operation."
+			return
+		if(!computer.nano_printer.print_text(parse_tags(F.stored_data)))
+			error = "Hardware error: Printer was unable to print the file. It may be out of paper."
+			return
+	if(href_list["PRG_copytousb"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD = computer.portable_drive
+		if(!HDD || !RHDD)
+			return
+		var/datum/computer_file/F = HDD.find_file_by_name(href_list["PRG_copytousb"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(0)
+		RHDD.store_file(C)
+	if(href_list["PRG_copyfromusb"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD = computer.portable_drive
+		if(!HDD || !RHDD)
+			return
+		var/datum/computer_file/F = RHDD.find_file_by_name(href_list["PRG_copyfromusb"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(0)
+		HDD.store_file(C)
+	..(href, href_list)
+
+/datum/computer_file/program/filemanager/proc/parse_tags(var/t)
+	t = replacetext(t, "\[center\]", "<center>")
+	t = replacetext(t, "\[/center\]", "</center>")
+	t = replacetext(t, "\[br\]", "<BR>")
+	t = replacetext(t, "\[b\]", "<B>")
+	t = replacetext(t, "\[/b\]", "</B>")
+	t = replacetext(t, "\[i\]", "<I>")
+	t = replacetext(t, "\[/i\]", "</I>")
+	t = replacetext(t, "\[u\]", "<U>")
+	t = replacetext(t, "\[/u\]", "</U>")
+	t = replacetext(t, "\[time\]", "[stationtime2text()]")
+	t = replacetext(t, "\[date\]", "[stationdate2text()]")
+	t = replacetext(t, "\[large\]", "<font size=\"4\">")
+	t = replacetext(t, "\[/large\]", "</font>")
+	t = replacetext(t, "\[h1\]", "<H1>")
+	t = replacetext(t, "\[/h1\]", "</H1>")
+	t = replacetext(t, "\[h2\]", "<H2>")
+	t = replacetext(t, "\[/h2\]", "</H2>")
+	t = replacetext(t, "\[h3\]", "<H3>")
+	t = replacetext(t, "\[/h3\]", "</H3>")
+	t = replacetext(t, "\[*\]", "<li>")
+	t = replacetext(t, "\[hr\]", "<HR>")
+	t = replacetext(t, "\[small\]", "<font size = \"1\">")
+	t = replacetext(t, "\[/small\]", "</font>")
+	t = replacetext(t, "\[list\]", "<ul>")
+	t = replacetext(t, "\[/list\]", "</ul>")
+	t = replacetext(t, "\[table\]", "<table border=1 cellspacing=0 cellpadding=3 style='border: 1px solid black;'>")
+	t = replacetext(t, "\[/table\]", "</td></tr></table>")
+	t = replacetext(t, "\[grid\]", "<table>")
+	t = replacetext(t, "\[/grid\]", "</td></tr></table>")
+	t = replacetext(t, "\[row\]", "</td><tr>")
+	t = replacetext(t, "\[tr\]", "</td><tr>")
+	t = replacetext(t, "\[td\]", "<td>")
+	t = replacetext(t, "\[cell\]", "<td>")
+	t = replacetext(t, "\[logo\]", "<img src = ntlogo.png>")
+	return t
+
+
+/datum/nano_module/computer_filemanager
+	name = "NTOS File Manager"
+
+/datum/nano_module/computer_filemanager/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+
+	var/datum/computer_file/program/filemanager/PRG
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+		PRG = program
+	else
+		return
+
+	var/obj/item/weapon/computer_hardware/hard_drive/HDD
+	var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD
+	if(PRG.error)
+		data["error"] = PRG.error
+	if(PRG.open_file)
+		var/datum/computer_file/data/file
+
+		if(!PRG.computer || !PRG.computer.hard_drive)
+			data["error"] = "I/O ERROR: Unable to access hard drive."
+		else
+			HDD = PRG.computer.hard_drive
+			file = HDD.find_file_by_name(PRG.open_file)
+			if(!istype(file))
+				data["error"] = "I/O ERROR: Unable to open file."
+			else
+				data["filedata"] = PRG.parse_tags(file.stored_data)
+				data["filename"] = "[file.filename].[file.filetype]"
+	else
+		if(!PRG.computer || !PRG.computer.hard_drive)
+			data["error"] = "I/O ERROR: Unable to access hard drive."
+		else
+			HDD = PRG.computer.hard_drive
+			RHDD = PRG.computer.portable_drive
+			var/list/files[0]
+			for(var/datum/computer_file/F in HDD.stored_files)
+				files.Add(list(list(
+					"name" = F.filename,
+					"type" = F.filetype,
+					"size" = F.size,
+					"undeletable" = F.undeletable
+				)))
+			data["files"] = files
+			if(RHDD)
+				data["usbconnected"] = 1
+				var/list/usbfiles[0]
+				for(var/datum/computer_file/F in RHDD.stored_files)
+					usbfiles.Add(list(list(
+						"name" = F.filename,
+						"type" = F.filetype,
+						"size" = F.size,
+						"undeletable" = F.undeletable
+					)))
+				data["usbfiles"] = usbfiles
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "file_manager.tmpl", "NTOS File Manager", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+

code/modules/modular_computers/file_system/programs/ntdownloader.dm

@@ -0,0 +1,160 @@
+/datum/computer_file/program/ntnetdownload
+	filename = "ntndownloader"
+	filedesc = "NTNet Software Download Tool"
+	program_icon_state = "generic"
+	extended_desc = "This program allows downloads of software from official NT repositories"
+	unsendable = 1
+	undeletable = 1
+	size = 4
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_SOFTWAREDOWNLOAD
+	available_on_ntnet = 0
+	nanomodule_path = /datum/nano_module/computer_ntnetdownload/
+	var/datum/computer_file/program/downloaded_file = null
+	var/hacked_download = 0
+	var/download_completion = 0 //GQ of downloaded data.
+	var/download_netspeed = 0
+	var/downloaderror = ""
+
+/datum/computer_file/program/ntnetdownload/proc/begin_file_download(var/filename)
+	if(downloaded_file)
+		return 0
+
+	var/datum/computer_file/program/PRG = ntnet_global.find_ntnet_file_by_name(filename)
+
+	if(!PRG || !istype(PRG))
+		return 0
+
+	// Attempting to download antag only program, but without having emagged computer. No.
+	if(PRG.available_on_syndinet && !computer_emagged)
+		return 0
+
+	if(!computer || !computer.hard_drive || !computer.hard_drive.try_store_file(PRG))
+		return 0
+
+	if(PRG in ntnet_global.available_station_software)
+		generate_network_log("Began downloading file [PRG.filename].[PRG.filetype] from NTNet Software Repository.")
+		hacked_download = 0
+	else if(PRG in ntnet_global.available_antag_software)
+		generate_network_log("Began downloading file **ENCRYPTED**.[PRG.filetype] from unspecified server.")
+		hacked_download = 1
+	else
+		generate_network_log("Began downloading file [PRG.filename].[PRG.filetype] from unspecified server.")
+		hacked_download = 0
+
+	downloaded_file = PRG.clone()
+
+/datum/computer_file/program/ntnetdownload/proc/abort_file_download()
+	if(!downloaded_file)
+		return
+	generate_network_log("Aborted download of file [hacked_download ? "**ENCRYPTED**" : downloaded_file.filename].[downloaded_file.filetype].")
+	downloaded_file = null
+	download_completion = 0
+
+/datum/computer_file/program/ntnetdownload/proc/complete_file_download()
+	if(!downloaded_file)
+		return
+	generate_network_log("Completed download of file [hacked_download ? "**ENCRYPTED**" : downloaded_file.filename].[downloaded_file.filetype].")
+	if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(downloaded_file))
+		// The download failed
+		downloaderror = "I/O ERROR - Unable to save file. Check whether you have enough free space on your hard drive and whether your hard drive is properly connected. If the issue persists contact your system administrator for assistance."
+	downloaded_file = null
+	download_completion = 0
+
+/datum/computer_file/program/ntnetdownload/process_tick()
+	if(!downloaded_file)
+		return
+	if(download_completion >= downloaded_file.size)
+		complete_file_download()
+	// Download speed according to connectivity state. NTNet server is assumed to be on unlimited speed so we're limited by our local connectivity
+	download_netspeed = 0
+	// Speed defines are found in misc.dm
+	switch(ntnet_status)
+		if(1)
+			download_netspeed = NTNETSPEED_LOWSIGNAL
+		if(2)
+			download_netspeed = NTNETSPEED_HIGHSIGNAL
+		if(3)
+			download_netspeed = NTNETSPEED_ETHERNET
+	download_completion += download_netspeed
+
+/datum/computer_file/program/ntnetdownload/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_downloadfile"])
+		if(!downloaded_file)
+			begin_file_download(href_list["PRG_downloadfile"])
+		return
+	if(href_list["PRG_reseterror"])
+		if(downloaderror)
+			download_completion = 0
+			download_netspeed = 0
+			downloaded_file = null
+			downloaderror = ""
+		return
+	return 0
+
+
+/datum/nano_module/computer_ntnetdownload
+	name = "Network Downloader"
+	var/obj/item/modular_computer/my_computer = null
+
+/datum/nano_module/computer_ntnetdownload/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(program)
+		my_computer = program.computer
+
+	if(!istype(my_computer))
+		return
+
+	var/list/data = list()
+	var/datum/computer_file/program/ntnetdownload/prog = program
+	// For now limited to execution by the downloader program
+	if(!prog || !istype(prog))
+		return
+	if(program)
+		data = program.get_header_data()
+
+	// This IF cuts on data transferred to client, so i guess it's worth it.
+	if(prog.downloaderror) // Download errored. Wait until user resets the program.
+		data["error"] = prog.downloaderror
+	else if(prog.downloaded_file) // Download running. Wait please..
+		data["downloadname"] = prog.downloaded_file.filename
+		data["downloaddesc"] = prog.downloaded_file.filedesc
+		data["downloadsize"] = prog.downloaded_file.size
+		data["downloadspeed"] = prog.download_netspeed
+		data["downloadcompletion"] = round(prog.download_completion, 0.1)
+	else // No download running, pick file.
+		data["disk_size"] = my_computer.hard_drive.max_capacity
+		data["disk_used"] = my_computer.hard_drive.used_capacity
+		var/list/all_entries[0]
+		for(var/datum/computer_file/program/P in ntnet_global.available_station_software)
+			// Only those programs our user can run will show in the list
+			if(!P.can_run(user))
+				continue
+			all_entries.Add(list(list(
+			"filename" = P.filename,
+			"filedesc" = P.filedesc,
+			"fileinfo" = P.extended_desc,
+			"size" = P.size
+			)))
+		data["hackedavailable"] = 0
+		if(prog.computer_emagged) // If we are running on emagged computer we have access to some "bonus" software
+			var/list/hacked_programs[0]
+			for(var/datum/computer_file/program/P in ntnet_global.available_antag_software)
+				data["hackedavailable"] = 1
+				hacked_programs.Add(list(list(
+				"filename" = P.filename,
+				"filedesc" = P.filedesc,
+				"fileinfo" = P.extended_desc,
+				"size" = P.size
+				)))
+			data["hacked_programs"] = hacked_programs
+
+		data["downloadable_programs"] = all_entries
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_downloader.tmpl", "NTNet Download Program", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/ntmonitor.dm

@@ -0,0 +1,85 @@
+/datum/computer_file/program/ntnetmonitor
+	filename = "ntmonitor"
+	filedesc = "NTNet Diagnostics and Monitoring"
+	program_icon_state = "comm_monitor"
+	extended_desc = "This program monitors stationwide NTNet network, provides access to logging systems, and allows for configuration changes"
+	size = 12
+	requires_ntnet = 1
+	required_access = access_network
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_ntnetmonitor/
+
+/datum/nano_module/computer_ntnetmonitor
+	name = "NTNet Diagnostics and Monitoring"
+
+/datum/nano_module/computer_ntnetmonitor/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global)
+		return
+
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+
+
+	data["ntnetstatus"] = ntnet_global.check_function()
+	data["ntnetrelays"] = ntnet_global.relays.len
+	data["idsstatus"] = ntnet_global.intrusion_detection_enabled
+	data["idsalarm"] = ntnet_global.intrusion_detection_alarm
+
+	data["config_softwaredownload"] = ntnet_global.setting_softwaredownload
+	data["config_peertopeer"] = ntnet_global.setting_peertopeer
+	data["config_communication"] = ntnet_global.setting_communication
+	data["config_systemcontrol"] = ntnet_global.setting_systemcontrol
+
+	data["ntnetlogs"] = ntnet_global.logs
+	data["ntnetmaxlogs"] = ntnet_global.setting_maxlogcount
+
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_monitor.tmpl", "NTNet Diagnostics and Monitoring Tool", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/nano_module/computer_ntnetmonitor/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["resetIDS"])
+		if(ntnet_global)
+			ntnet_global.resetIDS()
+		return 1
+	if(href_list["toggleIDS"])
+		if(ntnet_global)
+			ntnet_global.toggleIDS()
+		return 1
+	if(href_list["toggleWireless"])
+		if(!ntnet_global)
+			return 1
+
+		// NTNet is disabled. Enabling can be done without user prompt
+		if(ntnet_global.setting_disabled)
+			ntnet_global.setting_disabled = 0
+			return 1
+
+		// NTNet is enabled and user is about to shut it down. Let's ask them if they really want to do it, as wirelessly connected computers won't connect without NTNet being enabled (which may prevent people from turning it back on)
+		var/mob/user = usr
+		if(!user)
+			return
+		var/response = alert(user, "Really disable NTNet wireless? If your computer is connected wirelessly you won't be able to turn it back on! This will affect all connected wireless devices.", "NTNet shutdown", "Yes", "No")
+		if(response == "Yes")
+			ntnet_global.setting_disabled = 1
+		return 1
+	if(href_list["purgelogs"])
+		if(ntnet_global)
+			ntnet_global.purge_logs()
+	if(href_list["updatemaxlogs"])
+		var/mob/user = usr
+		var/logcount = text2num(input(user,"Enter amount of logs to keep in memory ([MIN_NTNET_LOGS]-[MAX_NTNET_LOGS]):"))
+		if(ntnet_global)
+			ntnet_global.update_max_log_count(logcount)
+	if(href_list["toggle_function"])
+		if(!ntnet_global)
+			return
+		ntnet_global.toggle_function(href_list["toggle_function"])

code/modules/modular_computers/file_system/programs/ntnrc_client.dm

@@ -0,0 +1,201 @@
+/datum/computer_file/program/chatclient
+	filename = "ntnrc_client"
+	filedesc = "NTNet Relay Chat Client"
+	program_icon_state = "command"
+	extended_desc = "This program allows communication over NTNRC network"
+	size = 8
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_COMMUNICATION
+	network_destination = "NTNRC server"
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_chatclient/
+	var/username
+	var/datum/ntnet_conversation/channel = null
+	var/operator_mode = 0		// Channel operator mode
+	var/netadmin_mode = 0		// Administrator mode (invisible to other users + bypasses passwords)
+
+/datum/computer_file/program/chatclient/New()
+	username = "DefaultUser[rand(100, 999)]"
+
+/datum/computer_file/program/chatclient/Topic(href, href_list)
+	if(href_list["PRG_speak"])
+		if(!channel)
+			return
+		var/mob/living/user = usr
+		var/message = sanitize(input(user, "Enter message or leave blank to cancel: "))
+		if(!message || !channel)
+			return
+		channel.add_message(message, username)
+
+	if(href_list["PRG_joinchannel"])
+		var/datum/ntnet_conversation/C
+		for(var/datum/ntnet_conversation/chan in ntnet_global.chat_channels)
+			if(chan.title == href_list["PRG_joinchannel"])
+				C = chan
+				break
+
+		if(!C)
+			return
+
+		if(netadmin_mode)
+			channel = C		// Bypasses normal leave/join and passwords. Technically makes the user invisible to others.
+			return
+
+		if(C.password)
+			var/mob/living/user = usr
+			var/password = sanitize(input(user,"Access Denied. Enter password:"))
+			if(C && (password == C.password))
+				C.add_client(src)
+				channel = C
+			return
+		C.add_client(src)
+		channel = C
+	if(href_list["PRG_leavechannel"])
+		if(channel)
+			channel.remove_client(src)
+		channel = null
+	if(href_list["PRG_newchannel"])
+		var/mob/living/user = usr
+		var/channel_title = sanitize(input(user,"Enter channel name or leave blank to cancel:"))
+		if(!channel_title)
+			return
+		var/datum/ntnet_conversation/C = new/datum/ntnet_conversation()
+		C.add_client(src)
+		C.operator = src
+		channel = C
+		C.title = channel_title
+	if(href_list["PRG_toggleadmin"])
+		if(netadmin_mode)
+			netadmin_mode = 0
+			if(channel)
+				channel.remove_client(src) // We shouldn't be in channel's user list, but just in case...
+				channel = null
+			return
+		var/mob/living/user = usr
+		if(can_run(usr, 1, access_network))
+			if(channel)
+				var/response = alert(user, "Really engage admin-mode? You will be disconnected from your current channel!", "NTNRC Admin mode", "Yes", "No")
+				if(response == "Yes")
+					if(channel)
+						channel.remove_client(src)
+						channel = null
+				else
+					return
+			netadmin_mode = 1
+	if(href_list["PRG_changename"])
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user,"Enter new nickname or leave blank to cancel:"))
+		if(!newname)
+			return
+		if(channel)
+			channel.add_status_message("[username] is now known as [newname].")
+		username = newname
+
+	if(href_list["PRG_savelog"])
+		if(!channel)
+			return
+		var/mob/living/user = usr
+		var/logname = input(user,"Enter desired logfile name (.log) or leave blank to cancel:")
+		if(!logname || !channel)
+			return
+		var/datum/computer_file/data/logfile = new/datum/computer_file/data/logfile()
+		// Now we will generate HTML-compliant file that can actually be viewed/printed.
+		logfile.filename = logname
+		logfile.stored_data = "\[b\]Logfile dump from NTNRC channel [channel.title]\[/b\]\[BR\]"
+		for(var/logstring in channel.messages)
+			logfile.stored_data += "[logstring]\[BR\]"
+		logfile.stored_data += "\[b\]Logfile dump completed.\[/b\]"
+		logfile.calculate_size()
+		if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(logfile))
+			if(!computer)
+				// This program shouldn't even be runnable without computer.
+				CRASH("Var computer is null!")
+				return
+			if(!computer.hard_drive)
+				computer.visible_message("\The [computer] shows an \"I/O Error - Hard drive connection error\" warning.")
+			else	// In 99.9% cases this will mean our HDD is full
+				computer.visible_message("\The [computer] shows an \"I/O Error - Hard drive may be full. Please free some space and try again. Required space: [logfile.size]GQ\" warning.")
+	if(href_list["PRG_renamechannel"])
+		if(!operator_mode || !channel)
+			return
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user, "Enter new channel name or leave blank to cancel:"))
+		if(!newname || !channel)
+			return
+		channel.add_status_message("Channel renamed from [channel.title] to [newname] by operator.")
+		channel.title = newname
+	if(href_list["PRG_deletechannel"])
+		if(channel && ((channel.operator == src) || netadmin_mode))
+			del(channel)
+	if(href_list["PRG_setpassword"])
+		if(!channel || ((channel.operator != src) && !netadmin_mode))
+			return
+
+		var/mob/living/user = usr
+		var/newpassword = sanitize(input(user, "Enter new password for this channel. Leave blank to cancel, enter 'nopassword' to remove password completely:"))
+		if(!channel || !newpassword || ((channel.operator != src) && !netadmin_mode))
+			return
+
+		if(newpassword == "nopassword")
+			channel.password = ""
+		else
+			channel.password = newpassword
+
+	..(href, href_list)
+
+
+/datum/computer_file/program/chatclient/kill_program(var/forced = 0)
+	if(channel)
+		channel.remove_client(src)
+		channel = null
+	..(forced)
+
+/datum/nano_module/computer_chatclient
+	name = "NTNet Relay Chat Client"
+
+/datum/nano_module/computer_chatclient/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global || !ntnet_global.chat_channels)
+		return
+
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+
+	var/datum/computer_file/program/chatclient/C = program
+	if(!istype(C))
+		return
+
+	data["adminmode"] = C.netadmin_mode
+	if(C.channel)
+		data["title"] = C.channel.title
+		var/list/messages[0]
+		for(var/M in C.channel.messages)
+			messages.Add(list(list(
+				"msg" = M
+			)))
+		data["messages"] = messages
+		var/list/clients[0]
+		for(var/datum/computer_file/program/chatclient/cl in C.channel.clients)
+			clients.Add(list(list(
+				"name" = cl.username
+			)))
+		data["clients"] = clients
+		C.operator_mode = (C.channel.operator == C) ? 1 : 0
+		data["is_operator"] = C.operator_mode || C.netadmin_mode
+
+	else // Channel selection screen
+		var/list/all_channels[0]
+		for(var/datum/ntnet_conversation/conv in ntnet_global.chat_channels)
+			if(conv && conv.title)
+				all_channels.Add(list(list(
+					"chan" = conv.title
+				)))
+		data["all_channels"] = all_channels
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_chat.tmpl", "NTNet Relay Chat Client", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/nttransfer.dm

@@ -0,0 +1,197 @@
+var/global/nttransfer_uid = 0
+
+/datum/computer_file/program/nttransfer
+	filename = "nttransfer"
+	filedesc = "NTNet P2P Transfer Client"
+	extended_desc = "This program allows for simple file transfer via direct peer to peer connection."
+	program_icon_state = "comm_logs"
+	size = 7
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_PEERTOPEER
+	network_destination = "other device via P2P tunnel"
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_nttransfer/
+
+	var/error = ""										// Error screen
+	var/server_password = ""							// Optional password to download the file.
+	var/datum/computer_file/provided_file = null		// File which is provided to clients.
+	var/datum/computer_file/downloaded_file = null		// File which is being downloaded
+	var/list/connected_clients = list()					// List of connected clients.
+	var/datum/computer_file/program/nttransfer/remote	// Client var, specifies who are we downloading from.
+	var/download_completion = 0							// Download progress in GQ
+	var/download_netspeed = 0							// Our connectivity speed in GQ/s
+	var/actual_netspeed = 0								// Displayed in the UI, this is the actual transfer speed.
+	var/unique_token 									// UID of this program
+	var/upload_menu = 0									// Whether we show the program list and upload menu
+
+/datum/computer_file/program/nttransfer/New()
+	unique_token = nttransfer_uid
+	nttransfer_uid++
+	..()
+
+/datum/computer_file/program/nttransfer/process_tick()
+	// Server mode
+	update_netspeed()
+	if(provided_file)
+		for(var/datum/computer_file/program/nttransfer/C in connected_clients)
+			// Transfer speed is limited by device which uses slower connectivity.
+			// We can have multiple clients downloading at same time, but let's assume we use some sort of multicast transfer
+			// so they can all run on same speed.
+			C.actual_netspeed = min(C.download_netspeed, download_netspeed)
+			C.download_completion += C.actual_netspeed
+			if(C.download_completion >= provided_file.size)
+				C.finish_download()
+	else if(downloaded_file) // Client mode
+		if(!remote)
+			crash_download("Connection to remote server lost")
+
+/datum/computer_file/program/nttransfer/kill_program(var/forced = 0)
+	if(downloaded_file) // Client mode, clean up variables for next use
+		finalize_download()
+
+	if(provided_file) // Server mode, disconnect all clients
+		for(var/datum/computer_file/program/nttransfer/P in connected_clients)
+			P.crash_download("Connection terminated by remote server")
+		downloaded_file = null
+	..(forced)
+
+
+
+/datum/computer_file/program/nttransfer/proc/update_netspeed()
+	download_netspeed = 0
+	switch(ntnet_status)
+		if(1)
+			download_netspeed = NTNETSPEED_LOWSIGNAL
+		if(2)
+			download_netspeed = NTNETSPEED_HIGHSIGNAL
+		if(3)
+			download_netspeed = NTNETSPEED_ETHERNET
+
+// Finishes download and attempts to store the file on HDD
+/datum/computer_file/program/nttransfer/proc/finish_download()
+	if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(downloaded_file))
+		error = "I/O Error:  Unable to save file. Check your hard drive and try again."
+	finalize_download()
+
+//  Crashes the download and displays specific error message
+/datum/computer_file/program/nttransfer/proc/crash_download(var/message)
+	error = message ? message : "An unknown error has occured during download"
+	finalize_download()
+
+// Cleans up variables for next use
+/datum/computer_file/program/nttransfer/proc/finalize_download()
+	if(remote)
+		remote.connected_clients.Remove(src)
+	downloaded_file = null
+	remote = null
+	download_completion = 0
+
+
+
+
+
+/datum/nano_module/computer_nttransfer
+	name = "NTNet P2P Transfer Client"
+
+/datum/nano_module/computer_nttransfer/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!program)
+		return
+	var/datum/computer_file/program/nttransfer/PRG = program
+	if(!istype(PRG))
+		return
+
+	var/list/data = program.get_header_data()
+
+	if(PRG.error)
+		data["error"] = PRG.error
+	else if(PRG.downloaded_file)
+		data["downloading"] = 1
+		data["download_size"] = PRG.downloaded_file.size
+		data["download_progress"] = PRG.download_completion
+		data["download_netspeed"] = PRG.actual_netspeed
+		data["download_name"] = "[PRG.downloaded_file.filename].[PRG.downloaded_file.filetype]"
+	else if (PRG.provided_file)
+		data["uploading"] = 1
+		data["upload_uid"] = PRG.unique_token
+		data["upload_clients"] = PRG.connected_clients.len
+		data["upload_haspassword"] = PRG.server_password ? 1 : 0
+		data["upload_filename"] = "[PRG.provided_file.filename].[PRG.provided_file.filetype]"
+	else if (PRG.upload_menu)
+		var/list/all_files[0]
+		for(var/datum/computer_file/F in PRG.computer.hard_drive.stored_files)
+			all_files.Add(list(list(
+			"uid" = F.uid,
+			"filename" = "[F.filename].[F.filetype]",
+			"size" = F.size
+			)))
+		data["upload_filelist"] = all_files
+	else
+		var/list/all_servers[0]
+		for(var/datum/computer_file/program/nttransfer/P in ntnet_global.fileservers)
+			all_servers.Add(list(list(
+			"uid" = P.unique_token,
+			"filename" = "[P.provided_file.filename].[P.provided_file.filetype]",
+			"size" = P.provided_file.size,
+			"haspassword" = P.server_password ? 1 : 0
+			)))
+		data["servers"] = all_servers
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_transfer.tmpl", "NTNet P2P Transfer Client", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/computer_file/program/nttransfer/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_downloadfile"])
+		for(var/datum/computer_file/program/nttransfer/P in ntnet_global.fileservers)
+			if("[P.unique_token]" == href_list["PRG_downloadfile"])
+				remote = P
+				break
+		if(!remote || !remote.provided_file)
+			return
+		if(remote.server_password)
+			var/pass = sanitize(input(usr, "Code 401 Unauthorized. Please enter password:", "Password required"))
+			if(pass != remote.server_password)
+				error = "Incorrect Password"
+				return
+		downloaded_file = remote.provided_file.clone()
+		remote.connected_clients.Add(src)
+		return
+	if(href_list["PRG_reset"])
+		error = ""
+		upload_menu = 0
+		finalize_download()
+		if(src in ntnet_global.fileservers)
+			ntnet_global.fileservers.Remove(src)
+		for(var/datum/computer_file/program/nttransfer/T in connected_clients)
+			T.crash_download("Remote server has forcibly closed the connection")
+		provided_file = null
+		return
+	if(href_list["PRG_setpassword"])
+		var/pass = sanitize(input(usr, "Enter new server password. Leave blank to cancel, input 'none' to disable password.", "Server security", "none"))
+		if(!pass)
+			return
+		if(pass == "none")
+			server_password = ""
+			return
+		server_password = pass
+		return
+	if(href_list["PRG_uploadfile"])
+		for(var/datum/computer_file/F in computer.hard_drive.stored_files)
+			if("[F.uid]" == href_list["PRG_uploadfile"])
+				if(F.unsendable)
+					error = "I/O Error: File locked."
+					return
+				provided_file = F
+				ntnet_global.fileservers.Add(src)
+				return
+		error = "I/O Error: Unable to locate file on hard drive."
+		return
+	if(href_list["PRG_uploadmenu"])
+		upload_menu = 1
+	return 0

code/modules/modular_computers/hardware/battery_module.dm

@@ -0,0 +1,59 @@
+// This device is wrapper for actual power cell. I have decided to not use power cells directly as even low-end cells available on station
+// have tremendeous capacity in comparsion. Higher tier cells would provide your device with nearly infinite battery life, which is something i want to avoid.
+/obj/item/weapon/computer_hardware/battery_module
+	name = "standard battery"
+	desc = "A standard power cell, commonly seen in high-end portable microcomputers or low-end laptops. It's rating is 750."
+	icon_state = "battery_normal"
+	critical = 1
+
+	var/battery_rating = 750
+	var/obj/item/weapon/cell/battery = null
+
+/obj/item/weapon/computer_hardware/battery_module/advanced
+	name = "advanced battery"
+	desc = "An advanced power cell, often used in most laptops. It is too large to be fitted into smaller devices. It's rating is 1100."
+	icon_state = "battery_advanced"
+	hardware_size = 2
+	battery_rating = 1100
+
+/obj/item/weapon/computer_hardware/battery_module/super
+	name = "super battery"
+	desc = "A very advanced power cell, often used in high-end devices, or as uninterruptable power supply for important consoles or servers. It's rating is 1500."
+	icon_state = "battery_super"
+	hardware_size = 2
+	battery_rating = 1500
+
+/obj/item/weapon/computer_hardware/battery_module/ultra
+	name = "ultra battery"
+	desc = "A very advanced large power cell. It's often used as uninterruptable power supply for critical consoles or servers. It's rating is 2000."
+	icon_state = "battery_ultra"
+	hardware_size = 3
+	battery_rating = 2000
+
+/obj/item/weapon/computer_hardware/battery_module/micro
+	name = "micro battery"
+	desc = "A small power cell, commonly seen in most portable microcomputers. It's rating is 500."
+	icon_state = "battery_micro"
+	battery_rating = 500
+
+/obj/item/weapon/computer_hardware/battery_module/nano
+	name = "nano battery"
+	desc = "A tiny power cell, commonly seen in low-end portable microcomputers. It's rating is 300."
+	icon_state = "battery_nano"
+	battery_rating = 300
+
+// This is not intended to be obtainable in-game. Intended for adminbus and debugging purposes.
+/obj/item/weapon/computer_hardware/battery_module/lambda
+	name = "lambda coil"
+	desc = "A very complex device that creates it's own bluespace dimension. This dimension may be used to store massive amounts of energy."
+	icon_state = "battery_lambda"
+	hardware_size = 1
+	battery_rating = 1000000
+
+
+
+/obj/item/weapon/computer_hardware/battery_module/New()
+	battery = new/obj/item/weapon/cell(src)
+	battery.maxcharge = battery_rating
+	battery.charge = battery_rating
+	..() 

code/modules/modular_computers/hardware/card_slot.dm

@@ -0,0 +1,16 @@
+/obj/item/weapon/computer_hardware/card_slot
+	name = "RFID card slot"
+	desc = "Slot that allows this computer to write data on RFID cards. Necessary for some programs to run properly."
+	power_usage = 10 //W
+	critical = 0
+	icon_state = "cardreader"
+	hardware_size = 1
+
+	var/obj/item/weapon/card/id/stored_card = null
+
+/obj/item/weapon/computer_hardware/card_slot/Destroy()
+	if(holder2 && (holder2.card_slot == src))
+		holder2.card_slot = null
+	stored_card.loc = get_turf(holder2)
+	holder2 = null
+	..() 

code/modules/modular_computers/hardware/hard_drive.dm

@@ -0,0 +1,146 @@
+/obj/item/weapon/computer_hardware/hard_drive/
+	name = "basic hard drive"
+	desc = "A small power efficient solid state drive, with 128GQ of storage capacity for use in basic computers where power efficiency is desired."
+	power_usage = 25					// SSD or something with low power usage
+	icon_state = "hdd_normal"
+	hardware_size = 1
+	var/max_capacity = 128
+	var/used_capacity = 0
+	var/list/stored_files = list()		// List of stored files on this drive. DO NOT MODIFY DIRECTLY!
+
+/obj/item/weapon/computer_hardware/hard_drive/advanced
+	name = "advanced hard drive"
+	desc = "A small hybrid hard drive with 256GQ of storage capacity for use in higher grade computers where balance between power efficiency and capacity is desired."
+	max_capacity = 256
+	power_usage = 50 					// Hybrid, medium capacity and medium power storage
+	icon_state = "hdd_advanced"
+	hardware_size = 2
+
+/obj/item/weapon/computer_hardware/hard_drive/super
+	name = "super hard drive"
+	desc = "A small hard drive with 512GQ of storage capacity for use in cluster storage solutions where capacity is more important than power efficiency."
+	max_capacity = 512
+	power_usage = 100					// High-capacity but uses lots of power, shortening battery life. Best used with APC link.
+	icon_state = "hdd_super"
+	hardware_size = 2
+
+/obj/item/weapon/computer_hardware/hard_drive/cluster
+	name = "cluster hard drive"
+	desc = "A large storage cluster consisting of multiple hard drives for usage in high capacity storage systems. Has capacity of 2048 GQ."
+	power_usage = 500
+	max_capacity = 2048
+	icon_state = "hdd_cluster"
+	hardware_size = 3
+
+// For tablets, etc. - highly power efficient.
+/obj/item/weapon/computer_hardware/hard_drive/small
+	name = "small hard drive"
+	desc = "A small highly efficient solid state drive for portable devices."
+	power_usage = 10
+	max_capacity = 64
+	icon_state = "hdd_small"
+	hardware_size = 1
+
+/obj/item/weapon/computer_hardware/hard_drive/micro
+	name = "micro hard drive"
+	desc = "A small micro hard drive for portable devices."
+	power_usage = 2
+	max_capacity = 32
+	icon_state = "hdd_micro"
+	hardware_size = 1
+
+// Use this proc to add file to the drive. Returns 1 on success and 0 on failure. Contains necessary sanity checks.
+/obj/item/weapon/computer_hardware/hard_drive/proc/store_file(var/datum/computer_file/F)
+	if(!F || !istype(F))
+		return 0
+
+	if(!can_store_file(F.size))
+		return 0
+
+	if(!stored_files)
+		return 0
+
+	// This file is already stored. Don't store it again.
+	if(F in stored_files)
+		return 0
+
+	F.holder = src
+	stored_files.Add(F)
+	recalculate_size()
+	return 1
+
+// Use this proc to add file to the drive. Returns 1 on success and 0 on failure. Contains necessary sanity checks.
+/obj/item/weapon/computer_hardware/hard_drive/proc/install_default_programs()
+	store_file(new/datum/computer_file/program/computerconfig(src)) 		// Computer configuration utility, allows hardware control and displays more info than status bar
+	store_file(new/datum/computer_file/program/ntnetdownload(src))			// NTNet Downloader Utility, allows users to download more software from NTNet repository
+	store_file(new/datum/computer_file/program/filemanager(src))			// File manager, allows text editor functions and basic file manipulation.
+
+
+// Use this proc to remove file from the drive. Returns 1 on success and 0 on failure. Contains necessary sanity checks.
+/obj/item/weapon/computer_hardware/hard_drive/proc/remove_file(var/datum/computer_file/F)
+	if(!F || !istype(F))
+		return 0
+
+	if(!stored_files)
+		return 0
+
+	if(F in stored_files)
+		stored_files -= F
+		recalculate_size()
+		return 1
+	else
+		return 0
+
+// Loops through all stored files and recalculates used_capacity of this drive
+/obj/item/weapon/computer_hardware/hard_drive/proc/recalculate_size()
+	var/total_size = 0
+	for(var/datum/computer_file/F in stored_files)
+		total_size += F.size
+
+	used_capacity = total_size
+
+// Checks whether file can be stored on the hard drive.
+/obj/item/weapon/computer_hardware/hard_drive/proc/can_store_file(var/size = 1)
+	// In the unlikely event someone manages to create that many files.
+	// BYOND is acting weird with numbers above 999 in loops (infinite loop prevention)
+	if(stored_files.len >= 999)
+		return 0
+	if(used_capacity + size > max_capacity)
+		return 0
+	else
+		return 1
+
+// Checks whether we can store the file. We can only store unique files, so this checks whether we wouldn't get a duplicity by adding a file.
+/obj/item/weapon/computer_hardware/hard_drive/proc/try_store_file(var/datum/computer_file/F)
+	if(!F || !istype(F))
+		return 0
+	var/name = F.filename + "." + F.filetype
+	for(var/datum/computer_file/file in stored_files)
+		if((file.filename + "." + file.filetype) == name)
+			return 0
+	return can_store_file(F.size)
+
+
+
+// Tries to find the file by filename. Returns null on failure
+/obj/item/weapon/computer_hardware/hard_drive/proc/find_file_by_name(var/filename)
+	if(!filename)
+		return null
+
+	if(!stored_files)
+		return null
+
+	for(var/datum/computer_file/F in stored_files)
+		if(F.filename == filename)
+			return F
+	return null
+
+/obj/item/weapon/computer_hardware/hard_drive/Destroy()
+	if(holder2 && (holder2.hard_drive == src))
+		holder2.hard_drive = null
+	stored_files = null
+	..()
+
+/obj/item/weapon/computer_hardware/hard_drive/New()
+	install_default_programs()
+	..() 

code/modules/modular_computers/hardware/hardware.dm

@@ -0,0 +1,23 @@
+/obj/item/weapon/computer_hardware/
+	name = "Hardware"
+	desc = "Unknown Hardware"
+	icon = 'icons/obj/modular_components.dmi'
+	var/obj/item/modular_computer/holder2 = null
+	var/power_usage = 0 	// If the hardware uses extra power, change this.
+	var/enabled = 1			// If the hardware is turned off set this to 0.
+	var/critical = 1		// Prevent disabling for important component, like the HDD.
+	var/hardware_size = 1	// Limits which devices can contain this component. 1: Tablets/Laptops/Consoles, 2: Laptops/Consoles, 3: Consoles only
+
+/obj/item/weapon/computer_hardware/New(var/obj/L)
+	if(istype(L, /obj/machinery/modular_computer))
+		var/obj/machinery/modular_computer/C = L
+		if(C.cpu)
+			holder2 = C.cpu
+			return
+	if(istype(L, /obj/item/modular_computer))
+		holder2 = L
+		return
+
+/obj/item/weapon/computer_hardware/Destroy()
+	holder2 = null
+	..() 

code/modules/modular_computers/hardware/nano_printer.dm

@@ -0,0 +1,59 @@
+/obj/item/weapon/computer_hardware/nano_printer
+	name = "nano printer"
+	desc = "Small integrated printer with scanner and paper recycling module."
+	power_usage = 50
+	icon_state = "printer"
+	hardware_size = 1
+	var/stored_paper = 5
+	var/max_paper = 10
+	var/obj/item/weapon/paper/P = null	// Currently stored paper for scanning.
+
+
+/obj/item/weapon/computer_hardware/nano_printer/proc/print_text(var/text_to_print)
+	if(!stored_paper)
+		return 0
+
+	// Recycle stored paper
+	if(P)
+		stored_paper++
+		qdel(P)
+		P = null
+
+	P = new/obj/item/weapon/paper(get_turf(holder2))
+	P.info = text_to_print
+	P.update_icon()
+	stored_paper--
+	P = null
+	return 1
+
+/obj/item/weapon/computer_hardware/nano_printer/proc/load_paper(var/obj/item/weapon/paper/paper)
+	if(!paper || !istype(paper))
+		return 0
+
+	// We already have paper loaded, recycle it.
+	if(P && try_recycle_paper())
+		P = paper
+		P.forceMove(holder2)
+
+/obj/item/weapon/computer_hardware/nano_printer/proc/try_recycle_paper()
+	if(!P)
+		return 0
+
+	if(stored_paper >= max_paper)
+		return 0
+
+	qdel(P)
+	P = null
+	return 1
+
+/obj/item/weapon/computer_hardware/nano_printer/Destroy()
+	if(holder2 && (holder2.nano_printer == src))
+		holder2.nano_printer = null
+	if(P)
+		if(holder2)
+			P.forceMove(get_turf(holder2))
+		else
+			qdel(P)
+		P = null
+	holder2 = null
+	..() 

code/modules/modular_computers/hardware/network_card.dm

@@ -0,0 +1,73 @@
+var/global/ntnet_card_uid = 1
+
+/obj/item/weapon/computer_hardware/network_card/
+	name = "basic NTNet network card"
+	desc = "A basic network card for usage with standard NTNet frequencies."
+	power_usage = 50
+	critical = 0
+	icon_state = "netcard_basic"
+	hardware_size = 1
+	var/identification_id = null	// Identification ID. Technically MAC address of this device. Can't be changed by user.
+	var/identification_string = "" 	// Identification string, technically nickname seen in the network. Can be set by user.
+	var/long_range = 0
+	var/ethernet = 0 // Hard-wired, therefore always on, ignores NTNet wireless checks.
+
+/obj/item/weapon/computer_hardware/network_card/New(var/l)
+	..(l)
+	identification_id = ntnet_card_uid
+	ntnet_card_uid++
+
+/obj/item/weapon/computer_hardware/network_card/advanced
+	name = "advanced NTNet network card"
+	desc = "An advanced network card for usage with standard NTNet frequencies. It's transmitter is strong enough to connect even off-station."
+	long_range = 1
+	power_usage = 100 // Better range but higher power usage.
+	icon_state = "netcard_advanced"
+	hardware_size = 1
+
+/obj/item/weapon/computer_hardware/network_card/wired
+	name = "wired NTNet network card"
+	desc = "An advanced network card for usage with NTNet. This one uses wired connection."
+	ethernet = 1
+	power_usage = 100 // Better range but higher power usage.
+	icon_state = "netcard_ethernet"
+	hardware_size = 3
+
+/obj/item/weapon/computer_hardware/network_card/Destroy()
+	if(holder2 && (holder2.network_card == src))
+		holder2.network_card = null
+	holder2 = null
+	..()
+
+// Returns a string identifier of this network card
+/obj/item/weapon/computer_hardware/network_card/proc/get_network_tag()
+	return "[identification_string] (NID [identification_id])"
+
+// 0 - No signal, 1 - Low signal, 2 - High signal. 3 - Wired Connection
+/obj/item/weapon/computer_hardware/network_card/proc/get_signal(var/specific_action = 0)
+	if(!holder2) // Hardware is not installed in anything. No signal. How did this even get called?
+		return 0
+
+	if(!enabled)
+		return 0
+
+	if(ethernet) // Computer is connected via wired connection.
+		return 3
+
+	if(!ntnet_global || !ntnet_global.check_function(specific_action)) // NTNet is down and we are not connected via wired connection. No signal.
+		return 0
+
+	if(holder2)
+		var/turf/T = get_turf(holder2)
+		if((T && istype(T)) && T.z in using_map.station_levels)
+			return 2
+
+	if(long_range) // Computer is not on station, but it has upgraded network card. Low signal.
+		return 1
+
+	return 0 // Computer is not on station and does not have upgraded network card. No signal.
+
+/obj/item/weapon/computer_hardware/network_card/Destroy()
+	if(holder2 && (holder2.network_card == src))
+		holder2.network_card = null
+	..()

code/modules/modular_computers/hardware/portable_hard_drive.dm

@@ -0,0 +1,31 @@
+// These are basically USB data sticks and may be used to transfer files between devices
+/obj/item/weapon/computer_hardware/hard_drive/portable/
+	name = "basic data crystal"
+	desc = "Small crystal with imprinted photonic circuits that can be used to store data. It's capacity is 16 GQ"
+	power_usage = 10
+	icon_state = "flashdrive_basic"
+	hardware_size = 1
+	max_capacity = 16
+
+
+/obj/item/weapon/computer_hardware/hard_drive/portable/advanced
+	name = "advanced data crystal"
+	desc = "Small crystal with imprinted high-density photonic circuits that can be used to store data. It's capacity is 64 GQ"
+	power_usage = 20
+	icon_state = "flashdrive_advanced"
+	hardware_size = 1
+	max_capacity = 64
+
+
+/obj/item/weapon/computer_hardware/hard_drive/portable/super
+	name = "super data crystal"
+	desc = "Small crystal with imprinted ultra-density photonic circuits that can be used to store data. It's capacity is 256 GQ"
+	power_usage = 40
+	icon_state = "flashdrive_super"
+	hardware_size = 1
+	max_capacity = 256
+
+/obj/item/weapon/computer_hardware/hard_drive/portable/New()
+	..()
+	stored_files = list()
+	recalculate_size() 

code/modules/modular_computers/hardware/tesla_link.dm

@@ -0,0 +1,19 @@
+/obj/item/weapon/computer_hardware/tesla_link
+	name = "tesla link"
+	desc = "An advanced tesla link that wirelessly recharges connected device from nearby area power controller."
+	critical = 0
+	enabled = 0 // Starts turned off
+	icon_state = "teslalink"
+	hardware_size = 2		// Can't be installed into tablets
+	var/obj/machinery/modular_computer/holder
+
+/obj/item/weapon/computer_hardware/tesla_link/New(var/obj/L)
+	if(istype(L, /obj/machinery/modular_computer))
+		holder = L
+		return
+	..(L)
+
+/obj/item/weapon/computer_hardware/tesla_link/Destroy()
+	if(holder && (holder.tesla_link == src))
+		holder.tesla_link = null
+	..() 

code/modules/modular_computers/laptop_vendor.dm

@@ -0,0 +1,278 @@
+// A vendor machine for modular computer portable devices - Laptops and Tablets
+
+/obj/machinery/lapvend
+	name = "computer vendor"
+	desc = "A vending machine with microfabricator capable of dispensing various NT-branded computers"
+	icon = 'icons/obj/vending.dmi'
+	icon_state = "robotics"
+	layer = 2.9
+	anchored = 1
+	density = 1
+
+	// The actual laptop/tablet
+	var/obj/machinery/modular_computer/laptop/fabricated_laptop = null
+	var/obj/item/modular_computer/tablet/fabricated_tablet = null
+
+	// Utility vars
+	var/state = 0 							// 0: Select device type, 1: Select loadout, 2: Payment, 3: Thankyou screen
+	var/devtype = 0 						// 0: None(unselected), 1: Laptop, 2: Tablet
+	var/total_price = 0						// Price of currently vended device.
+
+	// Device loadout
+	var/dev_battery = 1						// 1: Default, 2: Upgraded, 3: Advanced
+	var/dev_disk = 1						// 1: Default, 2: Upgraded, 3: Advanced
+	var/dev_netcard = 0						// 0: None, 1: Basic, 2: Long-Range
+	var/dev_tesla = 0						// 0: None, 1: Standard (LAPTOP ONLY)
+	var/dev_nanoprint = 0					// 0: None, 1: Standard
+	var/dev_card = 0						// 0: None, 1: Standard
+
+// Removes all traces of old order and allows you to begin configuration from scratch.
+/obj/machinery/lapvend/proc/reset_order()
+	state = 0
+	devtype = 0
+	if(fabricated_laptop)
+		qdel(fabricated_laptop)
+		fabricated_laptop = null
+	if(fabricated_tablet)
+		qdel(fabricated_tablet)
+		fabricated_tablet = null
+	dev_battery = 1
+	dev_disk = 1
+	dev_netcard = 0
+	dev_tesla = 0
+	dev_nanoprint = 0
+	dev_card = 0
+
+// Recalculates the price and optionally even fabricates the device.
+/obj/machinery/lapvend/proc/fabricate_and_recalc_price(var/fabricate = 0)
+	total_price = 0
+	if(devtype == 1) 		// Laptop, generally cheaper to make it accessible for most station roles
+		if(fabricate)
+			fabricated_laptop = new(src)
+		total_price = 99
+		switch(dev_battery)
+			if(1) // Basic(750C)
+				if(fabricate)
+					fabricated_laptop.cpu.battery_module = new/obj/item/weapon/computer_hardware/battery_module(fabricated_tablet)
+			if(2) // Upgraded(1100C)
+				if(fabricate)
+					fabricated_laptop.cpu.battery_module = new/obj/item/weapon/computer_hardware/battery_module/advanced(fabricated_tablet)
+				total_price += 199
+			if(3) // Advanced(1500C)
+				if(fabricate)
+					fabricated_laptop.cpu.battery_module = new/obj/item/weapon/computer_hardware/battery_module/super(fabricated_tablet)
+				total_price += 499
+		switch(dev_disk)
+			if(1) // Basic(128GQ)
+				if(fabricate)
+					fabricated_laptop.cpu.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive(fabricated_laptop.cpu)
+			if(2) // Upgraded(256GQ)
+				if(fabricate)
+					fabricated_laptop.cpu.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive/advanced(fabricated_laptop.cpu)
+				total_price += 99
+			if(3) // Advanced(512GQ)
+				if(fabricate)
+					fabricated_laptop.cpu.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive/super(fabricated_laptop.cpu)
+				total_price += 299
+		switch(dev_netcard)
+			if(1) // Basic(Short-Range)
+				if(fabricate)
+					fabricated_laptop.cpu.network_card = new/obj/item/weapon/computer_hardware/network_card(fabricated_laptop.cpu)
+				total_price += 99
+			if(2) // Advanced (Long Range)
+				if(fabricate)
+					fabricated_laptop.cpu.network_card = new/obj/item/weapon/computer_hardware/network_card/advanced(fabricated_laptop.cpu)
+				total_price += 299
+		if(dev_tesla)
+			total_price += 399
+			if(fabricate)
+				fabricated_laptop.tesla_link = new/obj/item/weapon/computer_hardware/tesla_link(fabricated_laptop)
+		if(dev_nanoprint)
+			total_price += 99
+			if(fabricate)
+				fabricated_laptop.cpu.nano_printer = new/obj/item/weapon/computer_hardware/nano_printer(fabricated_laptop.cpu)
+		if(dev_card)
+			total_price += 199
+			if(fabricate)
+				fabricated_laptop.cpu.card_slot = new/obj/item/weapon/computer_hardware/card_slot(fabricated_laptop.cpu)
+
+		return total_price
+	else if(devtype == 2) 	// Tablet, more expensive, not everyone could probably afford this.
+		if(fabricate)
+			fabricated_tablet = new(src)
+		total_price = 199
+		switch(dev_battery)
+			if(1) // Basic(300C)
+				if(fabricate)
+					fabricated_tablet.battery_module = new/obj/item/weapon/computer_hardware/battery_module/nano(fabricated_tablet)
+			if(2) // Upgraded(500C)
+				if(fabricate)
+					fabricated_tablet.battery_module = new/obj/item/weapon/computer_hardware/battery_module/micro(fabricated_tablet)
+				total_price += 199
+			if(3) // Advanced(750C)
+				if(fabricate)
+					fabricated_tablet.battery_module = new/obj/item/weapon/computer_hardware/battery_module(fabricated_tablet)
+				total_price += 499
+		switch(dev_disk)
+			if(1) // Basic(32GQ)
+				if(fabricate)
+					fabricated_tablet.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive/micro(fabricated_tablet)
+			if(2) // Upgraded(64GQ)
+				if(fabricate)
+					fabricated_tablet.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive/small(fabricated_tablet)
+				total_price += 99
+			if(3) // Advanced(128GQ)
+				if(fabricate)
+					fabricated_tablet.hard_drive = new/obj/item/weapon/computer_hardware/hard_drive(fabricated_tablet)
+				total_price += 299
+		switch(dev_netcard)
+			if(1) // Basic(Short-Range)
+				if(fabricate)
+					fabricated_tablet.network_card = new/obj/item/weapon/computer_hardware/network_card(fabricated_tablet)
+				total_price += 99
+			if(2) // Advanced (Long Range)
+				if(fabricate)
+					fabricated_tablet.network_card = new/obj/item/weapon/computer_hardware/network_card/advanced(fabricated_tablet)
+				total_price += 299
+		if(dev_nanoprint)
+			total_price += 99
+			if(fabricate)
+				fabricated_tablet.nano_printer = new/obj/item/weapon/computer_hardware/nano_printer(fabricated_tablet)
+		if(dev_card)
+			total_price += 199
+			if(fabricate)
+				fabricated_tablet.card_slot = new/obj/item/weapon/computer_hardware/card_slot(fabricated_tablet)
+		return total_price
+	return 0
+
+
+
+
+
+/obj/machinery/lapvend/Topic(href, href_list)
+	if(..())
+		return 1
+
+	if(href_list["pick_device"])
+		if(state) // We've already picked a device type
+			return 0
+		devtype = text2num(href_list["pick_device"])
+		state = 1
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["clean_order"])
+		reset_order()
+		return 1
+	if((state != 1) && devtype) // Following IFs should only be usable when in the Select Loadout mode
+		return 0
+	if(href_list["confirm_order"])
+		state = 2 // Wait for ID swipe for payment processing
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_battery"])
+		dev_battery = text2num(href_list["hw_battery"])
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_disk"])
+		dev_disk = text2num(href_list["hw_disk"])
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_netcard"])
+		dev_netcard = text2num(href_list["hw_netcard"])
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_tesla"])
+		dev_tesla = text2num(href_list["hw_tesla"])
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_nanoprint"])
+		dev_nanoprint = text2num(href_list["hw_nanoprint"])
+		fabricate_and_recalc_price(0)
+		return 1
+	if(href_list["hw_card"])
+		dev_card = text2num(href_list["hw_card"])
+		fabricate_and_recalc_price(0)
+		return 1
+	return 0
+
+/obj/machinery/lapvend/attack_hand(var/mob/user)
+	ui_interact(user)
+
+/obj/machinery/lapvend/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+	if(stat & (BROKEN | NOPOWER | MAINT))
+		if(ui)
+			ui.close()
+		return 0
+
+	var/list/data[0]
+	data["state"] = state
+	data["devtype"] = devtype
+	data["hw_battery"] = dev_battery
+	data["hw_disk"] = dev_disk
+	data["hw_netcard"] = dev_netcard
+	data["hw_tesla"] = dev_tesla
+	data["hw_nanoprint"] = dev_nanoprint
+	data["hw_card"] = dev_card
+	data["totalprice"] = "[total_price]$"
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "computer_fabricator.tmpl", "Personal Computer Vendor", 500, 400)
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+
+obj/machinery/lapvend/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	var/obj/item/weapon/card/id/I = W.GetID()
+	// Awaiting payment state
+	if(state == 2)
+		if(process_payment(I,W))
+			fabricate_and_recalc_price(1)
+			if((devtype == 1) && fabricated_laptop)
+				fabricated_laptop.forceMove(src.loc)
+				fabricated_laptop.close_laptop()
+				fabricated_laptop = null
+			else if((devtype == 2) && fabricated_tablet)
+				fabricated_tablet.forceMove(src.loc)
+				fabricated_tablet = null
+			ping("Enjoy your new product!")
+			state = 3
+			return 1
+		return 0
+	return ..()
+
+
+// Simplified payment processing, returns 1 on success.
+/obj/machinery/lapvend/proc/process_payment(var/obj/item/weapon/card/id/I, var/obj/item/ID_container)
+	if(I==ID_container || ID_container == null)
+		visible_message("<span class='info'>\The [usr] swipes \the [I] through \the [src].</span>")
+	else
+		visible_message("<span class='info'>\The [usr] swipes \the [ID_container] through \the [src].</span>")
+	var/datum/money_account/customer_account = get_account(I.associated_account_number)
+	if (!customer_account || customer_account.suspended)
+		ping("Connection error. Unable to connect to account.")
+		return 0
+
+	if(customer_account.security_level != 0) //If card requires pin authentication (ie seclevel 1 or 2)
+		var/attempt_pin = input("Enter pin code", "Vendor transaction") as num
+		customer_account = attempt_account_access(I.associated_account_number, attempt_pin, 2)
+
+		if(!customer_account)
+			ping("Unable to access account: incorrect credentials.")
+			return 0
+
+	if(total_price > customer_account.money)
+		ping("Insufficient funds in account.")
+		return 0
+	else
+		customer_account.money -= total_price
+		var/datum/transaction/T = new()
+		T.target_name = "Computer Manufacturer (via [src.name])"
+		T.purpose = "Purchase of [(devtype == 1) ? "laptop computer" : "tablet microcomputer"]."
+		T.amount = total_price
+		T.source_terminal = src.name
+		T.date = current_date_string
+		T.time = stationtime2text()
+		customer_account.transaction_log.Add(T)
+		return 1