Merge branch 'master' of github.com:Baystation12/Baystation12

code/WorkInProgress/AI_Visibility/ai.dm

@@ -0,0 +1,108 @@
+
+
+/mob/aiEye
+	var/list/visibleCameraChunks = list()
+	var/mob/ai = null
+	density = 0
+
+/mob/living/silicon/ai/var/mob/aiEye/eyeobj = new()
+
+/mob/living/silicon/ai/New()
+	..()
+	eyeobj.ai = src
+	spawn(20)
+		freelook()
+
+/mob/living/silicon/ai/death(gibbed)
+	if(client && client.eye == eyeobj)
+		for(var/datum/camerachunk/c in eyeobj.visibleCameraChunks)
+			c.remove(eyeobj)
+		client.eye = src
+	return ..(gibbed)
+
+/mob/living/silicon/ai/verb/freelook()
+	set category = "AI Commands"
+	set name = "freelook"
+	current = null	//cancel camera view first, it causes problems
+	cameraFollow = null
+	if(!eyeobj)	//if it got deleted somehow (like an admin trying to fix things <.<')
+		eyeobj = new()
+		eyeobj.ai = src
+	client.eye = eyeobj
+	eyeobj.loc = loc
+	cameranet.visibility(eyeobj)
+
+/mob/aiEye/Move()
+	. = ..()
+	if(.)
+		cameranet.visibility(src)
+
+/client/AIMove(n, direct, var/mob/living/silicon/ai/user)
+	if(eye == user.eyeobj)
+		user.eyeobj.loc = get_step(user.eyeobj, direct)
+		cameranet.visibility(user.eyeobj)
+
+	else
+		return ..()
+
+/turf/move_camera_by_click()
+	if(istype(usr, /mob/living/silicon/ai))
+		var/mob/living/silicon/ai/AI = usr
+		if(AI.client.eye == AI.eyeobj)
+			return
+	return ..()
+
+/mob/living/silicon/ai/attack_ai(var/mob/user as mob)
+	if (user != src)
+		return
+
+	if (stat == 2)
+		return
+
+	var/list/L = list()
+	for (var/obj/machinery/camera/C in world)
+		L.Add(C)
+
+	camera_sort(L)
+	L = camera_network_sort(L)
+
+	var/list/D = list()
+	for (var/obj/machinery/camera/C in L)
+		if ( C.network in src.networks )
+			D[text("[]: [][]", C.network, C.c_tag, (C.status ? null : " (Deactivated)"))] = C
+	D["Cancel"] = "Cancel"
+
+	var/t = input(user, "Which camera should you change to?") as null|anything in D
+
+	if (!t || t == "Cancel")
+		return 0
+
+	var/obj/machinery/camera/C = D[t]
+
+	eyeobj.loc = C.loc
+	cameranet.visibility(eyeobj)
+
+	return
+
+/mob/living/silicon/ai/cancel_camera()
+	set name = "Cancel Camera View"
+	set category = "OOC"
+	reset_view(null)
+	machine = null
+
+/mob/living/silicon/ai/reset_view(atom/A)
+	if (client)
+		if(!eyeobj)
+			eyeobj = new()
+			eyeobj.ai = src
+
+		client.eye = eyeobj
+		client.perspective = EYE_PERSPECTIVE
+
+		if (istype(A, /atom/movable))
+			eyeobj.loc = locate(A.x, A.y, A.z)
+
+		else
+			eyeobj.loc = locate(src.x, src.y, src.z)
+
+		cameranet.visibility(eyeobj)

code/WorkInProgress/AI_Visibility/cameranet.dm

