Ports Modular Computers from Baystation

This is just the initial parts. Additional work will probably be necessary.

code/modules/modular_computers/file_system/computer_file.dm

@@ -0,0 +1,39 @@
+var/global/file_uid = 0
+
+/datum/computer_file/
+	var/filename = "NewFile" 								// Placeholder. No spacebars
+	var/filetype = "XXX" 									// File full names are [filename].[filetype] so like NewFile.XXX in this case
+	var/size = 1											// File size in GQ. Integers only!
+	var/obj/item/weapon/computer_hardware/hard_drive/holder	// Holder that contains this file.
+	var/unsendable = 0										// Whether the file may be sent to someone via NTNet transfer or other means.
+	var/undeletable = 0										// Whether the file may be deleted. Setting to 1 prevents deletion/renaming/etc.
+	var/uid													// UID of this file
+
+/datum/computer_file/New()
+	..()
+	uid = file_uid
+	file_uid++
+
+/datum/computer_file/Destroy()
+	if(!holder)
+		return ..()
+
+	holder.remove_file(src)
+	// holder.holder is the computer that has drive installed. If we are Destroy()ing program that's currently running kill it.
+	if(holder.holder2 && holder.holder2.active_program == src)
+		holder.holder2.kill_program(1)
+	holder = null
+	..()
+
+// Returns independent copy of this file.
+/datum/computer_file/proc/clone(var/rename = 0)
+	var/datum/computer_file/temp = new type
+	temp.unsendable = unsendable
+	temp.undeletable = undeletable
+	temp.size = size
+	if(rename)
+		temp.filename = filename + "(Copy)"
+	else
+		temp.filename = filename
+	temp.filetype = filetype
+	return temp 

code/modules/modular_computers/file_system/data.dm

@@ -0,0 +1,17 @@
+// /data/ files store data in string format.
+// They don't contain other logic for now.
+/datum/computer_file/data
+	var/stored_data = "" 			// Stored data in string format.
+	filetype = "DAT"
+
+/datum/computer_file/data/clone()
+	var/datum/computer_file/data/temp = ..()
+	temp.stored_data = stored_data
+	return temp
+
+// Calculates file size from amount of characters in saved string
+/datum/computer_file/data/proc/calculate_size(var/block_size = 250)
+	size = max(1, round(length(stored_data) / block_size))
+
+/datum/computer_file/data/logfile
+	filetype = "LOG"

code/modules/modular_computers/file_system/program.dm

@@ -0,0 +1,127 @@
+// /program/ files are executable programs that do things.
+/datum/computer_file/program
+	filetype = "PRG"
+	filename = "UnknownProgram"				// File name. FILE NAME MUST BE UNIQUE IF YOU WANT THE PROGRAM TO BE DOWNLOADABLE FROM NTNET!
+	var/required_access = null				// List of required accesses to *run* the program.
+	var/datum/nano_module/NM = null			// If the program uses NanoModule, put it here and it will be automagically opened. Otherwise implement ui_interact.
+	var/nanomodule_path = null				// Path to nanomodule, make sure to set this if implementing new program.
+	var/running = 0							// Set to 1 when the program is run and back to 0 when it's stopped.
+	var/obj/item/modular_computer/computer	// Device that runs this program.
+	var/filedesc = "Unknown Program"		// User-friendly name of this program.
+	var/extended_desc = "N/A"				// Short description of this program's function.
+	var/program_icon_state = null			// Program-specific screen icon state
+	var/requires_ntnet = 0					// Set to 1 for program to require nonstop NTNet connection to run. If NTNet connection is lost program crashes.
+	var/requires_ntnet_feature = 0			// Optional, if above is set to 1 checks for specific function of NTNet (currently NTNET_SOFTWAREDOWNLOAD, NTNET_PEERTOPEER, NTNET_SYSTEMCONTROL and NTNET_COMMUNICATION)
+	var/ntnet_status = 1					// NTNet status, updated every tick by computer running this program. Don't use this for checks if NTNet works, computers do that. Use this for calculations, etc.
+	var/usage_flags = PROGRAM_ALL			// Bitflags (PROGRAM_CONSOLE, PROGRAM_LAPTOP, PROGRAM_TABLET combination) or PROGRAM_ALL
+	var/network_destination = null			// Optional string that describes what NTNet server/system this program connects to. Used in default logging.
+	var/available_on_ntnet = 1				// Whether the program can be downloaded from NTNet. Set to 0 to disable.
+	var/available_on_syndinet = 0			// Whether the program can be downloaded from SyndiNet (accessible via emagging the computer). Set to 1 to enable.
+	var/computer_emagged = 0				// Set to 1 if computer that's running us was emagged. Computer updates this every Process() tick
+
+/datum/computer_file/program/New(var/obj/item/modular_computer/comp = null)
+	..()
+	if(comp && istype(comp))
+		computer = comp
+
+/datum/computer_file/program/clone()
+	var/datum/computer_file/program/temp = ..()
+	temp.required_access = required_access
+	temp.nanomodule_path = nanomodule_path
+	temp.filedesc = filedesc
+	temp.program_icon_state = program_icon_state
+	temp.requires_ntnet = requires_ntnet
+	temp.requires_ntnet_feature = requires_ntnet_feature
+	temp.usage_flags = usage_flags
+	return temp
+
+// Attempts to create a log in global ntnet datum. Returns 1 on success, 0 on fail.
+/datum/computer_file/program/proc/generate_network_log(var/text)
+	if(computer)
+		return computer.add_log(text)
+	return 0
+
+/datum/computer_file/program/proc/is_supported_by_hardware(var/hardware_flag = 0, var/loud = 0, var/mob/user = null)
+	if(!(hardware_flag & usage_flags))
+		if(loud && computer && user)
+			user << "<span class='danger'>\The [computer] flashes an \"Hardware Error - Incompatible software\" warning.</span>"
+		return 0
+	return 1
+
+// Called by Process() on device that runs us, once every tick.
+/datum/computer_file/program/proc/process_tick()
+	return 1
+
+// Check if the user can run program. Only humans can operate computer. Automatically called in run_program()
+// User has to wear their ID or have it inhand for ID Scan to work.
+// Can also be called manually, with optional parameter being access_to_check to scan the user's ID
+/datum/computer_file/program/proc/can_run(var/mob/living/user, var/loud = 0, var/access_to_check)
+	// Defaults to required_access
+	if(!access_to_check)
+		access_to_check = required_access
+	if(!access_to_check) // No required_access, allow it.
+		return 1
+
+	var/obj/item/weapon/card/id/I = user.GetIdCard()
+	if(!I)
+		if(loud)
+			user << "<span class='danger'>\The [computer] flashes an \"RFID Error - Unable to scan ID\" warning.</span>"
+		return 0
+
+	if(access_to_check in I.access)
+		return 1
+	else if(loud)
+		user << "<span class='danger'>\The [computer] flashes an \"Access Denied\" warning.</span>"
+
+// This attempts to retrieve header data for NanoUIs. If implementing completely new device of different type than existing ones
+// always include the device here in this proc. This proc basically relays the request to whatever is running the program.
+/datum/computer_file/program/proc/get_header_data()
+	if(computer)
+		return computer.get_header_data()
+	return list()
+
+// This is performed on program startup. May be overriden to add extra logic. Remember to include ..() call. Return 1 on success, 0 on failure.
+// When implementing new program based device, use this to run the program.
+/datum/computer_file/program/proc/run_program(var/mob/living/user)
+	if(can_run(user, 1))
+		if(nanomodule_path)
+			NM = new nanomodule_path(computer)	// Computer is passed here as it's (probably!) physical object. Some UI's perform get_turf() and passing program datum wouldn't go well with this.
+			NM.program = src					// Set the program reference to separate variable, instead.
+		if(requires_ntnet && network_destination)
+			generate_network_log("Connection opened to [network_destination].")
+		running = 1
+		return 1
+	return 0
+
+// Use this proc to kill the program. Designed to be implemented by each program if it requires on-quit logic, such as the NTNRC client.
+/datum/computer_file/program/proc/kill_program(var/forced = 0)
+	running = 0
+	if(network_destination)
+		generate_network_log("Connection to [network_destination] closed.")
+	if(NM)
+		qdel(NM)
+		NM = null
+	return 1
+
+// This is called every tick when the program is enabled. Ensure you do parent call if you override it. If parent returns 1 continue with UI initialisation.
+// It returns 0 if it can't run or if NanoModule was used instead. I suggest using NanoModules where applicable.
+/datum/computer_file/program/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+	if(!running) // Our program was closed. Close the ui if it exists.
+		if(ui)
+			ui.close()
+		return computer.ui_interact(user)
+	if(istype(NM))
+		NM.ui_interact(user, ui_key, null, force_open)
+		return 0
+	return 1
+
+
+// CONVENTIONS, READ THIS WHEN CREATING NEW PROGRAM AND OVERRIDING THIS PROC:
+// Topic calls are automagically forwarded from NanoModule this program contains.
+// Calls beginning with "PRG_" are reserved for programs handling.
+// Calls beginning with "PC_" are reserved for computer handling (by whatever runs the program)
+// ALWAYS INCLUDE PARENT CALL ..() OR DIE IN FIRE.
+/datum/computer_file/program/Topic(href, href_list)
+	if(computer)
+		computer.Topic(href, href_list)
+	..()

