mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2026-08-19 03:06:26 +01:00
fdabe51ee8
* Adds linter defines to repo. * Uncomments linter defines already in the code. * Resolves unreachable code linter errors. * Nukes decade+ old syndie specops code except for computer since that's mapped in????? * Resolves procs has no parent linter error. * Proc signature fixes * Bad comments * "In" danger * Type safety * Implied nested list abuse * Top level ..() usage * Sleepy coder typos * Invalid kwargs calls * Pointless returns * Linter hacks (see full message) Byond doesn't care and it has no effect but linter doesn't like var/proc for holding references to procs, despite that it's valid byond code. Also, the linter seems to have serious issues figuring out relative proc names. This commit is a sort of take-it-or-leave-it thing. It's not required, it just cuts down on warnings, but this code is valid DM code. * WHATEVER THIS IS * Trick dreamchecker linter into ignoring this file's sins in it's weird use of vars * Fix list decoration syntax - Its a list, not list of lists - To declare that a var is a list you can `var/list/blah = list()` syntax or the `var/blah[0]` syntax. Both do exactly the same thing. But if you do `var/list/blah[0]` that is just like doing `var/list/list/blah = list()` * Hopefully stops the ai holder subtype folder from going quantum and sometimes changes capitalization over time, and incidentally causing 20+ linter errors. * Fixes unwrapped negated object in list linter error. * Resolves colon-like list accessing linter error. * Turns linter on in linter config. * Fixes closet indentation properly and cleans up suit storage unit switch. Co-authored-by: Aronai Sieyes <arokha@arokha.com> Co-authored-by: Leshana <Leshana@users.noreply.github.com>
82 lines
2.3 KiB
Plaintext
82 lines
2.3 KiB
Plaintext
/**********************
|
|
* Category Collection *
|
|
**********************/
|
|
/datum/category_collection
|
|
var/category_group_type // Type of categories to initialize
|
|
var/list/datum/category_group/categories // List of initialized categories
|
|
var/list/datum/category_group/categories_by_name // Associative list of initialized categories, keyed by name
|
|
|
|
/datum/category_collection/New()
|
|
..()
|
|
categories = new()
|
|
categories_by_name = new()
|
|
for(var/category_type in typesof(category_group_type))
|
|
var/datum/category_group/category = category_type
|
|
if(initial(category.name))
|
|
category = new category(src)
|
|
categories += category
|
|
categories_by_name[category.name] = category
|
|
categories = dd_sortedObjectList(categories)
|
|
|
|
/datum/category_collection/Destroy()
|
|
for(var/category in categories)
|
|
qdel(category)
|
|
categories.Cut()
|
|
return ..()
|
|
|
|
/******************
|
|
* Category Groups *
|
|
******************/
|
|
/datum/category_group
|
|
var/name = ""
|
|
var/category_item_type // Type of items to initialize
|
|
var/list/datum/category_item/items // List of initialized items
|
|
var/list/datum/category_item/items_by_name // Associative list of initialized items, by name
|
|
var/datum/category_collection/collection // The collection this group belongs to
|
|
|
|
/datum/category_group/New(var/datum/category_collection/cc)
|
|
..()
|
|
collection = cc
|
|
items = new()
|
|
items_by_name = new()
|
|
|
|
for(var/item_type in typesof(category_item_type))
|
|
var/datum/category_item/item = item_type
|
|
if(initial(item.name))
|
|
item = new item(src)
|
|
items += item
|
|
items_by_name[item.name] = item
|
|
|
|
// For whatever reason dd_insertObjectList(items, item) doesn't insert in the correct order
|
|
// If you change this, confirm that character setup doesn't become completely unordered.
|
|
items = dd_sortedObjectList(items)
|
|
|
|
/datum/category_group/Destroy()
|
|
for(var/item in items)
|
|
qdel(item)
|
|
items.Cut()
|
|
collection = null
|
|
return ..()
|
|
|
|
datum/category_group/dd_SortValue()
|
|
return name
|
|
|
|
|
|
/*****************
|
|
* Category Items *
|
|
*****************/
|
|
/datum/category_item
|
|
var/name = ""
|
|
var/datum/category_group/category // The group this item belongs to
|
|
|
|
/datum/category_item/New(var/datum/category_group/cg)
|
|
..()
|
|
category = cg
|
|
|
|
/datum/category_item/Destroy()
|
|
category = null
|
|
return ..()
|
|
|
|
datum/category_item/dd_SortValue()
|
|
return name
|