@@ -0,0 +1,157 @@
+
+//------------------------------------------------------------
+//
+//                      The Cameranet
+//
+//   The cameranet is a single global instance of a unique
+//  datum, which contains logic for managing the individual
+//  chunks.
+//
+//------------------------------------------------------------
+
+/datum/cameranet
+	var/list/cameras = list()
+	var/list/chunks = list()
+	var/network = "net1"
+	var/ready = 0
+
+	var/list/minimap = list()
+
+	var/generating_minimap = TRUE
+
+var/datum/cameranet/cameranet = new()
+
+
+
+/datum/cameranet/New()
+	..()
+
+	spawn(100)
+		init_minimap()
+
+
+/datum/cameranet/proc/init_minimap()
+	for(var/x = 0, x <= world.maxx, x += 16)
+		for(var/y = 0, y <= world.maxy, y += 16)
+			sleep(1)
+			getCameraChunk(x, y, 5)
+			getCameraChunk(x, y, 1)
+
+	generating_minimap = FALSE
+
+
+/datum/cameranet/proc/chunkGenerated(x, y, z)
+	var/key = "[x],[y],[z]"
+	return key in chunks
+
+
+/datum/cameranet/proc/getCameraChunk(x, y, z)
+	var/key = "[x],[y],[z]"
+
+	if(!(key in chunks))
+		chunks[key] = new /datum/camerachunk(null, x, y, z)
+
+	return chunks[key]
+
+
+
+
+//  This proc updates what chunks are considered seen
+// by an aiEye. As part of the process, it will force
+// any newly visible chunks with pending unscheduled
+// updates to update, and show the correct obscuring
+// and dimming image sets. If you do not call this
+// after the eye has moved, it may result in the
+// affected AI gaining (partial) xray, seeing through
+// now-closed doors, not seeing through open doors,
+// or other visibility oddities, depending on if/when
+// they last visited any of the chunks in the nearby
+// area.
+
+//  It must be called manually, as there is no way to
+// have a proc called automatically every time an
+// object's loc changes.
+
+/datum/cameranet/proc/visibility(mob/aiEye/ai)
+	var/x1 = max(0, ai.x - 16) & ~0xf
+	var/y1 = max(0, ai.y - 16) & ~0xf
+	var/x2 = min(world.maxx, ai.x + 16) & ~0xf
+	var/y2 = min(world.maxy, ai.y + 16) & ~0xf
+
+	var/list/visibleChunks = list()
+
+	for(var/x = x1; x <= x2; x += 16)
+		for(var/y = y1; y <= y2; y += 16)
+			visibleChunks += getCameraChunk(x, y, ai.z)
+
+	var/list/remove = ai.visibleCameraChunks - visibleChunks
+	var/list/add = visibleChunks - ai.visibleCameraChunks
+
+	for(var/datum/camerachunk/c in remove)
+		c.remove(ai)
+
+	for(var/datum/camerachunk/c in add)
+		c.add(ai)
+
+
+
+
+//  This proc should be called if a turf, or the contents
+// of a turf, changes opacity. This includes such things
+// as changing the turf, opening or closing a door, or
+// anything else that would alter line of sight in the
+// general area.
+
+/datum/cameranet/proc/updateVisibility(turf/loc)
+	if(!chunkGenerated(loc.x & ~0xf, loc.y & ~0xf, loc.z))
+		return
+
+	var/datum/camerachunk/chunk = getCameraChunk(loc.x & ~0xf, loc.y & ~0xf, loc.z)
+	chunk.visibilityChanged(loc)
+
+
+
+
+//  This proc updates all relevant chunks when enabling or
+// creating a camera, allowing freelook and the minimap to
+// respond correctly.
+
+/datum/cameranet/proc/addCamera(obj/machinery/camera/c)
+	var/x1 = max(0, c.x - 16) & ~0xf
+	var/y1 = max(0, c.y - 16) & ~0xf
+	var/x2 = min(world.maxx, c.x + 16) & ~0xf
+	var/y2 = min(world.maxy, c.y + 16) & ~0xf
+
+	for(var/x = x1; x <= x2; x += 16)
+		for(var/y = y1; y <= y2; y += 16)
+			if(chunkGenerated(x, y, c.z))
+				var/datum/camerachunk/chunk = getCameraChunk(x, y, c.z)
+
+				if(!(c in chunk.cameras))
+					chunk.cameras += c
+					chunk.hasChanged()
+
+
+
+
+//  This proc updates all relevant chunks when disabling or
+// deleting a camera, allowing freelook and the minimap to
+// respond correctly.
+
+/datum/cameranet/proc/removeCamera(obj/machinery/camera/c)
+	var/x1 = max(0, c.x - 16) & ~0xf
+	var/y1 = max(0, c.y - 16) & ~0xf
+	var/x2 = min(world.maxx, c.x + 16) & ~0xf
+	var/y2 = min(world.maxy, c.y + 16) & ~0xf
+
+	for(var/x = x1; x <= x2; x += 16)
+		for(var/y = y1; y <= y2; y += 16)
+			if(chunkGenerated(x, y, c.z))
+				var/datum/camerachunk/chunk = getCameraChunk(x, y, c.z)
+
+				if(!c)
+					chunk.hasChanged()
+
+				if(c in chunk.cameras)
+					chunk.cameras -= c
+					chunk.hasChanged()

code/WorkInProgress/AI_Visibility/chunk.dm

