mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2026-08-31 09:08:56 +01:00
715de43f35
* Better notifications * Add buttons to del/move tabs in edit mode * Add a <span> to emotes * Fix duplicate IDs in VChat and add more logging * VChat: Redone chat output in Vue.js * Ported tg asset cache * VChat DME Update * Replace \image macro with bicon() * NanoUI Subsystem Fixes Don't do this, the asset subsystem does this for you * Allow narrate/globalnarrate shenanigans Allows HTML if your entire thing is HTML * Disable bicon() icon object cache, and create text tag cache * Ore Scanner is written incorrectly Only revealed by vchat * Fixes 2 VChat bugs * Underline links in VChat * Fix LOOC color * VChat Improvements Hopefully, anyway. - Arbitrary font size setting - Line height setting - Multiple crush settings - Rewrote how tabs work hopefully for performance - Hidden messages are actually put elsewhere - Attempts to correct chat backlog restore on rejoin * Surgery steps to use <span> * Some VChat Tweaks - Chat remains between client reconnects if your client didn't close (so things like using the reconnect button, or autoreconnects at round end when that feels like working) - The client doesn't send pings to the server, the server sends pings to the client. This fixes AFK measurements for AFK kick purposes. - Turn latency indicator into a green/red indicator to show if you're connected, and when clicked will perform a one-time ping (and block doing it again for 10 seconds). It will display '?ms' if it never got a reply, or '999ms' if it did, but it was over 1s. * Include date in filename for VChat log save * Merge pull request #6767 from Cyantime/patch-2 Change chat export naming scheme * Adds VChat tab saving Saves every time you enter/exit edit mode. Persists between rounds, VChat reloads via verb, etc. * Fix chat exporting when someone has used unicode Only affects clients still using 512 * Use CLIENT_FROM_VAR for ease of code reading * Update code/modules/client/asset_cache.dm Co-Authored-By: Novacat <35587478+Novacat@users.noreply.github.com> * Fix runtime when client disconnects before vchat loads * Fix polaris version of command reports * Fix LOOC color in oldchat * Put some styles in various adminpm messages * Round info and advanced who spans * Fix missing tag-end * Maybe fix images for linux and statpanel but also doom everyone Co-authored-by: ShadowLarkens <ShadowLarkens@users.noreply.github.com> Co-authored-by: Novacat <35587478+Novacat@users.noreply.github.com>
79 lines
2.5 KiB
Plaintext
79 lines
2.5 KiB
Plaintext
/datum/wires/jukebox
|
|
random = 1
|
|
holder_type = /obj/machinery/media/jukebox
|
|
wire_count = 11
|
|
|
|
var/const/WIRE_POWER = 1
|
|
var/const/WIRE_HACK = 2
|
|
var/const/WIRE_SPEEDUP = 4
|
|
var/const/WIRE_SPEEDDOWN = 8
|
|
var/const/WIRE_REVERSE = 16
|
|
var/const/WIRE_NOTHING1 = 32
|
|
var/const/WIRE_NOTHING2 = 64
|
|
var/const/WIRE_START = 128
|
|
var/const/WIRE_STOP = 256
|
|
var/const/WIRE_PREV = 512
|
|
var/const/WIRE_NEXT = 1024
|
|
|
|
/datum/wires/jukebox/CanUse(var/mob/living/L)
|
|
var/obj/machinery/media/jukebox/A = holder
|
|
if(A.panel_open)
|
|
return 1
|
|
return 0
|
|
|
|
// Show the status of lights as a hint to the current state
|
|
/datum/wires/jukebox/GetInteractWindow()
|
|
var/obj/machinery/media/jukebox/A = holder
|
|
. += ..()
|
|
. += show_hint(0x1, A.stat & (BROKEN|NOPOWER), "The power light is off.", "The power light is on.")
|
|
. += show_hint(0x2, A.hacked, "The parental guidance light is off.", "The parental guidance light is on.")
|
|
. += show_hint(0x4, IsIndexCut(WIRE_REVERSE), "The data light is hauntingly dark.", "The data light is glowing softly.")
|
|
|
|
// Give a hint as to what each wire does
|
|
/datum/wires/jukebox/UpdatePulsed(var/index)
|
|
var/obj/machinery/media/jukebox/A = holder
|
|
switch(index)
|
|
if(WIRE_POWER)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The power light flickers.</span>")
|
|
A.shock(usr, 90)
|
|
if(WIRE_HACK)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The parental guidance light flickers.</span>")
|
|
if(WIRE_REVERSE)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The data light blinks ominously.</span>")
|
|
if(WIRE_SPEEDUP)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The speakers squeaks.</span>")
|
|
if(WIRE_SPEEDDOWN)
|
|
holder.visible_message("<span class='notice'>[bicon(holder)] The speakers rumble.</span>")
|
|
if(WIRE_START)
|
|
A.StartPlaying()
|
|
if(WIRE_STOP)
|
|
A.StopPlaying()
|
|
if(WIRE_PREV)
|
|
A.PrevTrack()
|
|
if(WIRE_NEXT)
|
|
A.NextTrack()
|
|
else
|
|
A.shock(usr, 10) // The nothing wires give a chance to shock just for fun
|
|
|
|
/datum/wires/jukebox/UpdateCut(var/index, var/mended)
|
|
var/obj/machinery/media/jukebox/A = holder
|
|
|
|
switch(index)
|
|
if(WIRE_POWER)
|
|
// TODO - Actually make machine electrified or something.
|
|
A.shock(usr, 90)
|
|
|
|
if(WIRE_HACK)
|
|
if(mended)
|
|
A.set_hacked(0)
|
|
else
|
|
A.set_hacked(1)
|
|
|
|
if(WIRE_SPEEDUP, WIRE_SPEEDDOWN, WIRE_REVERSE)
|
|
var/newfreq = IsIndexCut(WIRE_REVERSE) ? -1 : 1;
|
|
if (IsIndexCut(WIRE_SPEEDUP))
|
|
newfreq *= 2
|
|
if (IsIndexCut(WIRE_SPEEDDOWN))
|
|
newfreq *= 0.5
|
|
A.freq = newfreq
|