mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-24 00:51:46 +00:00
b4ca6b11e1
* Added a proc to the map datum which returns what zlevels a nanomap capable computer should display. * Updated the atmos control, power monitoring, crew monitoring, and camera consoles to use it. * Changed templates to not show the map button if no map levels are available.
85 lines
3.1 KiB
Plaintext
85 lines
3.1 KiB
Plaintext
/datum/nano_module/atmos_control
|
|
name = "Atmospherics Control"
|
|
var/obj/access = new()
|
|
var/emagged = 0
|
|
var/ui_ref
|
|
var/list/monitored_alarms = list()
|
|
|
|
/datum/nano_module/atmos_control/New(atmos_computer, req_access, req_one_access, monitored_alarm_ids)
|
|
..()
|
|
access.req_access = req_access
|
|
access.req_one_access = req_one_access
|
|
|
|
if(monitored_alarm_ids)
|
|
for(var/obj/machinery/alarm/alarm in machines)
|
|
if(alarm.alarm_id && alarm.alarm_id in monitored_alarm_ids)
|
|
monitored_alarms += alarm
|
|
// machines may not yet be ordered at this point
|
|
monitored_alarms = dd_sortedObjectList(monitored_alarms)
|
|
|
|
/datum/nano_module/atmos_control/Topic(href, href_list)
|
|
if(..())
|
|
return 1
|
|
|
|
if(href_list["alarm"])
|
|
if(ui_ref)
|
|
var/obj/machinery/alarm/alarm = locate(href_list["alarm"]) in (monitored_alarms.len ? monitored_alarms : machines)
|
|
if(alarm)
|
|
var/datum/topic_state/TS = generate_state(alarm)
|
|
alarm.ui_interact(usr, master_ui = ui_ref, state = TS)
|
|
return 1
|
|
|
|
/datum/nano_module/atmos_control/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/master_ui = null, var/datum/topic_state/state = default_state)
|
|
var/data[0]
|
|
var/alarms[0]
|
|
var/turf/T = get_turf(nano_host())
|
|
|
|
// TODO: Move these to a cache, similar to cameras
|
|
for(var/obj/machinery/alarm/alarm in (monitored_alarms.len ? monitored_alarms : machines))
|
|
alarms[++alarms.len] = list(
|
|
"name" = sanitize(alarm.name),
|
|
"ref"= "\ref[alarm]",
|
|
"danger" = max(alarm.danger_level, alarm.alarm_area.atmosalm),
|
|
"x" = alarm.x,
|
|
"y" = alarm.y,
|
|
"z" = alarm.z)
|
|
data["alarms"] = alarms
|
|
data["map_levels"] = using_map.get_map_levels(T.z)
|
|
|
|
ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
|
|
if(!ui)
|
|
ui = new(user, src, ui_key, "atmos_control.tmpl", src.name, 625, 625, state = state)
|
|
// adding a template with the key "mapContent" enables the map ui functionality
|
|
ui.add_template("mapContent", "atmos_control_map_content.tmpl")
|
|
// adding a template with the key "mapHeader" replaces the map header content
|
|
ui.add_template("mapHeader", "atmos_control_map_header.tmpl")
|
|
ui.set_initial_data(data)
|
|
ui.open()
|
|
ui.set_auto_update(1)
|
|
ui_ref = ui
|
|
|
|
/datum/nano_module/atmos_control/proc/generate_state(air_alarm)
|
|
var/datum/topic_state/air_alarm/state = new()
|
|
state.atmos_control = src
|
|
state.air_alarm = air_alarm
|
|
return state
|
|
|
|
/datum/topic_state/air_alarm
|
|
var/datum/nano_module/atmos_control/atmos_control = null
|
|
var/obj/machinery/alarm/air_alarm = null
|
|
|
|
/datum/topic_state/air_alarm/can_use_topic(var/src_object, var/mob/user)
|
|
if(has_access(user))
|
|
return STATUS_INTERACTIVE
|
|
return STATUS_UPDATE
|
|
|
|
/datum/topic_state/air_alarm/href_list(var/mob/user)
|
|
var/list/extra_href = list()
|
|
extra_href["remote_connection"] = 1
|
|
extra_href["remote_access"] = has_access(user)
|
|
|
|
return extra_href
|
|
|
|
/datum/topic_state/air_alarm/proc/has_access(var/mob/user)
|
|
return user && (isAI(user) || atmos_control.access.allowed(user) || atmos_control.emagged || air_alarm.rcon_setting == RCON_YES || (air_alarm.alarm_area.atmosalm && air_alarm.rcon_setting == RCON_AUTO))
|