@@ -0,0 +1,222 @@
+
+#define MINIMAP_UPDATE_DELAY 1200
+
+/datum/camerachunk
+	var/list/turfs = list()
+
+	var/list/obscuredTurfs = list()
+	var/list/visibleTurfs = list()
+	var/list/dimTurfs = list()
+
+	var/list/obscured = list()
+	var/list/dim = list()
+
+	var/list/cameras = list()
+	var/list/seenby = list()
+
+	var/changed = 1
+	var/updating = 0
+	var/minimap_updating = 0
+
+	var/x
+	var/y
+	var/z
+
+
+	var/icon/minimap_icon = new('minimap.dmi', "chunk_base")
+	var/obj/minimap_obj/minimap_obj = new()
+
+
+
+/datum/camerachunk/New(loc, x, y, z)
+	//Round X and Y down to a multiple of 16, if nessecary
+	src.x = x & ~0xF
+	src.y = y & ~0xF
+	src.z = z
+
+	rebuild_chunk()
+
+
+
+//  Completely re-calculate the whole chunk.
+
+/datum/camerachunk/proc/rebuild_chunk()
+	for(var/mob/aiEye/eye in seenby)
+		if(!eye.ai)
+			seenby -= eye
+			continue
+
+		if(eye.ai.client)
+			eye.ai.client.images -= obscured
+			eye.ai.client.images -= dim
+
+	var/start = locate(x, y, z)
+	var/end = locate(min(x + 15, world.maxx), min(y + 15, world.maxy), z)
+
+	turfs = block(start, end)
+	dimTurfs = list()
+	visibleTurfs = list()
+	obscured = list()
+	dim = list()
+	cameras = list()
+
+	for(var/obj/machinery/camera/c in range(16, locate(x + 8, y + 8, z)))
+		if(c.status)
+			cameras += c
+
+	for(var/obj/machinery/camera/c in cameras)
+		var/lum = c.luminosity
+		c.luminosity = 7
+
+		dimTurfs |= turfs & view(7, c)
+		visibleTurfs |= turfs & view(6, c)
+
+		c.luminosity = lum
+
+	obscuredTurfs = turfs - dimTurfs
+	dimTurfs -= visibleTurfs
+
+	for(var/turf/t in obscuredTurfs)
+		if(!t.obscured)
+			t.obscured = image('cameravis.dmi', t, "black", 15)
+
+		obscured += t.obscured
+
+	for(var/turf/t in dimTurfs)
+		if(!t.dim)
+			t.dim = image('cameravis.dmi', t, "dim", TURF_LAYER)
+			t.dim.mouse_opacity = 0
+
+		dim += t.dim
+
+	cameranet.minimap |= minimap_obj
+
+	for(var/mob/aiEye/eye in seenby)
+		if(eye.ai.client)
+			eye.ai.client.images |= obscured
+			eye.ai.client.images |= dim
+
+
+
+/datum/camerachunk/proc/add(mob/aiEye/eye)
+	eye.visibleCameraChunks |= src
+
+	if(eye.ai.client)
+		eye.ai.client.images |= obscured
+		eye.ai.client.images |= dim
+
+	seenby |= eye
+
+	if(changed && !updating)
+		update()
+		changed = 0
+
+
+
+/datum/camerachunk/proc/remove(mob/aiEye/eye)
+	eye.visibleCameraChunks -= src
+
+	if(eye.ai.client)
+		eye.ai.client.images -= obscured
+		eye.ai.client.images -= dim
+
+	seenby -= eye
+
+/datum/camerachunk/proc/visibilityChanged(turf/loc)
+	if(!(loc in visibleTurfs))
+		return
+
+	hasChanged()
+
+/datum/camerachunk/proc/hasChanged()
+	if(length(seenby) > 0)
+		if(!updating)
+			updating = 1
+
+			spawn(10)//Batch large changes, such as many doors opening or closing at once
+				update()
+				updating = 0
+
+	else
+		changed = 1
+
+	if(!minimap_updating)
+		minimap_updating = 1
+
+		spawn(MINIMAP_UPDATE_DELAY)
+			if(changed && !updating)
+				update()
+				changed = 0
+
+			update_minimap()
+			minimap_updating = 0
+
+/datum/camerachunk/proc/update()
+
+	var/list/newDimTurfs = list()
+	var/list/newVisibleTurfs = list()
+
+	for(var/obj/machinery/camera/c in cameras)
+		var/lum = c.luminosity
+		c.luminosity = 7
+
+		newDimTurfs |= turfs & view(7, c)
+		newVisibleTurfs |= turfs & view(6, c)
+
+		c.luminosity = lum
+
+	var/list/dimAdded = newDimTurfs - dimTurfs
+	var/list/dimRemoved = dimTurfs - newDimTurfs
+	var/list/visAdded = newVisibleTurfs - visibleTurfs
+	var/list/visRemoved = visibleTurfs - newVisibleTurfs
+
+	visibleTurfs = newVisibleTurfs
+	dimTurfs = newDimTurfs
+	obscuredTurfs = turfs - dimTurfs
+	dimTurfs -= visibleTurfs
+
+	var/list/images_added = list()
+	var/list/images_removed = list()
+
+	for(var/turf/t in dimRemoved)
+		if(t.dim)
+			dim -= t.dim
+			images_removed += t.dim
+
+		if(!(t in visibleTurfs))
+			if(!t.obscured)
+				t.obscured = image('cameravis.dmi', t, "black", 15)
+
+			obscured += t.obscured
+			images_added += t.obscured
+
+	for(var/turf/t in dimAdded)
+		if(!(t in visibleTurfs))
+			if(!t.dim)
+				t.dim = image('cameravis.dmi', t, "dim", 15)
+				t.mouse_opacity = 0
+
+			dim += t.dim
+			images_added += t.dim
+
+			if(t.obscured)
+				obscured -= t.obscured
+				images_removed += t.obscured
+
+	for(var/turf/t in visAdded)
+		if(t.obscured)
+			obscured -= t.obscured
+			images_removed += t.obscured
+
+	for(var/turf/t in visRemoved)
+		if(t in obscuredTurfs)
+			if(!t.obscured)
+				t.obscured = image('cameravis.dmi', t, "black", 15)
+
+			obscured += t.obscured
+			images_added += t.obscured
+
+	for(var/mob/aiEye/eye in seenby)
+		if(eye.ai.client)
+			eye.ai.client.images -= images_removed
+			eye.ai.client.images |= images_added

