Adds selectable default languages to all mobs which can speak

Set-Default-Language verb to set, Check-Default-Language verb to check
There are also links to set and reset in Check-Known-Languages

code/modules/mob/language/language.dm

@@ -134,6 +134,12 @@
 	. = (L in languages)
 	languages.Remove(L)
 
+/mob/living/remove_language(rem_language)
+	var/datum/language/L = all_languages[rem_language]
+	if(default_language == L)
+		default_language = null
+	return ..()
+
 // Can we speak this language, as opposed to just understanding it?
 /mob/proc/can_speak(datum/language/speaking)
 
@@ -154,4 +160,32 @@
 	src << browse(dat, "window=checklanguage")
 	return
 
+/mob/living/check_languages()
+	var/dat = "<b><font size = 5>Known Languages</font></b><br/><br/>"
+
+	if(default_language)
+		dat += "Current default language: [default_language] - <a href='byond://?src=\ref[src];default_lang=reset'>reset</a><br/><br/>"
+
+	for(var/datum/language/L in languages)
+		if(!(L.flags & NONGLOBAL))
+			if(L == default_language)
+				dat += "<b>[L.name] (:[L.key])</b> - default - <a href='byond://?src=\ref[src];default_lang=reset'>reset</a><br/>[L.desc]<br/><br/>"
+			else
+				dat += "<b>[L.name] (:[L.key])</b> - <a href='byond://?src=\ref[src];default_lang=[L]'>set default</a><br/>[L.desc]<br/><br/>"
+
+	src << browse(dat, "window=checklanguage")
+
+/mob/living/Topic(href, href_list)
+	if(href_list["default_lang"])
+		if(href_list["default_lang"] == "reset")
+			set_default_language(null)
+		else
+			var/datum/language/L = all_languages[href_list["default_lang"]]
+			if(L)
+				set_default_language(L)
+		check_languages()
+		return 1
+	else
+		return ..()
+
 #undef SCRAMBLE_CACHE_LEN

code/modules/mob/living/carbon/carbon.dm

@@ -456,6 +456,9 @@
 	return 1
 
 /mob/living/carbon/get_default_language()
+	if(default_language)
+		return default_language
+
 	if(!species)
 		return null
 	return species.default_language ? all_languages[species.default_language] : null

code/modules/mob/living/default_language.dm

@@ -0,0 +1,25 @@
+/mob/living
+	var/datum/language/default_language
+
+/mob/living/verb/set_default_language(language as null|anything in languages)
+	set name = "Set Default Language"
+	set category = "IC"
+
+	if(language)
+		src << "<span class='notice'>You will now speak [language] if you do not specify a language when speaking.</span>"
+	else
+		src << "<span class='notice'>You will now speak whatever your standard default language is if you do not specify one when speaking.</span>"
+	default_language = language
+
+// Silicons can't neccessarily speak everything in their languages list
+/mob/living/silicon/set_default_language(language as null|anything in speech_synthesizer_langs)
+	..()
+
+/mob/living/verb/check_default_language()
+	set name = "Check Default Language"
+	set category = "IC"
+
+	if(default_language)
+		src << "<span class='notice'>You are currently speaking [default_language] by default.</span>"
+	else
+		src << "<span class='notice'>Your current default language is your species or mob type default.</span>"

code/modules/mob/living/say.dm

@@ -80,7 +80,7 @@ proc/get_radio_key_from_channel(var/channel)
 		if(dongle.translate_binary) return 1
 
 /mob/living/proc/get_default_language()
-	return null
+	return default_language
 
 /mob/living/proc/handle_speech_problems(var/message, var/verb)
 	var/list/returns[3]

code/modules/mob/living/silicon/silicon.dm

@@ -210,9 +210,19 @@
 
 	var/dat = "<b><font size = 5>Known Languages</font></b><br/><br/>"
 
+	if(default_language)
+		dat += "Current default language: [default_language] - <a href='byond://?src=\ref[src];default_lang=reset'>reset</a><br/><br/>"
+
 	for(var/datum/language/L in languages)
 		if(!(L.flags & NONGLOBAL))
-			dat += "<b>[L.name] (:[L.key])</b><br/>Speech Synthesizer: <i>[(L in speech_synthesizer_langs)? "YES":"NOT SUPPORTED"]</i><br/>[L.desc]<br/><br/>"
+			var/default_str
+			if(L == default_language)
+				default_str = " - default - <a href='byond://?src=\ref[src];default_lang=reset'>reset</a>"
+			else
+				default_str = " - <a href='byond://?src=\ref[src];default_lang=[L]'>set default</a>"
+
+			var/synth = (L in speech_synthesizer_langs)
+			dat += "<b>[L.name] (:[L.key])</b>[synth ? default_str : null]<br/>Speech Synthesizer: <i>[synth ? "YES" : "NOT SUPPORTED"]</i><br/>[L.desc]<br/><br/>"
 
 	src << browse(dat, "window=checklanguage")
 	return