mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-19 22:51:40 +00:00
fdabe51ee8
* Adds linter defines to repo. * Uncomments linter defines already in the code. * Resolves unreachable code linter errors. * Nukes decade+ old syndie specops code except for computer since that's mapped in????? * Resolves procs has no parent linter error. * Proc signature fixes * Bad comments * "In" danger * Type safety * Implied nested list abuse * Top level ..() usage * Sleepy coder typos * Invalid kwargs calls * Pointless returns * Linter hacks (see full message) Byond doesn't care and it has no effect but linter doesn't like var/proc for holding references to procs, despite that it's valid byond code. Also, the linter seems to have serious issues figuring out relative proc names. This commit is a sort of take-it-or-leave-it thing. It's not required, it just cuts down on warnings, but this code is valid DM code. * WHATEVER THIS IS * Trick dreamchecker linter into ignoring this file's sins in it's weird use of vars * Fix list decoration syntax - Its a list, not list of lists - To declare that a var is a list you can `var/list/blah = list()` syntax or the `var/blah[0]` syntax. Both do exactly the same thing. But if you do `var/list/blah[0]` that is just like doing `var/list/list/blah = list()` * Hopefully stops the ai holder subtype folder from going quantum and sometimes changes capitalization over time, and incidentally causing 20+ linter errors. * Fixes unwrapped negated object in list linter error. * Resolves colon-like list accessing linter error. * Turns linter on in linter config. * Fixes closet indentation properly and cleans up suit storage unit switch. Co-authored-by: Aronai Sieyes <arokha@arokha.com> Co-authored-by: Leshana <Leshana@users.noreply.github.com>
92 lines
2.6 KiB
Plaintext
92 lines
2.6 KiB
Plaintext
//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:31
|
|
|
|
/obj/machinery/computer/prisoner
|
|
name = "prisoner management console"
|
|
desc = "Used to keep those sneaky prisoners in line, if they have an implant."
|
|
icon_keyboard = "security_key"
|
|
icon_screen = "explosive"
|
|
light_color = "#a91515"
|
|
req_access = list(access_armory)
|
|
circuit = /obj/item/weapon/circuitboard/prisoner
|
|
var/id = 0.0
|
|
var/temp = null
|
|
var/status = 0
|
|
var/timeleft = 60
|
|
var/stop = 0.0
|
|
var/screen = 0 // 0 - No Access Denied, 1 - Access allowed
|
|
|
|
/obj/machinery/computer/prisoner/attack_ai(var/mob/user as mob)
|
|
return src.attack_hand(user)
|
|
|
|
/obj/machinery/computer/prisoner/attack_hand(mob/user)
|
|
if(..())
|
|
return
|
|
tgui_interact(user)
|
|
|
|
/obj/machinery/computer/prisoner/tgui_interact(mob/user, datum/tgui/ui)
|
|
ui = SStgui.try_update_ui(user, src, ui)
|
|
if(!ui)
|
|
ui = new(user, src, "PrisonerManagement", name)
|
|
ui.open()
|
|
|
|
/obj/machinery/computer/prisoner/tgui_data(mob/user)
|
|
var/list/chemImplants = list()
|
|
var/list/trackImplants = list()
|
|
if(screen)
|
|
for(var/obj/item/weapon/implant/chem/C in all_chem_implants)
|
|
var/turf/T = get_turf(C)
|
|
if(!T)
|
|
continue
|
|
if(!C.implanted)
|
|
continue
|
|
chemImplants.Add(list(list(
|
|
"host" = C.imp_in,
|
|
"units" = C.reagents.total_volume,
|
|
"ref" = "\ref[C]"
|
|
)))
|
|
for(var/obj/item/weapon/implant/tracking/track in all_tracking_implants)
|
|
var/turf/T = get_turf(track)
|
|
if(!T)
|
|
continue
|
|
if(!track.implanted)
|
|
continue
|
|
var/loc_display = "Unknown"
|
|
var/mob/living/L = track.imp_in
|
|
if((get_z(L) in using_map.station_levels) && !istype(L.loc, /turf/space))
|
|
loc_display = T.loc
|
|
if(track.malfunction)
|
|
loc_display = pick(teleportlocs)
|
|
trackImplants.Add(list(list(
|
|
"host" = L,
|
|
"ref" = "\ref[track]",
|
|
"id" = "[track.id]",
|
|
"loc" = "[loc_display]",
|
|
)))
|
|
|
|
return list("locked" = !screen, "chemImplants" = chemImplants, "trackImplants" = trackImplants)
|
|
|
|
|
|
/obj/machinery/computer/prisoner/tgui_act(action, list/params)
|
|
if(..())
|
|
return TRUE
|
|
switch(action)
|
|
if("inject")
|
|
var/obj/item/weapon/implant/I = locate(params["imp"])
|
|
if(I)
|
|
I.activate(clamp(params["val"], 0, 10))
|
|
. = TRUE
|
|
if("lock")
|
|
if(allowed(usr))
|
|
screen = !screen
|
|
else
|
|
to_chat(usr, "Unauthorized Access.")
|
|
. = TRUE
|
|
if("warn")
|
|
var/warning = sanitize(input(usr, "Message:", "Enter your message here!", ""))
|
|
if(!warning)
|
|
return
|
|
var/obj/item/weapon/implant/I = locate(params["imp"])
|
|
if(I && I.imp_in)
|
|
to_chat(I.imp_in, "<span class='notice'>You hear a voice in your head saying: '[warning]'</span>")
|
|
. = TRUE
|
|
add_fingerprint(usr) |