code/WorkInProgress/AI_Visibility/minimap.dm

@@ -0,0 +1,138 @@
+
+/client/var/minimap_view_z = 1
+
+/obj/minimap_obj
+	var/datum/camerachunk/chunk
+
+/obj/minimap_obj/Click(location, control, params)
+	if(!istype(usr, /mob/dead) && !istype(usr, /mob/living/silicon/ai) && !(usr.client && usr.client.holder && usr.client.holder.level >= 4))
+		return
+
+	var/list/par = params2list(params)
+	var/screen_loc = par["screen-loc"]
+
+	if(findtext(screen_loc, "minimap:") != 1)
+		return
+
+	screen_loc = copytext(screen_loc, length("minimap:") + 1)
+
+	var/x_text = copytext(screen_loc, 1, findtext(screen_loc, ","))
+	var/y_text = copytext(screen_loc, findtext(screen_loc, ",") + 1)
+
+	var/x = chunk.x
+	x += round((text2num(copytext(x_text, findtext(x_text, ":") + 1)) + 1) / 2)
+
+	var/y = chunk.y
+	y += round((text2num(copytext(y_text, findtext(y_text, ":") + 1)) + 1) / 2)
+
+	if(istype(usr, /mob/living/silicon/ai))
+		var/mob/living/silicon/ai/ai = usr
+		ai.freelook()
+		ai.eyeobj.loc = locate(max(1, x - 1), max(1, y - 1), usr.client.minimap_view_z)
+		cameranet.visibility(ai.eyeobj)
+
+	else
+		usr.loc = locate(max(1, x - 1), max(1, y - 1), usr.client.minimap_view_z)
+
+/mob/dead/verb/Open_Minimap()
+	set category = "Ghost"
+	cameranet.show_minimap(client)
+
+
+/mob/living/silicon/ai/verb/Open_Minimap()
+	set category = "AI Commands"
+	cameranet.show_minimap(client)
+
+
+/client/proc/Open_Minimap()
+	set category = "Admin"
+	cameranet.show_minimap(src)
+
+
+/mob/verb/Open_Minimap_Z()
+	set hidden = 1
+
+	if(!istype(src, /mob/dead) && !istype(src, /mob/living/silicon/ai) && !(client && client.holder && client.holder.level >= 4))
+		return
+
+	var/level = input("Select a Z level", "Z select", null) as null | anything in cameranet.minimap
+
+	if(level != null)
+		cameranet.show_minimap(client, level)
+
+
+
+/datum/cameranet/proc/show_minimap(client/client, z_level = "z-1")
+	if(!istype(client.mob, /mob/dead) && !istype(client.mob, /mob/living/silicon/ai) && !(client.holder && client.holder.level >= 4))
+		return
+
+	if(z_level in cameranet.minimap)
+		winshow(client, "minimapwindow", 1)
+
+		for(var/key in cameranet.minimap)
+			client.screen -= cameranet.minimap[key]
+
+		client.screen |= cameranet.minimap[z_level]
+
+		if(cameranet.generating_minimap)
+			spawn(50)
+				show_minimap(client, z_level)
+
+		client.minimap_view_z = text2num(copytext(z_level, 3))
+
+
+/datum/camerachunk/proc/update_minimap()
+	if(changed && !updating)
+		update()
+
+	minimap_icon.Blend(rgb(255, 0, 0), ICON_MULTIPLY)
+
+	var/list/turfs = visibleTurfs | dimTurfs
+
+	for(var/turf/turf in turfs)
+		var/x = (turf.x & 0xf) * 2
+		var/y = (turf.y & 0xf) * 2
+
+		if(turf.density)
+			minimap_icon.DrawBox(rgb(100, 100, 100), x + 1, y + 1, x + 2, y + 2)
+			continue
+
+		else if(istype(turf, /turf/space))
+			minimap_icon.DrawBox(rgb(0, 0, 0), x + 1, y + 1, x + 2, y + 2)
+
+		else
+			minimap_icon.DrawBox(rgb(200, 200, 200), x + 1, y + 1, x + 2, y + 2)
+
+		for(var/obj/structure/o in turf)
+			if(o.density)
+				if(istype(o, /obj/structure/window) && (o.dir == NORTH || o.dir == SOUTH || o.dir == EAST || o.dir == WEST))
+					if(o.dir == NORTH)
+						minimap_icon.DrawBox(rgb(150, 150, 200), x + 1, y + 2, x + 2, y + 2)
+					else if(o.dir == SOUTH)
+						minimap_icon.DrawBox(rgb(150, 150, 200), x + 1, y + 1, x + 2, y + 1)
+					else if(o.dir == EAST)
+						minimap_icon.DrawBox(rgb(150, 150, 200), x + 3, y + 1, x + 2, y + 2)
+					else if(o.dir == WEST)
+						minimap_icon.DrawBox(rgb(150, 150, 200), x + 1, y + 1, x + 1, y + 2)
+
+				else
+					minimap_icon.DrawBox(rgb(150, 150, 150), x + 1, y + 1, x + 2, y + 2)
+					break
+
+		for(var/obj/machinery/door/o in turf)
+			if(istype(o, /obj/machinery/door/window))
+				if(o.dir == NORTH)
+					minimap_icon.DrawBox(rgb(100, 150, 100), x + 1, y + 2, x + 2, y + 2)
+				else if(o.dir == SOUTH)
+					minimap_icon.DrawBox(rgb(100, 150, 100), x + 1, y + 1, x + 2, y + 1)
+				else if(o.dir == EAST)
+					minimap_icon.DrawBox(rgb(100, 150, 100), x + 2, y + 1, x + 2, y + 2)
+				else if(o.dir == WEST)
+					minimap_icon.DrawBox(rgb(100, 150, 100), x + 1, y + 1, x + 1, y + 2)
+
+			else
+				minimap_icon.DrawBox(rgb(100, 150, 100), x + 1, y + 1, x + 2, y + 2)
+				break
+
+	minimap_obj.screen_loc = "minimap:[src.x / 16],[src.y / 16]"
+	minimap_obj.icon = minimap_icon