code/modules/modular_computers/file_system/programs/_engineering.dm

@@ -0,0 +1,48 @@
+// These programs are associated with engineering.
+
+/datum/computer_file/program/power_monitor
+	filename = "powermonitor"
+	filedesc = "Power Monitoring"
+	nanomodule_path = /datum/nano_module/power_monitor/
+	program_icon_state = "power_monitor"
+	extended_desc = "This program connects to sensors around the station to provide information about electrical systems"
+	required_access = access_engine
+	requires_ntnet = 1
+	network_destination = "power monitoring system"
+	size = 9
+
+/datum/computer_file/program/alarm_monitor
+	filename = "alarmmonitor"
+	filedesc = "Alarm Monitoring"
+	nanomodule_path = /datum/nano_module/alarm_monitor/engineering
+	program_icon_state = "alarm_monitor"
+	extended_desc = "This program provides visual interface for station's alarm system."
+	requires_ntnet = 1
+	network_destination = "alarm monitoring network"
+	size = 5
+
+/datum/computer_file/program/atmos_control
+	filename = "atmoscontrol"
+	filedesc = "Atmosphere Control"
+	nanomodule_path = /datum/nano_module/atmos_control
+	program_icon_state = "atmos_control"
+	extended_desc = "This program allows remote control of air alarms around the station"
+	required_access = access_atmospherics
+	requires_ntnet = 1
+	network_destination = "atmospheric control system"
+	requires_ntnet_feature = NTNET_SYSTEMCONTROL
+	usage_flags = PROGRAM_LAPTOP | PROGRAM_CONSOLE
+	size = 17
+
+/datum/computer_file/program/rcon_console
+	filename = "rconconsole"
+	filedesc = "RCON Remote Control"
+	nanomodule_path = /datum/nano_module/rcon
+	program_icon_state = "generic"
+	extended_desc = "This program allows remote control of power distribution systems around the station."
+	required_access = access_engine
+	requires_ntnet = 1
+	network_destination = "RCON remote control system"
+	requires_ntnet_feature = NTNET_SYSTEMCONTROL
+	usage_flags = PROGRAM_LAPTOP | PROGRAM_CONSOLE
+	size = 19 

code/modules/modular_computers/file_system/programs/_medical.dm

@@ -0,0 +1,10 @@
+/datum/computer_file/program/suit_sensors
+	filename = "sensormonitor"
+	filedesc = "Suit Sensors Monitoring"
+	nanomodule_path = /datum/nano_module/crew_monitor
+	program_icon_state = "crew"
+	extended_desc = "This program connects to life signs monitoring system to provide basic information on crew health."
+	required_access = access_medical
+	requires_ntnet = 1
+	network_destination = "crew lifesigns monitoring system"
+	size = 11 

code/modules/modular_computers/file_system/programs/antagonist/dos.dm

