mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-24 17:11:40 +00:00
d0d6689263
Adds autopilot functionality for shuttle one and shuttle two. It can be enabled and disabled by the flight computer. Autopilot is active by default on both shuttles. The shuttle waits for two minutes when it reaches the outpost or station, except for the first flight, where it waits for about ten minutes, which should be plenty of time for people to get on and for the pilot to turn it off if one exists. Adds renaming feature to all shuttles. Ports /tg/'s 'shuttle warning' effect, which adds a bunch of blue circles where a ship is about to land, which should prevent surprise shuttle crushes if paying attention. Flight times for all routes are cut in half to act as the bonus for flying manually. Automatic flight takes twice as long, and so it will take the current amount of time. Makes Ninja shuttle faster because Nippen steal. Does some cleanup with temporary effects.
50 lines
1.3 KiB
Plaintext
50 lines
1.3 KiB
Plaintext
/datum/technomancer/spell/pulsar
|
|
name = "Pulsar"
|
|
desc = "Emits electronic pulses to destroy, disable, or otherwise harm devices and machines. Be sure to not hit yourself with this."
|
|
cost = 100
|
|
obj_path = /obj/item/weapon/spell/spawner/pulsar
|
|
category = OFFENSIVE_SPELLS
|
|
|
|
/obj/item/weapon/spell/spawner/pulsar
|
|
name = "pulsar"
|
|
desc = "Be sure to not hit yourself!"
|
|
icon_state = "radiance"
|
|
cast_methods = CAST_RANGED | CAST_THROW
|
|
aspect = ASPECT_EMP
|
|
spawner_type = /obj/effect/temporary_effect/pulsar
|
|
|
|
/obj/item/weapon/spell/spawner/pulsar/New()
|
|
..()
|
|
set_light(3, 2, l_color = "#2ECCFA")
|
|
|
|
/obj/item/weapon/spell/spawner/pulsar/on_ranged_cast(atom/hit_atom, mob/user)
|
|
if(within_range(hit_atom) && pay_energy(4000))
|
|
adjust_instability(8)
|
|
..()
|
|
|
|
/obj/item/weapon/spell/spawner/pulsar/on_throw_cast(atom/hit_atom, mob/user)
|
|
empulse(hit_atom, 1, 1, 1, 1, log=1)
|
|
|
|
/obj/effect/temporary_effect/pulsar
|
|
name = "pulsar"
|
|
desc = "Not a real pulsar, but still emits loads of EMP."
|
|
icon_state = "shield2"
|
|
time_to_die = null
|
|
light_range = 4
|
|
light_power = 5
|
|
light_color = "#2ECCFA"
|
|
var/pulses_remaining = 3
|
|
|
|
/obj/effect/temporary_effect/pulsar/New()
|
|
..()
|
|
spawn(0)
|
|
pulse_loop()
|
|
|
|
/obj/effect/temporary_effect/pulsar/proc/pulse_loop()
|
|
while(pulses_remaining)
|
|
sleep(2 SECONDS)
|
|
empulse(src, 1, 1, 2, 2, log = 1)
|
|
pulses_remaining--
|
|
qdel(src)
|
|
|