code/WorkInProgress/AI_Visibility/util.dm

@@ -0,0 +1,39 @@
+
+
+/turf
+	var/image/obscured
+	var/image/dim
+
+/turf/proc/visibilityChanged()
+	cameranet.updateVisibility(src)
+
+/turf/New()
+	..()
+	cameranet.updateVisibility(src)
+
+/obj/machinery/door/update_nearby_tiles(need_rebuild)
+	. = ..(need_rebuild)
+	cameranet.updateVisibility(loc)
+
+/obj/machinery/camera/New()
+	..()
+	cameranet.addCamera(src)
+
+/obj/machinery/camera/Del()
+	cameranet.removeCamera(src)
+	..()
+
+/obj/machinery/camera/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
+	. = ..(W, user)
+	if(istype(W, /obj/item/weapon/wirecutters))
+		if(status)
+			cameranet.addCamera(src)
+		else
+			cameranet.removeCamera(src)
+
+/proc/checkcameravis(atom/A)
+	for(var/obj/machinery/camera/C in view(A,7))
+		if(!C.status || C.stat == 2)
+			continue
+		return 1
+	return 0

code/WorkInProgress/Cael_Aislinn/Rust/core_field.dm

@@ -131,7 +131,7 @@ Deuterium-tritium fusion: 4.5 x 10^7 K
 		radiation = 0
 
 		//update values
-		var/transfer_ratio = 50 / field_strength
+		var/transfer_ratio = field_strength / 50
 		major_radius = field_strength * 0.21875// max = 8.75
 		minor_radius = field_strength * 0.2125// max = 8.625
 		volume_covered = PI * major_radius * minor_radius * 2.5 * 2.5 * 2.5 * 7 * 7 * transfer_ratio
@@ -159,10 +159,12 @@ Deuterium-tritium fusion: 4.5 x 10^7 K
 			var/datum/gas_mixture/plasma_captured = new /datum/gas_mixture()
 			//
 			plasma_captured.toxins = round(gas_covered.toxins * transfer_ratio)
+			//world << "\blue[plasma_captured.toxins] moles of plasma captured"
 			plasma_captured.temperature = gas_covered.temperature
+			//plasma_captured.update_values()
 			gas_covered.toxins -= plasma_captured.toxins
