mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-17 21:52:42 +00:00
715de43f35
* Better notifications * Add buttons to del/move tabs in edit mode * Add a <span> to emotes * Fix duplicate IDs in VChat and add more logging * VChat: Redone chat output in Vue.js * Ported tg asset cache * VChat DME Update * Replace \image macro with bicon() * NanoUI Subsystem Fixes Don't do this, the asset subsystem does this for you * Allow narrate/globalnarrate shenanigans Allows HTML if your entire thing is HTML * Disable bicon() icon object cache, and create text tag cache * Ore Scanner is written incorrectly Only revealed by vchat * Fixes 2 VChat bugs * Underline links in VChat * Fix LOOC color * VChat Improvements Hopefully, anyway. - Arbitrary font size setting - Line height setting - Multiple crush settings - Rewrote how tabs work hopefully for performance - Hidden messages are actually put elsewhere - Attempts to correct chat backlog restore on rejoin * Surgery steps to use <span> * Some VChat Tweaks - Chat remains between client reconnects if your client didn't close (so things like using the reconnect button, or autoreconnects at round end when that feels like working) - The client doesn't send pings to the server, the server sends pings to the client. This fixes AFK measurements for AFK kick purposes. - Turn latency indicator into a green/red indicator to show if you're connected, and when clicked will perform a one-time ping (and block doing it again for 10 seconds). It will display '?ms' if it never got a reply, or '999ms' if it did, but it was over 1s. * Include date in filename for VChat log save * Merge pull request #6767 from Cyantime/patch-2 Change chat export naming scheme * Adds VChat tab saving Saves every time you enter/exit edit mode. Persists between rounds, VChat reloads via verb, etc. * Fix chat exporting when someone has used unicode Only affects clients still using 512 * Use CLIENT_FROM_VAR for ease of code reading * Update code/modules/client/asset_cache.dm Co-Authored-By: Novacat <35587478+Novacat@users.noreply.github.com> * Fix runtime when client disconnects before vchat loads * Fix polaris version of command reports * Fix LOOC color in oldchat * Put some styles in various adminpm messages * Round info and advanced who spans * Fix missing tag-end * Maybe fix images for linux and statpanel but also doom everyone Co-authored-by: ShadowLarkens <ShadowLarkens@users.noreply.github.com> Co-authored-by: Novacat <35587478+Novacat@users.noreply.github.com>
112 lines
3.3 KiB
Plaintext
112 lines
3.3 KiB
Plaintext
///////////////ANTIBODY SCANNER///////////////
|
|
|
|
/obj/item/device/antibody_scanner
|
|
name = "antibody scanner"
|
|
desc = "Scans living beings for antibodies in their blood."
|
|
icon_state = "health"
|
|
w_class = ITEMSIZE_SMALL
|
|
item_state = "electronic"
|
|
|
|
/obj/item/device/antibody_scanner/attack(mob/M as mob, mob/user as mob)
|
|
if(!istype(M,/mob/living/carbon/))
|
|
report("Scan aborted: Incompatible target.", user)
|
|
return
|
|
|
|
var/mob/living/carbon/C = M
|
|
if (istype(C,/mob/living/carbon/human/))
|
|
var/mob/living/carbon/human/H = C
|
|
if(!H.should_have_organ(O_HEART))
|
|
report("Scan aborted: The target does not have blood.", user)
|
|
return
|
|
|
|
if(!C.antibodies.len)
|
|
report("Scan Complete: No antibodies detected.", user)
|
|
return
|
|
|
|
if (CLUMSY in user.mutations && prob(50))
|
|
// I was tempted to be really evil and rot13 the output.
|
|
report("Antibodies detected: [reverse_text(antigens2string(C.antibodies))]", user)
|
|
else
|
|
report("Antibodies detected: [antigens2string(C.antibodies)]", user)
|
|
|
|
/obj/item/device/antibody_scanner/proc/report(var/text, mob/user as mob)
|
|
to_chat(user, "<font color='blue'>[bicon(src)] \The [src] beeps,</font> \"<font color='blue'>[text]</font>\"")
|
|
|
|
///////////////VIRUS DISH///////////////
|
|
|
|
/obj/item/weapon/virusdish
|
|
name = "virus dish"
|
|
icon = 'icons/obj/items.dmi'
|
|
icon_state = "implantcase-b"
|
|
var/datum/disease2/disease/virus2 = null
|
|
var/growth = 0
|
|
var/basic_info = null
|
|
var/info = 0
|
|
var/analysed = 0
|
|
|
|
/obj/item/weapon/virusdish/random
|
|
name = "virus sample"
|
|
|
|
/obj/item/weapon/virusdish/random/New()
|
|
..()
|
|
src.virus2 = new /datum/disease2/disease
|
|
src.virus2.makerandom()
|
|
growth = rand(5, 50)
|
|
|
|
/obj/item/weapon/virusdish/attackby(var/obj/item/weapon/W as obj,var/mob/living/carbon/user as mob)
|
|
if(istype(W,/obj/item/weapon/hand_labeler) || istype(W,/obj/item/weapon/reagent_containers/syringe))
|
|
return
|
|
..()
|
|
if(prob(50))
|
|
to_chat(user, "<span class='danger'>\The [src] shatters!</span>")
|
|
if(virus2.infectionchance > 0)
|
|
for(var/mob/living/carbon/target in view(1, get_turf(src)))
|
|
if(airborne_can_reach(get_turf(src), get_turf(target)))
|
|
infect_virus2(target, src.virus2)
|
|
qdel(src)
|
|
|
|
/obj/item/weapon/virusdish/examine(mob/user)
|
|
..()
|
|
if(basic_info)
|
|
to_chat(user, "[basic_info] : <a href='?src=\ref[src];info=1'>More Information</a>")
|
|
|
|
/obj/item/weapon/virusdish/Topic(href, href_list)
|
|
. = ..()
|
|
if(.) return 1
|
|
|
|
if(href_list["info"])
|
|
usr << browse(info, "window=info_\ref[src]")
|
|
return 1
|
|
|
|
/obj/item/weapon/ruinedvirusdish
|
|
name = "ruined virus sample"
|
|
icon = 'icons/obj/items.dmi'
|
|
icon_state = "implantcase-b"
|
|
desc = "The bacteria in the dish are completely dead."
|
|
|
|
/obj/item/weapon/ruinedvirusdish/attackby(var/obj/item/weapon/W as obj,var/mob/living/carbon/user as mob)
|
|
if(istype(W,/obj/item/weapon/hand_labeler) || istype(W,/obj/item/weapon/reagent_containers/syringe))
|
|
return ..()
|
|
|
|
if(prob(50))
|
|
to_chat(user, "\The [src] shatters!")
|
|
qdel(src)
|
|
|
|
///////////////GNA DISK///////////////
|
|
|
|
/obj/item/weapon/diseasedisk
|
|
name = "blank GNA disk"
|
|
icon = 'icons/obj/cloning.dmi'
|
|
icon_state = "datadisk0"
|
|
w_class = ITEMSIZE_TINY
|
|
var/datum/disease2/effectholder/effect = null
|
|
var/list/species = null
|
|
var/stage = 1
|
|
var/analysed = 1
|
|
|
|
/obj/item/weapon/diseasedisk/premade/New()
|
|
name = "blank GNA disk (stage: [stage])"
|
|
effect = new /datum/disease2/effectholder
|
|
effect.effect = new /datum/disease2/effect/invisible
|
|
effect.stage = stage
|