@@ -0,0 +1,104 @@
+/datum/computer_file/program/ntnet_dos
+	filename = "ntn_dos"
+	filedesc = "DoS Traffic Generator"
+	program_icon_state = "hostile"
+	extended_desc = "This advanced script can perform denial of service attacks against NTNet quantum relays. The system administrator will probably notice this. Multiple devices can run this program together against same relay for increased effect"
+	size = 20
+	requires_ntnet = 1
+	available_on_ntnet = 0
+	available_on_syndinet = 1
+	nanomodule_path = /datum/nano_module/computer_dos/
+	var/obj/machinery/ntnet_relay/target = null
+	var/dos_speed = 0
+	var/error = ""
+	var/executed = 0
+
+/datum/computer_file/program/ntnet_dos/process_tick()
+	dos_speed = 0
+	switch(ntnet_status)
+		if(1)
+			dos_speed = NTNETSPEED_LOWSIGNAL * 10
+		if(2)
+			dos_speed = NTNETSPEED_HIGHSIGNAL * 10
+		if(3)
+			dos_speed = NTNETSPEED_ETHERNET * 10
+	if(target && executed)
+		target.dos_overload += dos_speed
+		if(target.is_operational())
+			target.dos_sources.Remove(src)
+			target = null
+			error = "Connection to destination relay lost."
+
+/datum/computer_file/program/ntnet_dos/kill_program(var/forced)
+	target.dos_sources.Remove(src)
+	target = null
+	executed = 0
+
+	..(forced)
+
+/datum/nano_module/computer_dos
+	name = "DoS Traffic Generator"
+
+/datum/nano_module/computer_dos/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global)
+		return
+	var/datum/computer_file/program/ntnet_dos/PRG = program
+	var/list/data = list()
+	if(!istype(PRG))
+		return
+	data = PRG.get_header_data()
+
+	if(PRG.error)
+		data["error"] = PRG.error
+	else if(PRG.target && PRG.executed)
+		data["target"] = 1
+		data["speed"] = PRG.dos_speed
+
+		// This is mostly visual, generate some strings of 1s and 0s
+		// Probability of 1 is equal of completion percentage of DoS attack on this relay.
+		// Combined with UI updates this adds quite nice effect to the UI
+		var/percentage = PRG.target.dos_overload * 100 / PRG.target.dos_capacity
+		var/list/strings[0]
+		for(var/j, j<10, j++)
+			var/string = ""
+			for(var/i, i<20, i++)
+				string = "[string][prob(percentage)]"
+			strings.Add(string)
+		data["dos_strings"] = strings
+	else
+		var/list/relays[0]
+		for(var/obj/machinery/ntnet_relay/R in ntnet_global.relays)
+			relays.Add(R.uid)
+		data["relays"] = relays
+		data["focus"] = PRG.target ? PRG.target.uid : null
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_dos.tmpl", "DoS Traffic Generator", 400, 250, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/computer_file/program/ntnet_dos/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_target_relay"])
+		for(var/obj/machinery/ntnet_relay/R in ntnet_global.relays)
+			if("[R.uid]" == href_list["PRG_target_relay"])
+				target = R
+		return
+	if(href_list["PRG_reset"])
+		target.dos_sources.Remove(src)
+		target = null
+		executed = 0
+		error = ""
+		return
+	if(href_list["PRG_execute"])
+		if(target)
+			executed = 1
+			target.dos_sources.Add(src)
+			if(ntnet_global.intrusion_detection_enabled)
+				ntnet_global.add_log("IDS WARNING - Excess traffic flood targeting relay [target.uid] detected from device: [computer.network_card.get_network_tag()]")
+				ntnet_global.intrusion_detection_alarm = 1
+		return

code/modules/modular_computers/file_system/programs/antagonist/revelation.dm

@@ -0,0 +1,77 @@
+/datum/computer_file/program/revelation
+	filename = "revelation"
+	filedesc = "Revelation"
+	program_icon_state = "hostile"
+	extended_desc = "This virus can destroy hard drive of system it is executed on. It may be obfuscated to look like another non-malicious program. Once armed, it will destroy the system upon next execution."
+	size = 13
+	requires_ntnet = 0
+	available_on_ntnet = 0
+	available_on_syndinet = 1
+	nanomodule_path = /datum/nano_module/revelation/
+	var/armed = 0
+
+/datum/computer_file/program/revelation/run_program(var/mob/living/user)
+	. = ..(user)
+	if(armed)
+		activate()
+
+/datum/computer_file/program/revelation/proc/activate()
+	if(computer)
+		computer.visible_message("<span class='notice'>\The [computer]'s screen brightly flashes and loud electrical buzzing is heard.</span>")
+		computer.enabled = 0
+		computer.update_icon()
+		qdel(computer.hard_drive)
+		if(computer.battery_module && prob(25))
+			qdel(computer.battery_module)
+			computer.visible_message("<span class='notice'>\The [computer]'s battery explodes in rain of sparks.</span>")
+			var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+			s.set_up(10, 1, computer.loc)
+			s.start()
+		if(istype(computer, /obj/item/modular_computer/processor))
+			var/obj/item/modular_computer/processor/P = computer
+			if(P.machinery_computer.tesla_link && prob(50))
+				qdel(P.machinery_computer.tesla_link)
+				computer.visible_message("<span class='notice'>\The [computer]'s tesla link explodes in rain of sparks.</span>")
+				var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+				s.set_up(10, 1, computer.loc)
+				s.start()
+
+/datum/computer_file/program/revelation/Topic(href, href_list)
+	if(..())
+		return 1
+	else if(href_list["PRG_arm"])
+		armed = !armed
+	else if(href_list["PRG_activate"])
+		activate()
+	else if(href_list["PRG_obfuscate"])
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user, "Enter new program name: "))
+		if(!newname)
+			return
+		filedesc = newname
+
+/datum/computer_file/program/revelation/clone()
+	var/datum/computer_file/program/revelation/temp = ..()
+	temp.armed = armed
+	return temp
+
+/datum/nano_module/revelation
+	name = "Revelation Virus"
+
+/datum/nano_module/revelation/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	var/list/data = list()
+	var/datum/computer_file/program/revelation/PRG = program
+	if(!istype(PRG))
+		return
+
+	data = PRG.get_header_data()
+
+	data["armed"] = PRG.armed
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "revelation.tmpl", "Revelation Virus", 400, 250, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/configurator.dm

@@ -0,0 +1,80 @@
+// This is special hardware configuration program.
+// It is to be used only with modular computers.
+// It allows you to toggle components of your device.
+
+/datum/computer_file/program/computerconfig
+	filename = "compconfig"
+	filedesc = "Computer Configuration Tool"
+	extended_desc = "This program allows configuration of computer's hardware"
+	program_icon_state = "generic"
+	unsendable = 1
+	undeletable = 1
+	size = 4
+	available_on_ntnet = 0
+	requires_ntnet = 0
+	nanomodule_path = /datum/nano_module/computer_configurator/
+
+/datum/nano_module/computer_configurator
+	name = "NTOS Computer Configuration Tool"
+	var/obj/machinery/modular_computer/stationary = null
+	var/obj/item/modular_computer/movable = null
+
+/datum/nano_module/computer_configurator/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(program)
+		stationary = program.computer
+		movable = program.computer
+
+	if(!istype(stationary))
+		stationary = null
+	if(!istype(movable))
+		movable = null
+
+	// No computer connection, we can't get data from that.
+	if(!movable && !stationary)
+		return 0
+
+	var/list/data = list()
+
+	if(program)
+		data = program.get_header_data()
+
+	var/list/hardware = list()
+	if(stationary)
+		if(stationary.cpu)
+			movable = stationary.cpu
+			hardware.Add(stationary.tesla_link)
+		else
+			return
+
+	if(movable)
+		hardware.Add(movable.network_card)
+		hardware.Add(movable.hard_drive)
+		hardware.Add(movable.card_slot)
+		hardware.Add(movable.nano_printer)
+		hardware.Add(movable.battery_module)
+		data["disk_size"] = movable.hard_drive.max_capacity
+		data["disk_used"] = movable.hard_drive.used_capacity
+		data["power_usage"] = movable.last_power_usage
+		data["battery_exists"] = movable.battery_module ? 1 : 0
+		if(movable.battery_module)
+			data["battery_rating"] = movable.battery_module.battery.maxcharge
+			data["battery_percent"] = round(movable.battery_module.battery.percent())
+
+	var/list/all_entries[0]
+	for(var/obj/item/weapon/computer_hardware/H in hardware)
+		all_entries.Add(list(list(
+		"name" = H.name,
+		"desc" = H.desc,
+		"enabled" = H.enabled,
+		"critical" = H.critical,
+		"powerusage" = H.power_usage
+		)))
+
+	data["hardware"] = all_entries
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "laptop_configuration.tmpl", "NTOS Configuration Utility", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/file_browser.dm