-			plasma_captured.update_values()
-			gas_covered.update_values()
+			//gas_covered.update_values()
+			//
 			held_plasma.merge(plasma_captured)
 			//
 			environment.merge(gas_covered)
@@ -187,7 +189,25 @@ Deuterium-tritium fusion: 4.5 x 10^7 K
 		//if there is too much plasma in the field, lose some
 		/*if( held_plasma.toxins > (MOLES_CELLSTANDARD * 7) * (50 / field_strength) )
 			LosePlasma()*/
-		LosePlasma()
+		if(held_plasma.toxins > 1)
+			//lose a random amount of plasma back into the air, increased by the field strength (want to switch this over to frequency eventually)
+			var/loss_ratio = rand() * (0.05 + (0.05 * 50 / field_strength))
+			//world << "lost [loss_ratio*100]% of held plasma"
+			//
+			var/datum/gas_mixture/plasma_lost = new
+			plasma_lost.temperature = held_plasma.temperature
+			//
+			plasma_lost.toxins = held_plasma.toxins * loss_ratio
+			//plasma_lost.update_values()
+			held_plasma.toxins -= held_plasma.toxins * loss_ratio
+			//held_plasma.update_values()
+			//
+			environment.merge(plasma_lost)
+			radiation += loss_ratio * mega_energy * 0.1
+			mega_energy -= loss_ratio * mega_energy * 0.1
+		else
+			held_plasma.toxins = 0
+			//held_plasma.update_values()
 
 		//handle some reactants formatting
 		//helium-4 has no use at the moment, but a buttload of it is produced
@@ -293,30 +313,6 @@ Deuterium-tritium fusion: 4.5 x 10^7 K
 			catcher.UpdateSize()
 		return changed
 
-	proc/LosePlasma()
-		if(held_plasma.toxins > 1)
-			//lose a random amount of plasma back into the air, increased by the field strength (want to switch this over to frequency eventually)
-			var/datum/gas_mixture/environment = loc.return_air()
-			var/loss_ratio = rand() * (0.05 + (0.05 * 50 / field_strength))
-			//world << "lost [loss_ratio*100]% of held plasma"
-			//
-			var/datum/gas_mixture/plasma_lost = new
-			plasma_lost.temperature = held_plasma.temperature
-			//
-			plasma_lost.toxins = held_plasma.toxins * loss_ratio
-			plasma_lost.update_values()
-			held_plasma.toxins -= held_plasma.toxins * loss_ratio
-			held_plasma.update_values()
-			//
-			environment.merge(plasma_lost)
-			radiation += loss_ratio * mega_energy * 0.1
-			mega_energy -= loss_ratio * mega_energy * 0.1
-			return 1
-		else
-			held_plasma.toxins = 0
-			held_plasma.update_values()
-			return 0
-
 	//the !!fun!! part
 	//reactions have to be individually hardcoded, see AttemptReaction() below this
 	proc/React()

code/WorkInProgress/Cael_Aislinn/Rust/fuel_injector.dm

@@ -104,11 +104,11 @@
 					user.machine = null
 					user << browse(null, "window=fuel_injector")
 					return
-			var/t = "<B>Reactor Core Fuel Injector</B><BR>"
+			var/t = "<B>Reactor Core Fuel Injector</B><hr>"
 			t += "<b>Stage:</b> <font color=blue>[stage]</font><br>"
 			t += "<b>Status:</b> [injecting ? "<font color=green>Active</font> <a href='?src=\ref[src];end_injecting=1'>\[Disable\]</a>" : "<font color=blue>Standby</font> <a href='?src=\ref[src];begin_injecting=1'>\[Enable\]</a>"]<br>"
-			t += "<b>Interval (sec):</b> <font color=blue>[rate/10]</font> <a href='?src=\ref[src];cyclerate=1'>\[Modify\]</a>"
-			t += "<b>Fuel usage:</b> [fuel_usage*100]% <a href='?src=\ref[src];fuel_usage=1'>\[Modify\]</a>"
+			t += "<b>Interval (sec):</b> <font color=blue>[rate/10]</font> <a href='?src=\ref[src];cyclerate=1'>\[Modify\]</a><br>"
+			t += "<b>Fuel usage:</b> [fuel_usage*100]% <a href='?src=\ref[src];fuel_usage=1'>\[Modify\]</a><br>"
 			/*
 			var/t = "<B>Reactor Core Fuel Control</B><BR>"
 			t += "Current fuel injection stage: [active_stage]<br>"
@@ -146,6 +146,7 @@
 					t += "</tr>"
 			t += "</table>"
 			*/
+			t += "<hr>"
 			t += "<A href='?src=\ref[src];close=1'>Close</A><BR>"
 			user << browse(t, "window=fuel_injector;size=500x800")
 			user.machine = src
