mirror of
https://github.com/Skyrat-SS13/Skyrat-tg.git
synced 2026-08-22 04:18:46 +01:00
649fbfca43
* Removed tank dispenser UI (#84313) ## About The Pull Request Removed tank dispenser UI, making the tanks dispense on left and right clicks instead.  ## Why It's Good For The Game Less clicks. ## Changelog 🆑 del: Removed tank dispenser UI to use left/right clicks instead /🆑 --------- Co-authored-by: Afevis <ShizCalev@ users.noreply.github.com> * Removed tank dispenser UI --------- Co-authored-by: Andrew <mt.forspam@gmail.com> Co-authored-by: Afevis <ShizCalev@ users.noreply.github.com>
109 lines
3.0 KiB
Plaintext
109 lines
3.0 KiB
Plaintext
#define TANK_DISPENSER_CAPACITY 10
|
|
|
|
/obj/structure/tank_dispenser
|
|
name = "tank dispenser"
|
|
desc = "A simple yet bulky storage device for gas tanks."
|
|
icon = 'icons/obj/structures.dmi'
|
|
icon_state = "dispenser"
|
|
density = TRUE
|
|
anchored = TRUE
|
|
max_integrity = 300
|
|
var/oxygentanks = TANK_DISPENSER_CAPACITY
|
|
var/plasmatanks = TANK_DISPENSER_CAPACITY
|
|
|
|
/obj/structure/tank_dispenser/oxygen
|
|
plasmatanks = 0
|
|
|
|
/obj/structure/tank_dispenser/plasma
|
|
oxygentanks = 0
|
|
|
|
/obj/structure/tank_dispenser/Initialize(mapload)
|
|
. = ..()
|
|
AddElement(/datum/element/contextual_screentip_bare_hands, lmb_text = "Take Plasma Tank", rmb_text = "Take Oxygen Tank")
|
|
update_appearance()
|
|
|
|
/obj/structure/tank_dispenser/update_overlays()
|
|
. = ..()
|
|
switch(oxygentanks)
|
|
if(1 to 3)
|
|
. += "oxygen-[oxygentanks]"
|
|
if(4 to TANK_DISPENSER_CAPACITY)
|
|
. += "oxygen-4"
|
|
switch(plasmatanks)
|
|
if(1 to 4)
|
|
. += "plasma-[plasmatanks]"
|
|
if(5 to TANK_DISPENSER_CAPACITY)
|
|
. += "plasma-5"
|
|
|
|
/obj/structure/tank_dispenser/attack_hand(mob/living/user, list/modifiers)
|
|
. = ..()
|
|
if (!plasmatanks)
|
|
balloon_alert(user, "no plasma tanks!")
|
|
return
|
|
dispense(/obj/item/tank/internals/plasma, user)
|
|
plasmatanks--
|
|
update_appearance()
|
|
|
|
/obj/structure/tank_dispenser/attack_hand_secondary(mob/user, list/modifiers)
|
|
. = ..()
|
|
if (!oxygentanks)
|
|
balloon_alert(user, "no oxygen tanks!")
|
|
return SECONDARY_ATTACK_CANCEL_ATTACK_CHAIN
|
|
dispense(/obj/item/tank/internals/oxygen, user)
|
|
oxygentanks--
|
|
update_appearance()
|
|
return SECONDARY_ATTACK_CANCEL_ATTACK_CHAIN
|
|
|
|
/obj/structure/tank_dispenser/wrench_act(mob/living/user, obj/item/tool)
|
|
. = ..()
|
|
default_unfasten_wrench(user, tool)
|
|
return ITEM_INTERACT_SUCCESS
|
|
|
|
/obj/structure/tank_dispenser/attackby(obj/item/I, mob/living/user, params)
|
|
var/full
|
|
if(istype(I, /obj/item/tank/internals/plasma))
|
|
if(plasmatanks < TANK_DISPENSER_CAPACITY)
|
|
plasmatanks++
|
|
else
|
|
full = TRUE
|
|
else if(istype(I, /obj/item/tank/internals/oxygen))
|
|
if(oxygentanks < TANK_DISPENSER_CAPACITY)
|
|
oxygentanks++
|
|
else
|
|
full = TRUE
|
|
else if(!user.combat_mode)
|
|
balloon_alert(user, "can't insert!")
|
|
return
|
|
else
|
|
return ..()
|
|
if(full)
|
|
balloon_alert(user, "it is full!")
|
|
return
|
|
|
|
if(!user.transferItemToLoc(I, src))
|
|
return
|
|
balloon_alert(user, "tank inserted")
|
|
update_appearance()
|
|
|
|
/obj/structure/tank_dispenser/atom_deconstruct(disassembled = TRUE)
|
|
for(var/X in src)
|
|
var/obj/item/I = X
|
|
I.forceMove(loc)
|
|
new /obj/item/stack/sheet/iron (loc, 2)
|
|
|
|
/obj/structure/tank_dispenser/examine(mob/user)
|
|
. = ..()
|
|
if(plasmatanks && oxygentanks)
|
|
. += span_notice("It has <b>[plasmatanks]</b> plasma tank\s and <b>[oxygentanks]</b> oxygen tank\s left.")
|
|
else if(plasmatanks || oxygentanks)
|
|
. += span_notice("It has <b>[plasmatanks ? "[plasmatanks]</b> plasma" : "[oxygentanks]</b> oxygen"] tank\s left.")
|
|
|
|
/obj/structure/tank_dispenser/proc/dispense(tank_type, mob/receiver)
|
|
var/existing_tank = locate(tank_type) in src
|
|
if (isnull(existing_tank))
|
|
existing_tank = new tank_type
|
|
receiver.put_in_hands(existing_tank)
|
|
balloon_alert(receiver, "tank received")
|
|
|
|
#undef TANK_DISPENSER_CAPACITY
|