@@ -0,0 +1,227 @@
+/datum/computer_file/program/filemanager
+	filename = "filemanager"
+	filedesc = "NTOS File Manager"
+	extended_desc = "This program allows management of files."
+	program_icon_state = "generic"
+	size = 8
+	requires_ntnet = 0
+	available_on_ntnet = 0
+	undeletable = 1
+	nanomodule_path = /datum/nano_module/computer_filemanager/
+	var/open_file
+	var/error
+
+/datum/computer_file/program/filemanager/Topic(href, href_list)
+	if(href_list["PRG_openfile"])
+		open_file = href_list["PRG_openfile"]
+	if(href_list["PRG_newtextfile"])
+		var/newname = sanitize(input(usr, "Enter file name or leave blank to cancel:", "File rename"))
+		if(!newname)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = new/datum/computer_file/data()
+		F.filename = newname
+		F.filetype = "TXT"
+		HDD.store_file(F)
+	if(href_list["PRG_deletefile"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/file = HDD.find_file_by_name(href_list["PRG_deletefile"])
+		if(!file || file.undeletable)
+			return
+		HDD.remove_file(file)
+	if(href_list["PRG_usbdeletefile"])
+		var/obj/item/weapon/computer_hardware/hard_drive/RHDD = computer.portable_drive
+		if(!RHDD)
+			return
+		var/datum/computer_file/file = RHDD.find_file_by_name(href_list["PRG_usbdeletefile"])
+		if(!file || file.undeletable)
+			return
+		RHDD.remove_file(file)
+	if(href_list["PRG_closefile"])
+		open_file = null
+		error = null
+	if(href_list["PRG_clone"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/F = HDD.find_file_by_name(href_list["PRG_clone"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(1)
+		HDD.store_file(C)
+	if(href_list["PRG_rename"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/file = HDD.find_file_by_name(href_list["PRG_rename"])
+		if(!file || !istype(file))
+			return
+		var/newname = sanitize(input(usr, "Enter new file name:", "File rename", file.filename))
+		if(file && newname)
+			file.filename = newname
+	if(href_list["PRG_edit"])
+		if(!open_file)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = HDD.find_file_by_name(open_file)
+		if(!F || !istype(F))
+			return
+		// 16384 is the limit for file length in characters. Currently, papers have value of 2048 so this is 8 times as long, since we can't edit parts of the file independently.
+		var/newtext = sanitize(html_decode(input(usr, "Editing file [open_file]. You may use most tags used in paper formatting:", "Text Editor", F.stored_data) as message), 16384)
+		if(F)
+			var/datum/computer_file/data/backup = F.clone()
+			HDD.remove_file(F)
+			F.stored_data = newtext
+			F.calculate_size()
+			// We can't store the updated file, it's probably too large. Print an error and restore backed up version.
+			// This is mostly intended to prevent people from losing texts they spent lot of time working on due to running out of space.
+			// They will be able to copy-paste the text from error screen and store it in notepad or something.
+			if(!HDD.store_file(F))
+				error = "I/O error: Unable to overwrite file. Hard drive is probably full. You may want to backup your changes before closing this window:<br><br>[F.stored_data]<br><br>"
+				HDD.store_file(backup)
+	if(href_list["PRG_printfile"])
+		if(!open_file)
+			return
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		if(!HDD)
+			return
+		var/datum/computer_file/data/F = HDD.find_file_by_name(open_file)
+		if(!F || !istype(F))
+			return
+		if(!computer.nano_printer)
+			error = "Missing Hardware: Your computer does not have required hardware to complete this operation."
+			return
+		if(!computer.nano_printer.print_text(parse_tags(F.stored_data)))
+			error = "Hardware error: Printer was unable to print the file. It may be out of paper."
+			return
+	if(href_list["PRG_copytousb"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD = computer.portable_drive
+		if(!HDD || !RHDD)
+			return
+		var/datum/computer_file/F = HDD.find_file_by_name(href_list["PRG_copytousb"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(0)
+		RHDD.store_file(C)
+	if(href_list["PRG_copyfromusb"])
+		var/obj/item/weapon/computer_hardware/hard_drive/HDD = computer.hard_drive
+		var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD = computer.portable_drive
+		if(!HDD || !RHDD)
+			return
+		var/datum/computer_file/F = RHDD.find_file_by_name(href_list["PRG_copyfromusb"])
+		if(!F || !istype(F))
+			return
+		var/datum/computer_file/C = F.clone(0)
+		HDD.store_file(C)
+	..(href, href_list)
+
+/datum/computer_file/program/filemanager/proc/parse_tags(var/t)
+	t = replacetext(t, "\[center\]", "<center>")
+	t = replacetext(t, "\[/center\]", "</center>")
+	t = replacetext(t, "\[br\]", "<BR>")
+	t = replacetext(t, "\[b\]", "<B>")
+	t = replacetext(t, "\[/b\]", "</B>")
+	t = replacetext(t, "\[i\]", "<I>")
+	t = replacetext(t, "\[/i\]", "</I>")
+	t = replacetext(t, "\[u\]", "<U>")
+	t = replacetext(t, "\[/u\]", "</U>")
+	t = replacetext(t, "\[time\]", "[stationtime2text()]")
+	t = replacetext(t, "\[date\]", "[stationdate2text()]")
+	t = replacetext(t, "\[large\]", "<font size=\"4\">")
+	t = replacetext(t, "\[/large\]", "</font>")
+	t = replacetext(t, "\[h1\]", "<H1>")
+	t = replacetext(t, "\[/h1\]", "</H1>")
+	t = replacetext(t, "\[h2\]", "<H2>")
+	t = replacetext(t, "\[/h2\]", "</H2>")
+	t = replacetext(t, "\[h3\]", "<H3>")
+	t = replacetext(t, "\[/h3\]", "</H3>")
+	t = replacetext(t, "\[*\]", "<li>")
+	t = replacetext(t, "\[hr\]", "<HR>")
+	t = replacetext(t, "\[small\]", "<font size = \"1\">")
+	t = replacetext(t, "\[/small\]", "</font>")
+	t = replacetext(t, "\[list\]", "<ul>")
+	t = replacetext(t, "\[/list\]", "</ul>")
+	t = replacetext(t, "\[table\]", "<table border=1 cellspacing=0 cellpadding=3 style='border: 1px solid black;'>")
+	t = replacetext(t, "\[/table\]", "</td></tr></table>")
+	t = replacetext(t, "\[grid\]", "<table>")
+	t = replacetext(t, "\[/grid\]", "</td></tr></table>")
+	t = replacetext(t, "\[row\]", "</td><tr>")
+	t = replacetext(t, "\[tr\]", "</td><tr>")
+	t = replacetext(t, "\[td\]", "<td>")
+	t = replacetext(t, "\[cell\]", "<td>")
+	t = replacetext(t, "\[logo\]", "<img src = ntlogo.png>")
+	return t
+
+
+/datum/nano_module/computer_filemanager
+	name = "NTOS File Manager"
+
+/datum/nano_module/computer_filemanager/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+
+	var/datum/computer_file/program/filemanager/PRG
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+		PRG = program
+	else
+		return
+
+	var/obj/item/weapon/computer_hardware/hard_drive/HDD
+	var/obj/item/weapon/computer_hardware/hard_drive/portable/RHDD
+	if(PRG.error)
+		data["error"] = PRG.error
+	if(PRG.open_file)
+		var/datum/computer_file/data/file
+
+		if(!PRG.computer || !PRG.computer.hard_drive)
+			data["error"] = "I/O ERROR: Unable to access hard drive."
+		else
+			HDD = PRG.computer.hard_drive
+			file = HDD.find_file_by_name(PRG.open_file)
+			if(!istype(file))
+				data["error"] = "I/O ERROR: Unable to open file."
+			else
+				data["filedata"] = PRG.parse_tags(file.stored_data)
+				data["filename"] = "[file.filename].[file.filetype]"
+	else
+		if(!PRG.computer || !PRG.computer.hard_drive)
+			data["error"] = "I/O ERROR: Unable to access hard drive."
+		else
+			HDD = PRG.computer.hard_drive
+			RHDD = PRG.computer.portable_drive
+			var/list/files[0]
+			for(var/datum/computer_file/F in HDD.stored_files)
+				files.Add(list(list(
+					"name" = F.filename,
+					"type" = F.filetype,
+					"size" = F.size,
+					"undeletable" = F.undeletable
+				)))
+			data["files"] = files
+			if(RHDD)
+				data["usbconnected"] = 1
+				var/list/usbfiles[0]
+				for(var/datum/computer_file/F in RHDD.stored_files)
+					usbfiles.Add(list(list(
+						"name" = F.filename,
+						"type" = F.filetype,
+						"size" = F.size,
+						"undeletable" = F.undeletable
+					)))
+				data["usbfiles"] = usbfiles
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "file_manager.tmpl", "NTOS File Manager", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+

code/modules/modular_computers/file_system/programs/ntdownloader.dm

@@ -0,0 +1,160 @@
+/datum/computer_file/program/ntnetdownload
+	filename = "ntndownloader"
+	filedesc = "NTNet Software Download Tool"
+	program_icon_state = "generic"
+	extended_desc = "This program allows downloads of software from official NT repositories"
+	unsendable = 1
+	undeletable = 1
+	size = 4
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_SOFTWAREDOWNLOAD
+	available_on_ntnet = 0
+	nanomodule_path = /datum/nano_module/computer_ntnetdownload/
+	var/datum/computer_file/program/downloaded_file = null
+	var/hacked_download = 0
+	var/download_completion = 0 //GQ of downloaded data.
+	var/download_netspeed = 0
+	var/downloaderror = ""
+
+/datum/computer_file/program/ntnetdownload/proc/begin_file_download(var/filename)
+	if(downloaded_file)
+		return 0
+
+	var/datum/computer_file/program/PRG = ntnet_global.find_ntnet_file_by_name(filename)
+
+	if(!PRG || !istype(PRG))
+		return 0
+
+	// Attempting to download antag only program, but without having emagged computer. No.
+	if(PRG.available_on_syndinet && !computer_emagged)
+		return 0
+
+	if(!computer || !computer.hard_drive || !computer.hard_drive.try_store_file(PRG))
+		return 0
+
+	if(PRG in ntnet_global.available_station_software)
+		generate_network_log("Began downloading file [PRG.filename].[PRG.filetype] from NTNet Software Repository.")
+		hacked_download = 0
+	else if(PRG in ntnet_global.available_antag_software)
+		generate_network_log("Began downloading file **ENCRYPTED**.[PRG.filetype] from unspecified server.")
+		hacked_download = 1
+	else
+		generate_network_log("Began downloading file [PRG.filename].[PRG.filetype] from unspecified server.")
+		hacked_download = 0
+
+	downloaded_file = PRG.clone()
+
+/datum/computer_file/program/ntnetdownload/proc/abort_file_download()
+	if(!downloaded_file)
+		return
+	generate_network_log("Aborted download of file [hacked_download ? "**ENCRYPTED**" : downloaded_file.filename].[downloaded_file.filetype].")
+	downloaded_file = null
+	download_completion = 0
+
+/datum/computer_file/program/ntnetdownload/proc/complete_file_download()
+	if(!downloaded_file)
+		return
+	generate_network_log("Completed download of file [hacked_download ? "**ENCRYPTED**" : downloaded_file.filename].[downloaded_file.filetype].")
+	if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(downloaded_file))
+		// The download failed
+		downloaderror = "I/O ERROR - Unable to save file. Check whether you have enough free space on your hard drive and whether your hard drive is properly connected. If the issue persists contact your system administrator for assistance."
+	downloaded_file = null
+	download_completion = 0
+
+/datum/computer_file/program/ntnetdownload/process_tick()
+	if(!downloaded_file)
+		return
+	if(download_completion >= downloaded_file.size)
+		complete_file_download()
+	// Download speed according to connectivity state. NTNet server is assumed to be on unlimited speed so we're limited by our local connectivity
+	download_netspeed = 0
+	// Speed defines are found in misc.dm
+	switch(ntnet_status)
+		if(1)
+			download_netspeed = NTNETSPEED_LOWSIGNAL
+		if(2)
+			download_netspeed = NTNETSPEED_HIGHSIGNAL
+		if(3)
+			download_netspeed = NTNETSPEED_ETHERNET
+	download_completion += download_netspeed
+
+/datum/computer_file/program/ntnetdownload/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_downloadfile"])
+		if(!downloaded_file)
+			begin_file_download(href_list["PRG_downloadfile"])
+		return
+	if(href_list["PRG_reseterror"])
+		if(downloaderror)
+			download_completion = 0
+			download_netspeed = 0
+			downloaded_file = null
+			downloaderror = ""
+		return
+	return 0
+
+
+/datum/nano_module/computer_ntnetdownload
+	name = "Network Downloader"
+	var/obj/item/modular_computer/my_computer = null
+
+/datum/nano_module/computer_ntnetdownload/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(program)
+		my_computer = program.computer
+
+	if(!istype(my_computer))
+		return
+
+	var/list/data = list()
+	var/datum/computer_file/program/ntnetdownload/prog = program
+	// For now limited to execution by the downloader program
+	if(!prog || !istype(prog))
+		return
+	if(program)
+		data = program.get_header_data()
+
+	// This IF cuts on data transferred to client, so i guess it's worth it.
+	if(prog.downloaderror) // Download errored. Wait until user resets the program.
+		data["error"] = prog.downloaderror
+	else if(prog.downloaded_file) // Download running. Wait please..
+		data["downloadname"] = prog.downloaded_file.filename
+		data["downloaddesc"] = prog.downloaded_file.filedesc
+		data["downloadsize"] = prog.downloaded_file.size
+		data["downloadspeed"] = prog.download_netspeed
+		data["downloadcompletion"] = round(prog.download_completion, 0.1)
+	else // No download running, pick file.
+		data["disk_size"] = my_computer.hard_drive.max_capacity
+		data["disk_used"] = my_computer.hard_drive.used_capacity
+		var/list/all_entries[0]
+		for(var/datum/computer_file/program/P in ntnet_global.available_station_software)
+			// Only those programs our user can run will show in the list
+			if(!P.can_run(user))
+				continue
+			all_entries.Add(list(list(
+			"filename" = P.filename,
+			"filedesc" = P.filedesc,
+			"fileinfo" = P.extended_desc,
+			"size" = P.size
+			)))
+		data["hackedavailable"] = 0
+		if(prog.computer_emagged) // If we are running on emagged computer we have access to some "bonus" software
+			var/list/hacked_programs[0]
+			for(var/datum/computer_file/program/P in ntnet_global.available_antag_software)
+				data["hackedavailable"] = 1
+				hacked_programs.Add(list(list(
+				"filename" = P.filename,
+				"filedesc" = P.filedesc,
+				"fileinfo" = P.extended_desc,
+				"size" = P.size
+				)))
+			data["hacked_programs"] = hacked_programs
+
+		data["downloadable_programs"] = all_entries
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_downloader.tmpl", "NTNet Download Program", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/ntmonitor.dm

@@ -0,0 +1,85 @@
+/datum/computer_file/program/ntnetmonitor
+	filename = "ntmonitor"
+	filedesc = "NTNet Diagnostics and Monitoring"
+	program_icon_state = "comm_monitor"
+	extended_desc = "This program monitors stationwide NTNet network, provides access to logging systems, and allows for configuration changes"
+	size = 12
+	requires_ntnet = 1
+	required_access = access_network
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_ntnetmonitor/
+
+/datum/nano_module/computer_ntnetmonitor
+	name = "NTNet Diagnostics and Monitoring"
+
+/datum/nano_module/computer_ntnetmonitor/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global)
+		return
+
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+
+
+	data["ntnetstatus"] = ntnet_global.check_function()
+	data["ntnetrelays"] = ntnet_global.relays.len
+	data["idsstatus"] = ntnet_global.intrusion_detection_enabled
+	data["idsalarm"] = ntnet_global.intrusion_detection_alarm
+
+	data["config_softwaredownload"] = ntnet_global.setting_softwaredownload
+	data["config_peertopeer"] = ntnet_global.setting_peertopeer
+	data["config_communication"] = ntnet_global.setting_communication
+	data["config_systemcontrol"] = ntnet_global.setting_systemcontrol
+
+	data["ntnetlogs"] = ntnet_global.logs
+	data["ntnetmaxlogs"] = ntnet_global.setting_maxlogcount
+
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_monitor.tmpl", "NTNet Diagnostics and Monitoring Tool", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/nano_module/computer_ntnetmonitor/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["resetIDS"])
+		if(ntnet_global)
+			ntnet_global.resetIDS()
+		return 1
+	if(href_list["toggleIDS"])
+		if(ntnet_global)
+			ntnet_global.toggleIDS()
+		return 1
+	if(href_list["toggleWireless"])
+		if(!ntnet_global)
+			return 1
+
+		// NTNet is disabled. Enabling can be done without user prompt
+		if(ntnet_global.setting_disabled)
+			ntnet_global.setting_disabled = 0
+			return 1
+
+		// NTNet is enabled and user is about to shut it down. Let's ask them if they really want to do it, as wirelessly connected computers won't connect without NTNet being enabled (which may prevent people from turning it back on)
+		var/mob/user = usr
+		if(!user)
+			return
+		var/response = alert(user, "Really disable NTNet wireless? If your computer is connected wirelessly you won't be able to turn it back on! This will affect all connected wireless devices.", "NTNet shutdown", "Yes", "No")
+		if(response == "Yes")
+			ntnet_global.setting_disabled = 1
+		return 1
+	if(href_list["purgelogs"])
+		if(ntnet_global)
+			ntnet_global.purge_logs()
+	if(href_list["updatemaxlogs"])
+		var/mob/user = usr
+		var/logcount = text2num(input(user,"Enter amount of logs to keep in memory ([MIN_NTNET_LOGS]-[MAX_NTNET_LOGS]):"))
+		if(ntnet_global)
+			ntnet_global.update_max_log_count(logcount)
+	if(href_list["toggle_function"])
+		if(!ntnet_global)
+			return
+		ntnet_global.toggle_function(href_list["toggle_function"])

code/modules/modular_computers/file_system/programs/ntnrc_client.dm

@@ -0,0 +1,201 @@
+/datum/computer_file/program/chatclient
+	filename = "ntnrc_client"
+	filedesc = "NTNet Relay Chat Client"
+	program_icon_state = "command"
+	extended_desc = "This program allows communication over NTNRC network"
+	size = 8
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_COMMUNICATION
+	network_destination = "NTNRC server"
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_chatclient/
+	var/username
+	var/datum/ntnet_conversation/channel = null
+	var/operator_mode = 0		// Channel operator mode
+	var/netadmin_mode = 0		// Administrator mode (invisible to other users + bypasses passwords)
+
+/datum/computer_file/program/chatclient/New()
+	username = "DefaultUser[rand(100, 999)]"
+
+/datum/computer_file/program/chatclient/Topic(href, href_list)
+	if(href_list["PRG_speak"])
+		if(!channel)
+			return
+		var/mob/living/user = usr
+		var/message = sanitize(input(user, "Enter message or leave blank to cancel: "))
+		if(!message || !channel)
+			return
+		channel.add_message(message, username)
+
+	if(href_list["PRG_joinchannel"])
+		var/datum/ntnet_conversation/C
+		for(var/datum/ntnet_conversation/chan in ntnet_global.chat_channels)
+			if(chan.title == href_list["PRG_joinchannel"])
+				C = chan
+				break
+
+		if(!C)
+			return
+
+		if(netadmin_mode)
+			channel = C		// Bypasses normal leave/join and passwords. Technically makes the user invisible to others.
+			return
+
+		if(C.password)
+			var/mob/living/user = usr
+			var/password = sanitize(input(user,"Access Denied. Enter password:"))
+			if(C && (password == C.password))
+				C.add_client(src)
+				channel = C
+			return
+		C.add_client(src)
+		channel = C
+	if(href_list["PRG_leavechannel"])
+		if(channel)
+			channel.remove_client(src)
+		channel = null
+	if(href_list["PRG_newchannel"])
+		var/mob/living/user = usr
+		var/channel_title = sanitize(input(user,"Enter channel name or leave blank to cancel:"))
+		if(!channel_title)
+			return
+		var/datum/ntnet_conversation/C = new/datum/ntnet_conversation()
+		C.add_client(src)
+		C.operator = src
+		channel = C
+		C.title = channel_title
+	if(href_list["PRG_toggleadmin"])
+		if(netadmin_mode)
+			netadmin_mode = 0
+			if(channel)
+				channel.remove_client(src) // We shouldn't be in channel's user list, but just in case...
+				channel = null
+			return
+		var/mob/living/user = usr
+		if(can_run(usr, 1, access_network))
+			if(channel)
+				var/response = alert(user, "Really engage admin-mode? You will be disconnected from your current channel!", "NTNRC Admin mode", "Yes", "No")
+				if(response == "Yes")
+					if(channel)
+						channel.remove_client(src)
+						channel = null
+				else
+					return
+			netadmin_mode = 1
+	if(href_list["PRG_changename"])
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user,"Enter new nickname or leave blank to cancel:"))
+		if(!newname)
+			return
+		if(channel)
+			channel.add_status_message("[username] is now known as [newname].")
+		username = newname
+
+	if(href_list["PRG_savelog"])
+		if(!channel)
+			return
+		var/mob/living/user = usr
+		var/logname = input(user,"Enter desired logfile name (.log) or leave blank to cancel:")
+		if(!logname || !channel)
+			return
+		var/datum/computer_file/data/logfile = new/datum/computer_file/data/logfile()
+		// Now we will generate HTML-compliant file that can actually be viewed/printed.
+		logfile.filename = logname
+		logfile.stored_data = "\[b\]Logfile dump from NTNRC channel [channel.title]\[/b\]\[BR\]"
+		for(var/logstring in channel.messages)
+			logfile.stored_data += "[logstring]\[BR\]"
+		logfile.stored_data += "\[b\]Logfile dump completed.\[/b\]"
+		logfile.calculate_size()
+		if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(logfile))
+			if(!computer)
+				// This program shouldn't even be runnable without computer.
+				CRASH("Var computer is null!")
+				return
+			if(!computer.hard_drive)
+				computer.visible_message("\The [computer] shows an \"I/O Error - Hard drive connection error\" warning.")
+			else	// In 99.9% cases this will mean our HDD is full
+				computer.visible_message("\The [computer] shows an \"I/O Error - Hard drive may be full. Please free some space and try again. Required space: [logfile.size]GQ\" warning.")
+	if(href_list["PRG_renamechannel"])
+		if(!operator_mode || !channel)
+			return
+		var/mob/living/user = usr
+		var/newname = sanitize(input(user, "Enter new channel name or leave blank to cancel:"))
+		if(!newname || !channel)
+			return
+		channel.add_status_message("Channel renamed from [channel.title] to [newname] by operator.")
+		channel.title = newname
+	if(href_list["PRG_deletechannel"])
+		if(channel && ((channel.operator == src) || netadmin_mode))
+			del(channel)
+	if(href_list["PRG_setpassword"])
+		if(!channel || ((channel.operator != src) && !netadmin_mode))
+			return
+
+		var/mob/living/user = usr
+		var/newpassword = sanitize(input(user, "Enter new password for this channel. Leave blank to cancel, enter 'nopassword' to remove password completely:"))
+		if(!channel || !newpassword || ((channel.operator != src) && !netadmin_mode))
+			return
+
+		if(newpassword == "nopassword")
+			channel.password = ""
+		else
+			channel.password = newpassword
+
+	..(href, href_list)
+
+
+/datum/computer_file/program/chatclient/kill_program(var/forced = 0)
+	if(channel)
+		channel.remove_client(src)
+		channel = null
+	..(forced)
+
+/datum/nano_module/computer_chatclient
+	name = "NTNet Relay Chat Client"
+
+/datum/nano_module/computer_chatclient/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!ntnet_global || !ntnet_global.chat_channels)
+		return
+
+	var/list/data = list()
+	if(program)
+		data = program.get_header_data()
+
+	var/datum/computer_file/program/chatclient/C = program
+	if(!istype(C))
+		return
+
+	data["adminmode"] = C.netadmin_mode
+	if(C.channel)
+		data["title"] = C.channel.title
+		var/list/messages[0]
+		for(var/M in C.channel.messages)
+			messages.Add(list(list(
+				"msg" = M
+			)))
+		data["messages"] = messages
+		var/list/clients[0]
+		for(var/datum/computer_file/program/chatclient/cl in C.channel.clients)
+			clients.Add(list(list(
+				"name" = cl.username
+			)))
+		data["clients"] = clients
+		C.operator_mode = (C.channel.operator == C) ? 1 : 0
+		data["is_operator"] = C.operator_mode || C.netadmin_mode
+
+	else // Channel selection screen
+		var/list/all_channels[0]
+		for(var/datum/ntnet_conversation/conv in ntnet_global.chat_channels)
+			if(conv && conv.title)
+				all_channels.Add(list(list(
+					"chan" = conv.title
+				)))
+		data["all_channels"] = all_channels
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_chat.tmpl", "NTNet Relay Chat Client", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)

code/modules/modular_computers/file_system/programs/nttransfer.dm

@@ -0,0 +1,197 @@
+var/global/nttransfer_uid = 0
+
+/datum/computer_file/program/nttransfer
+	filename = "nttransfer"
+	filedesc = "NTNet P2P Transfer Client"
+	extended_desc = "This program allows for simple file transfer via direct peer to peer connection."
+	program_icon_state = "comm_logs"
+	size = 7
+	requires_ntnet = 1
+	requires_ntnet_feature = NTNET_PEERTOPEER
+	network_destination = "other device via P2P tunnel"
+	available_on_ntnet = 1
+	nanomodule_path = /datum/nano_module/computer_nttransfer/
+
+	var/error = ""										// Error screen
+	var/server_password = ""							// Optional password to download the file.
+	var/datum/computer_file/provided_file = null		// File which is provided to clients.
+	var/datum/computer_file/downloaded_file = null		// File which is being downloaded
+	var/list/connected_clients = list()					// List of connected clients.
+	var/datum/computer_file/program/nttransfer/remote	// Client var, specifies who are we downloading from.
+	var/download_completion = 0							// Download progress in GQ
+	var/download_netspeed = 0							// Our connectivity speed in GQ/s
+	var/actual_netspeed = 0								// Displayed in the UI, this is the actual transfer speed.
+	var/unique_token 									// UID of this program
+	var/upload_menu = 0									// Whether we show the program list and upload menu
+
+/datum/computer_file/program/nttransfer/New()
+	unique_token = nttransfer_uid
+	nttransfer_uid++
+	..()
+
+/datum/computer_file/program/nttransfer/process_tick()
+	// Server mode
+	update_netspeed()
+	if(provided_file)
+		for(var/datum/computer_file/program/nttransfer/C in connected_clients)
+			// Transfer speed is limited by device which uses slower connectivity.
+			// We can have multiple clients downloading at same time, but let's assume we use some sort of multicast transfer
+			// so they can all run on same speed.
+			C.actual_netspeed = min(C.download_netspeed, download_netspeed)
+			C.download_completion += C.actual_netspeed
+			if(C.download_completion >= provided_file.size)
+				C.finish_download()
+	else if(downloaded_file) // Client mode
+		if(!remote)
+			crash_download("Connection to remote server lost")
+
+/datum/computer_file/program/nttransfer/kill_program(var/forced = 0)
+	if(downloaded_file) // Client mode, clean up variables for next use
+		finalize_download()
+
+	if(provided_file) // Server mode, disconnect all clients
+		for(var/datum/computer_file/program/nttransfer/P in connected_clients)
+			P.crash_download("Connection terminated by remote server")
+		downloaded_file = null
+	..(forced)
+
+
+
+/datum/computer_file/program/nttransfer/proc/update_netspeed()
+	download_netspeed = 0
+	switch(ntnet_status)
+		if(1)
+			download_netspeed = NTNETSPEED_LOWSIGNAL
+		if(2)
+			download_netspeed = NTNETSPEED_HIGHSIGNAL
+		if(3)
+			download_netspeed = NTNETSPEED_ETHERNET
+
+// Finishes download and attempts to store the file on HDD
+/datum/computer_file/program/nttransfer/proc/finish_download()
+	if(!computer || !computer.hard_drive || !computer.hard_drive.store_file(downloaded_file))
+		error = "I/O Error:  Unable to save file. Check your hard drive and try again."
+	finalize_download()
+
+//  Crashes the download and displays specific error message
+/datum/computer_file/program/nttransfer/proc/crash_download(var/message)
+	error = message ? message : "An unknown error has occured during download"
+	finalize_download()
+
+// Cleans up variables for next use
+/datum/computer_file/program/nttransfer/proc/finalize_download()
+	if(remote)
+		remote.connected_clients.Remove(src)
+	downloaded_file = null
+	remote = null
+	download_completion = 0
+
+
+
+
+
+/datum/nano_module/computer_nttransfer
+	name = "NTNet P2P Transfer Client"
+
+/datum/nano_module/computer_nttransfer/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
+	if(!program)
+		return
+	var/datum/computer_file/program/nttransfer/PRG = program
+	if(!istype(PRG))
+		return
+
+	var/list/data = program.get_header_data()
+
+	if(PRG.error)
+		data["error"] = PRG.error
+	else if(PRG.downloaded_file)
+		data["downloading"] = 1
+		data["download_size"] = PRG.downloaded_file.size
+		data["download_progress"] = PRG.download_completion
+		data["download_netspeed"] = PRG.actual_netspeed
+		data["download_name"] = "[PRG.downloaded_file.filename].[PRG.downloaded_file.filetype]"
+	else if (PRG.provided_file)
+		data["uploading"] = 1
+		data["upload_uid"] = PRG.unique_token
+		data["upload_clients"] = PRG.connected_clients.len
+		data["upload_haspassword"] = PRG.server_password ? 1 : 0
+		data["upload_filename"] = "[PRG.provided_file.filename].[PRG.provided_file.filetype]"
+	else if (PRG.upload_menu)
+		var/list/all_files[0]
+		for(var/datum/computer_file/F in PRG.computer.hard_drive.stored_files)
+			all_files.Add(list(list(
+			"uid" = F.uid,
+			"filename" = "[F.filename].[F.filetype]",
+			"size" = F.size
+			)))
+		data["upload_filelist"] = all_files
+	else
+		var/list/all_servers[0]
+		for(var/datum/computer_file/program/nttransfer/P in ntnet_global.fileservers)
+			all_servers.Add(list(list(
+			"uid" = P.unique_token,
+			"filename" = "[P.provided_file.filename].[P.provided_file.filetype]",
+			"size" = P.provided_file.size,
+			"haspassword" = P.server_password ? 1 : 0
+			)))
+		data["servers"] = all_servers
+
+	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
+	if (!ui)
+		ui = new(user, src, ui_key, "ntnet_transfer.tmpl", "NTNet P2P Transfer Client", 575, 700, state = state)
+		ui.auto_update_layout = 1
+		ui.set_initial_data(data)
+		ui.open()
+		ui.set_auto_update(1)
+
+/datum/computer_file/program/nttransfer/Topic(href, href_list)
+	if(..())
+		return 1
+	if(href_list["PRG_downloadfile"])
+		for(var/datum/computer_file/program/nttransfer/P in ntnet_global.fileservers)
+			if("[P.unique_token]" == href_list["PRG_downloadfile"])
+				remote = P
+				break
+		if(!remote || !remote.provided_file)
+			return
+		if(remote.server_password)
+			var/pass = sanitize(input(usr, "Code 401 Unauthorized. Please enter password:", "Password required"))
+			if(pass != remote.server_password)
+				error = "Incorrect Password"
+				return
+		downloaded_file = remote.provided_file.clone()
+		remote.connected_clients.Add(src)
+		return
+	if(href_list["PRG_reset"])
+		error = ""
+		upload_menu = 0
+		finalize_download()
+		if(src in ntnet_global.fileservers)
+			ntnet_global.fileservers.Remove(src)
+		for(var/datum/computer_file/program/nttransfer/T in connected_clients)
+			T.crash_download("Remote server has forcibly closed the connection")
+		provided_file = null
+		return
+	if(href_list["PRG_setpassword"])
+		var/pass = sanitize(input(usr, "Enter new server password. Leave blank to cancel, input 'none' to disable password.", "Server security", "none"))
+		if(!pass)
+			return
+		if(pass == "none")
+			server_password = ""
+			return
+		server_password = pass
+		return
+	if(href_list["PRG_uploadfile"])
+		for(var/datum/computer_file/F in computer.hard_drive.stored_files)
+			if("[F.uid]" == href_list["PRG_uploadfile"])
+				if(F.unsendable)
+					error = "I/O Error: File locked."
+					return
+				provided_file = F
+				ntnet_global.fileservers.Add(src)
+				return
+		error = "I/O Error: Unable to locate file on hard drive."
+		return
+	if(href_list["PRG_uploadmenu"])
+		upload_menu = 1
+	return 0