@@ -178,26 +179,21 @@
 			for(var/reagent in owned_assembly_port.cur_assembly.rod_quantities)
 				//world << "checking [reagent]"
 				if(owned_assembly_port.cur_assembly.rod_quantities[reagent] > 0)
-					//world << "	rods left: [owned_assembly_port.cur_assembly.rod_quantities[reagent]]]
+					//world << "	rods left: [owned_assembly_port.cur_assembly.rod_quantities[reagent]]"
 					var/amount = owned_assembly_port.cur_assembly.rod_quantities[reagent] * fuel_usage
 					var/numparticles = round(amount * 1000)
 					if(numparticles < 1)
 						numparticles = 1
 					//world << "	amount: [amount]"
 					//world << "	numparticles: [numparticles]"
-					for(var/i=0, i<numparticles, i++)
-						var/obj/effect/accelerated_particle/particle = new(src.loc, src.dir)
-						particle.particle_type = reagent
-						particle.energy = 0
-						particle.icon_state = "particle_single"
-						particle.pixel_x = rand(-10,10)
-						particle.pixel_y = rand(-10,10)
-						var/extra_particles = round(rand(0, numparticles - i - 1))
-						//world << "[extra_particles + 1] [reagent] particles"
-						particle.additional_particles = extra_particles
-						particle.target = target_field
-						i += extra_particles
-						//world << "[reagent] particle injected"
+					//
+					var/obj/effect/accelerated_particle/particle = new/obj/effect/accelerated_particle(src.loc, src.dir)
+					particle.particle_type = reagent
+					particle.energy = 0
+					particle.icon_state = "particle"
+					particle.additional_particles = numparticles - 1
+					particle.target = target_field
+					//
 					owned_assembly_port.cur_assembly.rod_quantities[reagent] -= amount
 					amount_left += owned_assembly_port.cur_assembly.rod_quantities[reagent]
 			owned_assembly_port.cur_assembly.amount_depleted = amount_left / 300

code/WorkInProgress/Cael_Aislinn/power_monitor.dm

