mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2026-07-15 02:03:05 +01:00
Spookerton
978f4511a5
- distance is INFINITE, 0, or a positive integer based on get_dist() between the examiner and examinee's turfs when they are on the same Z. When the examiner is dead or a ghost, distance is always 0. - also updates /examine( implementations to use it! - adds w_class_to_name proc for reusing "It is a X item." examine behavior.
54 lines
1.5 KiB
Plaintext
54 lines
1.5 KiB
Plaintext
/obj/item/shield_diffuser
|
|
name = "portable shield diffuser"
|
|
desc = "A small handheld device designed to disrupt energy barriers"
|
|
description_info = "This device disrupts shields on directly adjacent tiles (in a + shaped pattern), in a similar way the floor mounted variant does. It is, however, portable and run by an internal battery. Can be recharged with a regular recharger."
|
|
icon = 'icons/obj/machines/shielding.dmi'
|
|
icon_state = "hdiffuser_off"
|
|
var/obj/item/cell/device/cell
|
|
var/enabled = 0
|
|
|
|
|
|
/obj/item/shield_diffuser/Initialize()
|
|
cell = new(src)
|
|
. = ..()
|
|
|
|
/obj/item/shield_diffuser/Destroy()
|
|
qdel(cell)
|
|
cell = null
|
|
if(enabled)
|
|
STOP_PROCESSING(SSobj, src)
|
|
. = ..()
|
|
|
|
/obj/item/shield_diffuser/get_cell()
|
|
return cell
|
|
|
|
/obj/item/shield_diffuser/process()
|
|
if(!enabled)
|
|
return
|
|
|
|
for(var/direction in cardinal)
|
|
var/turf/simulated/shielded_tile = get_step(get_turf(src), direction)
|
|
for(var/obj/effect/energy_field/S in shielded_tile)
|
|
if(istype(S) && cell.checked_use(10 KILOWATTS * CELLRATE))
|
|
qdel(S)
|
|
|
|
/obj/item/shield_diffuser/update_icon()
|
|
if(enabled)
|
|
icon_state = "hdiffuser_on"
|
|
else
|
|
icon_state = "hdiffuser_off"
|
|
|
|
/obj/item/shield_diffuser/attack_self()
|
|
enabled = !enabled
|
|
update_icon()
|
|
if(enabled)
|
|
START_PROCESSING(SSobj, src)
|
|
else
|
|
STOP_PROCESSING(SSobj, src)
|
|
to_chat(usr, "You turn \the [src] [enabled ? "on" : "off"].")
|
|
|
|
/obj/item/shield_diffuser/examine(mob/user, distance, infix, suffix)
|
|
. = ..()
|
|
. += "The charge meter reads [cell ? cell.percent() : 0]%"
|
|
. += "It is [enabled ? "enabled" : "disabled"]."
|