mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-20 15:12:57 +00:00
fdabe51ee8
* Adds linter defines to repo. * Uncomments linter defines already in the code. * Resolves unreachable code linter errors. * Nukes decade+ old syndie specops code except for computer since that's mapped in????? * Resolves procs has no parent linter error. * Proc signature fixes * Bad comments * "In" danger * Type safety * Implied nested list abuse * Top level ..() usage * Sleepy coder typos * Invalid kwargs calls * Pointless returns * Linter hacks (see full message) Byond doesn't care and it has no effect but linter doesn't like var/proc for holding references to procs, despite that it's valid byond code. Also, the linter seems to have serious issues figuring out relative proc names. This commit is a sort of take-it-or-leave-it thing. It's not required, it just cuts down on warnings, but this code is valid DM code. * WHATEVER THIS IS * Trick dreamchecker linter into ignoring this file's sins in it's weird use of vars * Fix list decoration syntax - Its a list, not list of lists - To declare that a var is a list you can `var/list/blah = list()` syntax or the `var/blah[0]` syntax. Both do exactly the same thing. But if you do `var/list/blah[0]` that is just like doing `var/list/list/blah = list()` * Hopefully stops the ai holder subtype folder from going quantum and sometimes changes capitalization over time, and incidentally causing 20+ linter errors. * Fixes unwrapped negated object in list linter error. * Resolves colon-like list accessing linter error. * Turns linter on in linter config. * Fixes closet indentation properly and cleans up suit storage unit switch. Co-authored-by: Aronai Sieyes <arokha@arokha.com> Co-authored-by: Leshana <Leshana@users.noreply.github.com>
92 lines
3.7 KiB
Plaintext
92 lines
3.7 KiB
Plaintext
/var/global/datum/topic_state/default/default_state = new()
|
|
|
|
/datum/topic_state/default/href_list(var/mob/user)
|
|
return list()
|
|
|
|
/datum/topic_state/default/can_use_topic(var/src_object, var/mob/user)
|
|
return user.default_can_use_topic(src_object)
|
|
|
|
/mob/proc/default_can_use_topic(var/src_object)
|
|
return STATUS_CLOSE // By default no mob can do anything with NanoUI
|
|
|
|
/mob/observer/dead/default_can_use_topic(var/src_object)
|
|
if(can_admin_interact())
|
|
return STATUS_INTERACTIVE // Admins are more equal
|
|
if(!client || get_dist(src_object, src) > client.view) // Preventing ghosts from having a million windows open by limiting to objects in range
|
|
return STATUS_CLOSE
|
|
return STATUS_UPDATE // Ghosts can view updates
|
|
|
|
/mob/living/silicon/pai/default_can_use_topic(var/src_object)
|
|
if((src_object == src || src_object == radio || src_object == communicator) && !stat)
|
|
return STATUS_INTERACTIVE
|
|
else
|
|
return ..()
|
|
|
|
/mob/living/silicon/robot/default_can_use_topic(var/src_object)
|
|
. = shared_nano_interaction()
|
|
if(. <= STATUS_DISABLED)
|
|
return
|
|
|
|
// robots can interact with things they can see within their view range
|
|
if((src_object in view(src)) && get_dist(src_object, src) <= src.client.view)
|
|
return STATUS_INTERACTIVE // interactive (green visibility)
|
|
return STATUS_DISABLED // no updates, completely disabled (red visibility)
|
|
|
|
/mob/living/silicon/ai/default_can_use_topic(var/src_object)
|
|
. = shared_nano_interaction()
|
|
if(. != STATUS_INTERACTIVE)
|
|
return
|
|
|
|
// Prevents the AI from using Topic on admin levels (by for example viewing through the court/thunderdome cameras)
|
|
// unless it's on the same level as the object it's interacting with.
|
|
var/turf/T = get_turf(src_object)
|
|
if(!T || !(z == T.z || (T.z in using_map.player_levels)))
|
|
return STATUS_CLOSE
|
|
|
|
// If an object is in view then we can interact with it
|
|
if(src_object in view(client.view, src))
|
|
return STATUS_INTERACTIVE
|
|
|
|
// If we're installed in a chassi, rather than transfered to an inteliCard or other container, then check if we have camera view
|
|
if(is_in_chassis())
|
|
//stop AIs from leaving windows open and using then after they lose vision
|
|
if(cameranet && !cameranet.checkTurfVis(get_turf(src_object)))
|
|
return STATUS_CLOSE
|
|
return STATUS_INTERACTIVE
|
|
else if(get_dist(src_object, src) <= client.view) // View does not return what one would expect while installed in an inteliCard
|
|
return STATUS_INTERACTIVE
|
|
|
|
return STATUS_CLOSE
|
|
|
|
//Some atoms such as vehicles might have special rules for how mobs inside them interact with NanoUI.
|
|
/atom/proc/contents_nano_distance(var/src_object, var/mob/living/user)
|
|
return user.shared_living_nano_distance(src_object)
|
|
|
|
/mob/living/proc/shared_living_nano_distance(var/atom/movable/src_object)
|
|
if (!(src_object in view(4, src))) // If the src object is not in visable, disable updates
|
|
return STATUS_CLOSE
|
|
|
|
var/dist = get_dist(src_object, src)
|
|
if (dist <= 1)
|
|
return STATUS_INTERACTIVE // interactive (green visibility)
|
|
else if (dist <= 2)
|
|
return STATUS_UPDATE // update only (orange visibility)
|
|
else if (dist <= 4)
|
|
return STATUS_DISABLED // no updates, completely disabled (red visibility)
|
|
return STATUS_CLOSE
|
|
|
|
/mob/living/default_can_use_topic(var/src_object)
|
|
. = shared_nano_interaction(src_object)
|
|
if(. != STATUS_CLOSE)
|
|
if(loc)
|
|
. = min(., loc.contents_nano_distance(src_object, src))
|
|
if(. == STATUS_INTERACTIVE)
|
|
return STATUS_UPDATE
|
|
|
|
/mob/living/carbon/human/default_can_use_topic(var/src_object)
|
|
. = shared_nano_interaction(src_object)
|
|
if(. != STATUS_CLOSE)
|
|
. = min(., shared_living_nano_distance(src_object))
|
|
if(. == STATUS_UPDATE && (TK in mutations)) // If we have telekinesis and remain close enough, allow interaction.
|
|
return STATUS_INTERACTIVE
|