@@ -0,0 +1,226 @@
+//links to a power monitor computer and transmits the amount of energy in the associated powercable network
+//uses the navbeacon sprite and transmits data via magic for now
+
+/obj/machinery/powermonitor
+
+	icon = 'objects.dmi'
+	icon_state = "navbeacon0-f"
+	name = "power monitor"
+	desc = "A monitoring device used to track power in a cable network."
+	level = 1		// underfloor
+	layer = 2.5
+	anchored = 1
+
+	var/freq = 1427		// radio frequency
+	var/powernet_tag = ""	//the text tag associated with this power monitor's network
+	var/open = 0		// true if cover is open
+	var/locked = 1		// true if controls are locked
+	var/list/codes		// assoc. list of transponder codes
+	var/codes_txt = ""	// codes as set on map: "tag1;tag2" or "tag1=value;tag2=value"
+
+	req_access = list(access_engine)
+
+	New()
+		..()
+		var/turf/T = loc
+		hide(T.intact)
+
+		set_codes()
+
+		spawn(5)	// must wait for map loading to finish
+			if(radio_controller)
+				radio_controller.add_object(src, freq, RADIO_POWER)
+
+	// set the transponder codes assoc list from codes_txt
+	proc/set_codes()
+		if(!codes_txt)
+			return
+
+		codes = new()
+
+		var/list/entries = dd_text2List(codes_txt, ";")	// entries are separated by semicolons
+
+		for(var/e in entries)
+			var/index = findtext(e, "=")		// format is "key=value"
+			if(index)
+				var/key = copytext(e, 1, index)
+				var/val = copytext(e, index+1)
+				codes[key] = val
+			else
+				codes[e] = "1"
+
+	// called when turf state changes
+	// hide the object if turf is intact
+	hide(var/intact)
+		invisibility = intact ? 101 : 0
+		updateicon()
+
+	// update the icon_state
+	proc/updateicon()
+		var/state="navbeacon[open]"
+		if(invisibility)
+			icon_state = "[state]-f"	// if invisible, set icon to faded version
+										// in case revealed by T-scanner
+		else
+			icon_state = "[state]"
+
+	// look for a signal of the form "getpowerlevel"
+	// where X is any
+	// or the location
+	// or one of the set transponder keys
+	// if found, return a signal
+	receive_signal(datum/signal/signal)
+
+		var/request = signal.data["getpowermonitor"]
+		if(request && (request == "any" || request == powernet_tag) )
+			spawn(1)
+				post_signal()
+
+	// return a signal giving the power network energy level
+	proc/post_signal()
+
+		var/datum/radio_frequency/frequency = radio_controller.return_frequency(freq)
+
+		if(!frequency) return
+
+		var/datum/signal/signal = new()
+		signal.source = src
+		signal.transmission_method = 1
+		signal.data["powerlevel"] = 1	//TODO
+
+		for(var/key in codes)
+			signal.data[key] = codes[key]
+
+		frequency.post_signal(src, signal, filter = RADIO_POWER)
+
+	attackby(var/obj/item/I, var/mob/user)
+		var/turf/T = loc
+		if(T.intact)
+			return		// prevent intraction when T-scanner revealed
+
+		if(istype(I, /obj/item/weapon/screwdriver))
+			open = !open
+
+			user.visible_message("[user] [open ? "opens" : "closes"] the beacon's cover.", "You [open ? "open" : "close"] the beacon's cover.")
+
+			updateicon()
+
+		else if (istype(I, /obj/item/weapon/card/id)||istype(I, /obj/item/device/pda))
+			if(open)
+				if (src.allowed(user))
+					src.locked = !src.locked
+					user << "Controls are now [src.locked ? "locked." : "unlocked."]"
+				else
+					user << "\red Access denied."
+				updateDialog()
+			else
+				user << "You must open the cover first!"
+		return
+
+	attack_ai(var/mob/user)
+		interact(user, 1)
+
+	attack_paw()
+		return
+
+	attack_hand(var/mob/user)
+		interact(user, 0)
+
+	proc/interact(var/mob/user, var/ai = 0)
+		var/turf/T = loc
+		if(T.intact)
+			return		// prevent intraction when T-scanner revealed
+
+		if(!open && !ai)	// can't alter controls if not open, unless you're an AI
+			user << "The monitor's control cover is closed."
+			return
+
+		var/dat = "<TT><B>Navigation Beacon</B><HR>"
+		if(locked && !ai)
+			dat += "<i>(swipe card to unlock controls)</i><BR>"
+		else if(!ai)
+			dat += "<i>(swipe card to lock controls)</i><BR>"
+
+		dat += "Frequency: "
+		if(!locked)
+			dat += "<A href='byond://?src=\ref[src];freq=-10'>-</A>"
+			dat += "<A href='byond://?src=\ref[src];freq=-2'>-</A>"
+		dat += "[format_frequency(freq)]"
+		if(!locked)
+			dat += "<A href='byond://?src=\ref[src];freq=2'>+</A>"
+			dat += "<A href='byond://?src=\ref[src];freq=10'>+</A>"
+		dat += "<hr>"
+
+		dat += "Power network tag: [powernet_tag ? powernet_tag : "(none)"]</A><BR>"
+		dat += "Transponder Codes:<UL>"
+		for(var/key in codes)
+			dat += "<LI>[key] ... [codes[key]]"
+			if(!locked)
+				dat += " <small><A href='byond://?src=\ref[src];edit=1;code=[key]'>(edit)</A>"
+				dat += " <A href='byond://?src=\ref[src];delete=1;code=[key]'>(delete)</A></small><BR>"
+		if(!locked)
+			dat += "<small><A href='byond://?src=\ref[src];add=1;'>(add new)</A></small><BR>"
+		dat += "<UL></TT>"
+
+		user << browse(dat, "window=powermonitor")
+		onclose(user, "powermonitor")
+		return
+
+	Topic(href, href_list)
+		..()
+		if (usr.stat)
+			return
+		if ((in_range(src, usr) && istype(src.loc, /turf)) || (istype(usr, /mob/living/silicon)))
+			if(open && !locked)
+				usr.machine = src
+
+				if (href_list["freq"])
+					freq = sanitize_frequency(freq + text2num(href_list["freq"]))
+					updateDialog()
+
+				else if(href_list["modifytag"])
+					var/newtag = input("Enter new power network tag", "Power Monitor", powernet_tag) as text|null
+					if(newtag)
+						powernet_tag = newtag
+						updateDialog()
+
+				else if(href_list["edit"])
+					var/codekey = href_list["code"]
+
+					var/newkey = input("Enter Transponder Code Key", "Power Monitor", codekey) as text|null
+					if(!newkey)
+						return
+
+					var/codeval = codes[codekey]
+					var/newval = input("Enter Transponder Code Value", "Power Monitor", codeval) as text|null
+					if(!newval)
+						newval = codekey
+						return
+
+					codes.Remove(codekey)
+					codes[newkey] = newval
+
+					updateDialog()
+
+				else if(href_list["delete"])
+					var/codekey = href_list["code"]
+					codes.Remove(codekey)
+					updateDialog()
+
+				else if(href_list["add"])
+
+					var/newkey = input("Enter New Transponder Code Key", "Power Monitor") as text|null
+					if(!newkey)
+						return
+
+					var/newval = input("Enter New Transponder Code Value", "Power Monitor") as text|null
+					if(!newval)
+						newval = "1"
+						return
+
+					if(!codes)
+						codes = new()
+
+					codes[newkey] = newval
+
+					updateDialog()