mirror of
https://github.com/PolarisSS13/Polaris.git
synced 2025-12-16 13:12:22 +00:00
fdabe51ee8
* Adds linter defines to repo. * Uncomments linter defines already in the code. * Resolves unreachable code linter errors. * Nukes decade+ old syndie specops code except for computer since that's mapped in????? * Resolves procs has no parent linter error. * Proc signature fixes * Bad comments * "In" danger * Type safety * Implied nested list abuse * Top level ..() usage * Sleepy coder typos * Invalid kwargs calls * Pointless returns * Linter hacks (see full message) Byond doesn't care and it has no effect but linter doesn't like var/proc for holding references to procs, despite that it's valid byond code. Also, the linter seems to have serious issues figuring out relative proc names. This commit is a sort of take-it-or-leave-it thing. It's not required, it just cuts down on warnings, but this code is valid DM code. * WHATEVER THIS IS * Trick dreamchecker linter into ignoring this file's sins in it's weird use of vars * Fix list decoration syntax - Its a list, not list of lists - To declare that a var is a list you can `var/list/blah = list()` syntax or the `var/blah[0]` syntax. Both do exactly the same thing. But if you do `var/list/blah[0]` that is just like doing `var/list/list/blah = list()` * Hopefully stops the ai holder subtype folder from going quantum and sometimes changes capitalization over time, and incidentally causing 20+ linter errors. * Fixes unwrapped negated object in list linter error. * Resolves colon-like list accessing linter error. * Turns linter on in linter config. * Fixes closet indentation properly and cleans up suit storage unit switch. Co-authored-by: Aronai Sieyes <arokha@arokha.com> Co-authored-by: Leshana <Leshana@users.noreply.github.com>
263 lines
7.3 KiB
Plaintext
263 lines
7.3 KiB
Plaintext
/*
|
|
Every cycle, the pump uses the air in air_in to try and make air_out the perfect pressure.
|
|
|
|
node1, air1, network1 correspond to input
|
|
node2, air2, network2 correspond to output
|
|
|
|
Thus, the two variables affect pump operation are set in New():
|
|
air1.volume
|
|
This is the volume of gas available to the pump that may be transfered to the output
|
|
air2.volume
|
|
Higher quantities of this cause more air to be perfected later
|
|
but overall network volume is also increased as this increases...
|
|
*/
|
|
|
|
/obj/machinery/atmospherics/binary/pump
|
|
icon = 'icons/atmos/pump.dmi'
|
|
icon_state = "map_off"
|
|
construction_type = /obj/item/pipe/directional
|
|
pipe_state = "pump"
|
|
level = 1
|
|
var/base_icon = "pump"
|
|
|
|
name = "gas pump"
|
|
desc = "A pump that moves gas from one place to another."
|
|
|
|
var/target_pressure = ONE_ATMOSPHERE
|
|
|
|
//var/max_volume_transfer = 10000
|
|
|
|
use_power = USE_POWER_OFF
|
|
idle_power_usage = 150 //internal circuitry, friction losses and stuff
|
|
power_rating = 7500 //7500 W ~ 10 HP
|
|
|
|
var/max_pressure_setting = 15000 //kPa
|
|
|
|
var/frequency = 0
|
|
var/id = null
|
|
var/datum/radio_frequency/radio_connection
|
|
|
|
/obj/machinery/atmospherics/binary/pump/New()
|
|
..()
|
|
air1.volume = ATMOS_DEFAULT_VOLUME_PUMP
|
|
air2.volume = ATMOS_DEFAULT_VOLUME_PUMP
|
|
|
|
/obj/machinery/atmospherics/binary/pump/Destroy()
|
|
unregister_radio(src, frequency)
|
|
. = ..()
|
|
|
|
/obj/machinery/atmospherics/binary/pump/on
|
|
icon_state = "map_on"
|
|
use_power = USE_POWER_IDLE
|
|
|
|
/obj/machinery/atmospherics/binary/pump/fuel
|
|
icon_state = "map_off-fuel"
|
|
base_icon = "pump-fuel"
|
|
icon_connect_type = "-fuel"
|
|
connect_types = CONNECT_TYPE_FUEL
|
|
|
|
/obj/machinery/atmospherics/binary/pump/fuel/on
|
|
icon_state = "map_on-fuel"
|
|
use_power = USE_POWER_IDLE
|
|
|
|
/obj/machinery/atmospherics/binary/pump/aux
|
|
icon_state = "map_off-aux"
|
|
base_icon = "pump-aux"
|
|
icon_connect_type = "-aux"
|
|
connect_types = CONNECT_TYPE_AUX
|
|
|
|
/obj/machinery/atmospherics/binary/pump/aux/on
|
|
icon_state = "map_on-aux"
|
|
use_power = USE_POWER_IDLE
|
|
|
|
/obj/machinery/atmospherics/binary/pump/update_icon()
|
|
if(!powered())
|
|
icon_state = "[base_icon]-off"
|
|
else
|
|
icon_state = "[use_power ? "[base_icon]-on" : "[base_icon]-off"]"
|
|
|
|
/obj/machinery/atmospherics/binary/pump/update_underlays()
|
|
if(..())
|
|
underlays.Cut()
|
|
var/turf/T = get_turf(src)
|
|
if(!istype(T))
|
|
return
|
|
add_underlay(T, node1, turn(dir, -180), node1?.icon_connect_type)
|
|
add_underlay(T, node2, dir, node2?.icon_connect_type)
|
|
|
|
/obj/machinery/atmospherics/binary/pump/hide(var/i)
|
|
update_underlays()
|
|
|
|
/obj/machinery/atmospherics/binary/pump/process()
|
|
last_power_draw = 0
|
|
last_flow_rate = 0
|
|
|
|
if((stat & (NOPOWER|BROKEN)) || !use_power)
|
|
return
|
|
|
|
var/power_draw = -1
|
|
var/pressure_delta = target_pressure - air2.return_pressure()
|
|
|
|
if(pressure_delta > 0.01 && air1.temperature > 0)
|
|
//Figure out how much gas to transfer to meet the target pressure.
|
|
var/transfer_moles = calculate_transfer_moles(air1, air2, pressure_delta, (network2)? network2.volume : 0)
|
|
power_draw = pump_gas(src, air1, air2, transfer_moles, power_rating)
|
|
|
|
if (power_draw >= 0)
|
|
last_power_draw = power_draw
|
|
use_power(power_draw)
|
|
|
|
if(network1)
|
|
network1.update = 1
|
|
|
|
if(network2)
|
|
network2.update = 1
|
|
|
|
return 1
|
|
|
|
//Radio remote control
|
|
|
|
/obj/machinery/atmospherics/binary/pump/proc/set_frequency(new_frequency)
|
|
radio_controller.remove_object(src, frequency)
|
|
frequency = new_frequency
|
|
if(frequency)
|
|
radio_connection = radio_controller.add_object(src, frequency, radio_filter = RADIO_ATMOSIA)
|
|
|
|
/obj/machinery/atmospherics/binary/pump/proc/broadcast_status()
|
|
if(!radio_connection)
|
|
return 0
|
|
|
|
var/datum/signal/signal = new
|
|
signal.transmission_method = TRANSMISSION_RADIO //radio signal
|
|
signal.source = src
|
|
|
|
signal.data = list(
|
|
"tag" = id,
|
|
"device" = "AGP",
|
|
"power" = use_power,
|
|
"target_output" = target_pressure,
|
|
"sigtype" = "status"
|
|
)
|
|
|
|
radio_connection.post_signal(src, signal, radio_filter = RADIO_ATMOSIA)
|
|
|
|
return 1
|
|
|
|
/obj/machinery/atmospherics/binary/pump/tgui_interact(mob/user, datum/tgui/ui)
|
|
if(stat & (BROKEN|NOPOWER))
|
|
return
|
|
ui = SStgui.try_update_ui(user, src, ui)
|
|
if(!ui)
|
|
ui = new(user, src, "GasPump", name)
|
|
ui.open()
|
|
|
|
/obj/machinery/atmospherics/binary/pump/tgui_data(mob/user)
|
|
// this is the data which will be sent to the ui
|
|
var/data[0]
|
|
|
|
data = list(
|
|
"on" = use_power,
|
|
"pressure_set" = round(target_pressure*100), //Nano UI can't handle rounded non-integers, apparently.
|
|
"max_pressure" = max_pressure_setting,
|
|
"last_flow_rate" = round(last_flow_rate*10),
|
|
"last_power_draw" = round(last_power_draw),
|
|
"max_power_draw" = power_rating,
|
|
)
|
|
|
|
return data
|
|
|
|
/obj/machinery/atmospherics/binary/pump/Initialize()
|
|
. = ..()
|
|
if(frequency)
|
|
set_frequency(frequency)
|
|
|
|
/obj/machinery/atmospherics/binary/pump/receive_signal(datum/signal/signal)
|
|
if(!signal.data["tag"] || (signal.data["tag"] != id) || (signal.data["sigtype"]!="command"))
|
|
return 0
|
|
|
|
if(signal.data["power"])
|
|
if(text2num(signal.data["power"]))
|
|
update_use_power(USE_POWER_IDLE)
|
|
else
|
|
update_use_power(USE_POWER_OFF)
|
|
|
|
if("power_toggle" in signal.data)
|
|
update_use_power(!use_power)
|
|
|
|
if(signal.data["set_output_pressure"])
|
|
target_pressure = between(
|
|
0,
|
|
text2num(signal.data["set_output_pressure"]),
|
|
ONE_ATMOSPHERE*50
|
|
)
|
|
|
|
if(signal.data["status"])
|
|
spawn(2)
|
|
broadcast_status()
|
|
return //do not update_icon
|
|
|
|
spawn(2)
|
|
broadcast_status()
|
|
update_icon()
|
|
return
|
|
|
|
/obj/machinery/atmospherics/binary/pump/attack_ghost(mob/user)
|
|
tgui_interact(user)
|
|
|
|
/obj/machinery/atmospherics/binary/pump/attack_hand(mob/user)
|
|
if(..())
|
|
return
|
|
add_fingerprint(usr)
|
|
if(!allowed(user))
|
|
to_chat(user, "<span class='warning'>Access denied.</span>")
|
|
return
|
|
tgui_interact(user)
|
|
|
|
/obj/machinery/atmospherics/binary/pump/tgui_act(action, params)
|
|
if(..())
|
|
return TRUE
|
|
|
|
switch(action)
|
|
if("power")
|
|
update_use_power(!use_power)
|
|
. = TRUE
|
|
if("set_press")
|
|
var/press = params["press"]
|
|
switch(press)
|
|
if("min")
|
|
target_pressure = 0
|
|
if("max")
|
|
target_pressure = max_pressure_setting
|
|
if("set")
|
|
var/new_pressure = input(usr,"Enter new output pressure (0-[max_pressure_setting]kPa)","Pressure control",src.target_pressure) as num
|
|
src.target_pressure = between(0, new_pressure, max_pressure_setting)
|
|
. = TRUE
|
|
|
|
add_fingerprint(usr)
|
|
update_icon()
|
|
|
|
/obj/machinery/atmospherics/binary/pump/power_change()
|
|
var/old_stat = stat
|
|
..()
|
|
if(old_stat != stat)
|
|
update_icon()
|
|
|
|
/obj/machinery/atmospherics/binary/pump/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
|
|
if (!W.is_wrench())
|
|
return ..()
|
|
if (!(stat & NOPOWER) && use_power)
|
|
to_chat(user, "<span class='warning'>You cannot unwrench this [src], turn it off first.</span>")
|
|
return 1
|
|
if(!can_unwrench())
|
|
to_chat(user, "<span class='warning'>You cannot unwrench this [src], it too exerted due to internal pressure.</span>")
|
|
add_fingerprint(user)
|
|
return 1
|
|
playsound(src, W.usesound, 50, 1)
|
|
to_chat(user, "<span class='notice'>You begin to unfasten \the [src]...</span>")
|
|
if (do_after(user, 40 * W.toolspeed))
|
|
user.visible_message( \
|
|
"<span class='notice'>\The [user] unfastens \the [src].</span>", \
|
|
"<span class='notice'>You have unfastened \the [src].</span>", \
|
|
"You hear ratchet.")
|
|
deconstruct()
|