mirror of
https://github.com/SPLURT-Station/S.P.L.U.R.T-Station-13.git
synced 2025-12-10 09:54:52 +00:00
84 lines
2.4 KiB
Plaintext
84 lines
2.4 KiB
Plaintext
/mob/dead/observer/DblClickOn(var/atom/A, var/params)
|
|
if(can_reenter_corpse && mind && mind.current)
|
|
if(A == mind.current || (mind.current in A)) // double click your corpse or whatever holds it
|
|
reenter_corpse() // (cloning scanner, body bag, closet, mech, etc)
|
|
return // seems legit.
|
|
|
|
// Things you might plausibly want to follow
|
|
if(ismovable(A))
|
|
ManualFollow(A)
|
|
|
|
// Otherwise jump
|
|
else if(A.loc)
|
|
forceMove(get_turf(A))
|
|
update_parallax_contents()
|
|
|
|
/mob/dead/observer/ClickOn(var/atom/A, var/params)
|
|
if(check_click_intercept(params,A))
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(modifiers["shift"] && modifiers["middle"])
|
|
ShiftMiddleClickOn(A)
|
|
return
|
|
if(modifiers["shift"] && modifiers["ctrl"])
|
|
CtrlShiftClickOn(A)
|
|
return
|
|
if(modifiers["middle"])
|
|
MiddleClickOn(A)
|
|
return
|
|
if(modifiers["shift"])
|
|
ShiftClickOn(A)
|
|
return
|
|
if(modifiers["alt"])
|
|
altclick_listed_turf(A)
|
|
return
|
|
if(modifiers["ctrl"])
|
|
CtrlClickOn(A)
|
|
return
|
|
|
|
if(world.time <= next_move)
|
|
return
|
|
// You are responsible for checking config.ghost_interaction when you override this function
|
|
// Not all of them require checking, see below
|
|
A.attack_ghost(src)
|
|
|
|
// Oh by the way this didn't work with old click code which is why clicking shit didn't spam you
|
|
/atom/proc/attack_ghost(mob/dead/observer/user)
|
|
if(SEND_SIGNAL(src, COMSIG_ATOM_ATTACK_GHOST, user) & COMPONENT_NO_ATTACK_HAND)
|
|
return TRUE
|
|
if(user.client)
|
|
if(IsAdminGhost(user))
|
|
attack_ai(user)
|
|
else if(user.client.prefs.inquisitive_ghost)
|
|
user.examinate(src)
|
|
return FALSE
|
|
|
|
/mob/living/attack_ghost(mob/dead/observer/user)
|
|
if(user.client && user.health_scan)
|
|
healthscan(user, src, 1, TRUE)
|
|
return ..()
|
|
|
|
// ---------------------------------------
|
|
// And here are some good things for free:
|
|
// Now you can click through portals, wormholes, gateways, and teleporters while observing. -Sayu
|
|
|
|
/obj/machinery/gateway/centerstation/attack_ghost(mob/user)
|
|
if(awaygate)
|
|
user.forceMove(awaygate.loc)
|
|
else
|
|
to_chat(user, "[src] has no destination.")
|
|
return ..()
|
|
|
|
/obj/machinery/gateway/centeraway/attack_ghost(mob/user)
|
|
if(stationgate)
|
|
user.forceMove(stationgate.loc)
|
|
else
|
|
to_chat(user, "[src] has no destination.")
|
|
return ..()
|
|
|
|
/obj/machinery/teleport/hub/attack_ghost(mob/user)
|
|
if(power_station && power_station.engaged && power_station.teleporter_console && power_station.teleporter_console.target)
|
|
user.forceMove(get_turf(power_station.teleporter_console.target))
|
|
return ..()
|