Space update

code/modules/reagents/chemistry/reagents/other_reagents.dm

@@ -241,6 +241,43 @@
 	if(istype(data))
 		src.data |= data.Copy()
 
+/datum/reagent/corgium
+	name = "Corgium"
+	description = "A happy looking liquid that you feel compelled to consume if you want a better life."
+	color = "#ecca7f"
+	taste_description = "dog treats"
+	var/mob/living/simple_animal/pet/dog/corgi/new_corgi
+
+/datum/reagent/corgium/on_mob_metabolize(mob/living/L)
+	. = ..()
+	var/obj/shapeshift_holder/H = locate() in L
+	if(H)
+		to_chat(L, "<span class='warning'>You're already corgified!</span>")
+		return
+	new_corgi = new(L.loc)
+	//hat check
+	var/mob/living/carbon/C = L
+	if(istype(C))
+		var/obj/item/hat = C.get_item_by_slot(ITEM_SLOT_HEAD)
+		if(hat?.dog_fashion)
+			new_corgi.place_on_head(hat,null,FALSE)
+	H = new(new_corgi,src,L)
+	//Restore after this time
+	addtimer(CALLBACK(src, PROC_REF(restore), L), 5 * (volume / metabolization_rate))
+
+/datum/reagent/corgium/proc/restore(mob/living/L)
+	//The mob was qdeleted by an explosion or something
+	if(QDELETED(L))
+		return
+	//Remove all the corgium from the person
+	L.reagents?.remove_reagent(/datum/reagent/corgium, INFINITY)
+	if(QDELETED(new_corgi))
+		return
+	var/obj/shapeshift_holder/H = locate() in new_corgi
+	if(!H)
+		return
+	H.restore()
+
 /datum/reagent/water
 	name = "Water"
 	description = "An ubiquitous chemical substance that is composed of hydrogen and oxygen."