Ports GinjaNinja32's drinks rewrite from Bay

code/modules/reagents/Chemistry-Machinery.dm

@@ -349,7 +349,7 @@
 			return
 
 	if (istype(O,/obj/item/weapon/reagent_containers/glass) || \
-		istype(O,/obj/item/weapon/reagent_containers/food/drinks/drinkingglass) || \
+		istype(O,/obj/item/weapon/reagent_containers/food/drinks/glass2) || \
 		istype(O,/obj/item/weapon/reagent_containers/food/drinks/shaker))
 
 		if (beaker)

code/modules/reagents/Chemistry-Reagents.dm

@@ -26,17 +26,19 @@
 	var/overdose = 0
 	var/scannable = 0 // Shows up on health analyzers.
 	var/affects_dead = 0
-	var/glass_icon_state = null
-	var/glass_name = null
-	var/glass_desc = null
-	var/glass_center_of_mass = null
 	var/cup_icon_state = null
 	var/cup_name = null
 	var/cup_desc = null
 	var/cup_center_of_mass = null
+
 	var/color = "#000000"
 	var/color_weight = 1
 
+	var/glass_icon = DRINK_ICON_DEFAULT
+	var/glass_name = "something"
+	var/glass_desc = "It's a glass of... what, exactly?"
+	var/list/glass_special = null // null equivalent to list()
+
 /datum/reagent/proc/remove_self(var/amount) // Shortcut
 	holder.remove_reagent(id, amount)
 

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Core.dm

@@ -6,8 +6,7 @@
 	metabolism = REM * 5
 	color = "#C80000"
 
-	glass_icon_state = "glass_red"
-	glass_name = "glass of tomato juice"
+	glass_name = "tomato juice"
 	glass_desc = "Are you sure this is tomato juice?"
 
 /datum/reagent/blood/initialize_data(var/newdata)
@@ -91,8 +90,7 @@
 	color = "#0064C877"
 	metabolism = REM * 10
 
-	glass_icon_state = "glass_clear"
-	glass_name = "glass of water"
+	glass_name = "water"
 	glass_desc = "The father of all refreshments."
 
 /datum/reagent/water/touch_turf(var/turf/simulated/T)
@@ -154,8 +152,7 @@
 	reagent_state = LIQUID
 	color = "#660000"
 
-	glass_icon_state = "dr_gibb_glass"
-	glass_name = "glass of welder fuel"
+	glass_name = "welder fuel"
 	glass_desc = "Unless you are an industrial tool, this is probably not safe for consumption."
 
 /datum/reagent/fuel/touch_turf(var/turf/T)

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Dispenser.dm

@@ -66,8 +66,7 @@
 	var/targ_temp = 310
 	var/halluci = 0
 
-	glass_icon_state = "glass_clear"
-	glass_name = "glass of ethanol"
+	glass_name = "ethanol"
 	glass_desc = "A well-known alcohol with a variety of applications."
 
 /datum/reagent/ethanol/touch_mob(var/mob/living/L, var/amount)
@@ -368,9 +367,10 @@
 	description = "The organic compound commonly known as table sugar and sometimes called saccharose. This white, odorless, crystalline powder has a pleasing, sweet taste."
 	reagent_state = SOLID
 	color = "#FFFFFF"
-	glass_icon_state = "iceglass"
-	glass_name = "glass of sugar"
+
+	glass_name = "sugar"
 	glass_desc = "The organic compound commonly known as table sugar and sometimes called saccharose. This white, odorless, crystalline powder has a pleasing, sweet taste."
+	glass_icon = DRINK_ICON_NOISY
 
 /datum/reagent/sugar/affect_blood(var/mob/living/carbon/M, var/alien, var/removed)
 	M.nutrition += removed * 3

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Other.dm

@@ -112,8 +112,7 @@
 	color = "#C8A5DC"
 	affects_dead = 1 //This can even heal dead people.
 
-	glass_icon_state = "golden_cup"
-	glass_name = "golden cup"
+	glass_name = "liquid gold"
 	glass_desc = "It's magic. We don't have to explain it."
 
 /datum/reagent/adminordrazine/affect_touch(var/mob/living/carbon/M, var/alien, var/removed)
@@ -197,8 +196,7 @@
 	description = "An ashen-obsidian-water mix, this solution will alter certain sections of the brain's rationality."
 	color = "#E0E8EF"
 
-	glass_icon_state = "glass_clear"
-	glass_name = "glass of holy water"
+	glass_name = "holy water"
 	glass_desc = "An ashen-obsidian-water mix, this solution will alter certain sections of the brain's rationality."
 
 /datum/reagent/water/holywater/affect_ingest(var/mob/living/carbon/M, var/alien, var/removed)

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Toxins.dm

@@ -331,13 +331,10 @@
 	id = "beer2"
 	description = "An alcoholic beverage made from malted grains, hops, yeast, and water. The fermentation appears to be incomplete." //If the players manage to analyze this, they deserve to know something is wrong.
 	reagent_state = LIQUID
-	color = "#664300"
+	color = "#FFD300"
 
-	glass_icon_state = "beerglass"
-	glass_name = "glass of beer"
+	glass_name = "beer"
 	glass_desc = "A freezing pint of beer"
-	glass_center_of_mass = list("x"=16, "y"=8)
-
 /* Drugs */
 
 /datum/reagent/space_drugs

code/modules/reagents/reagent_containers/drinkingglass/drinkingglass.dm

@@ -0,0 +1,145 @@
+#define DRINK_ICON_FILE 'icons/pdrink.dmi'
+
+/var/const/DRINK_FIZZ = "fizz"
+/var/const/DRINK_ICE = "ice"
+/var/const/DRINK_ICON_DEFAULT = ""
+/var/const/DRINK_ICON_NOISY = "_noise"
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2
+	name = "glass" // Name when empty
+	var/base_name = "glass" // Name to put in front of drinks, i.e. "[base_name] of [contents]"
+	desc = "A generic drinking glass." // Description when empty
+	icon = DRINK_ICON_FILE
+	var/base_icon = "square" // Base icon name
+	volume = 30
+
+	var/list/filling_states // List of percentages full that have icons
+
+	var/list/extras = list() // List of extras. Two extras maximum
+
+	var/rim_pos
+
+	center_of_mass = list("x"=16, "y"=10)
+
+	amount_per_transfer_from_this = 5
+	possible_transfer_amounts = list(5,10,15,30)
+	flags = OPENCONTAINER
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/examine(mob/M as mob)
+	..()
+
+	for(var/I in extras)
+		if(istype(I, /obj/item/weapon/glass_extra))
+			M << "There is \a [I] in \the [src]."
+		else if(istype(I, /obj/item/weapon/reagent_containers/food/snacks/fruit_slice))
+			M << "There is \a [I] on the rim."
+		else
+			M << "There is \a [I] somewhere on the glass. Somehow."
+
+	if(has_ice())
+		M << "There is some ice floating in the drink."
+
+	if(has_fizz())
+		M << "It is fizzing slightly."
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/proc/has_ice()
+	if(reagents.reagent_list.len > 0)
+		var/datum/reagent/R = reagents.get_master_reagent()
+		if(!((R.id == "ice") || ("ice" in R.glass_special))) // if it's not a cup of ice, and it's not already supposed to have ice in, see if the bartender's put ice in it
+			if(reagents.has_reagent("ice", reagents.total_volume / 10)) // 10% ice by volume
+				return 1
+
+	return 0
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/proc/has_fizz()
+	if(reagents.reagent_list.len > 0)
+		var/datum/reagent/R = reagents.get_master_reagent()
+		if(!("fizz" in R.glass_special))
+			var/totalfizzy = 0
+			for(var/datum/reagent/re in reagents.reagent_list)
+				if("fizz" in re.glass_special)
+					totalfizzy += re.volume
+			if(totalfizzy >= reagents.total_volume / 5) // 20% fizzy by volume
+				return 1
+	return 0
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/New()
+	..()
+	icon_state = base_icon
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/on_reagent_change()
+	update_icon()
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/proc/can_add_extra(obj/item/weapon/glass_extra/GE)
+	if(!("[base_icon]_[GE.glass_addition]left" in icon_states(DRINK_ICON_FILE)))
+		return 0
+	if(!("[base_icon]_[GE.glass_addition]right" in icon_states(DRINK_ICON_FILE)))
+		return 0
+
+	return 1
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/update_icon()
+	underlays.Cut()
+
+	if (reagents.reagent_list.len > 0)
+		var/datum/reagent/R = reagents.get_master_reagent()
+		name = "[base_name] of [R.glass_name ? R.glass_name : "something"]"
+		desc = R.glass_desc ? R.glass_desc : initial(desc)
+
+		var/list/under_liquid = list()
+		var/list/over_liquid = list()
+
+		var/amnt = 100
+		var/percent = round((reagents.total_volume / volume) * 100)
+		for(var/k in filling_states)
+			if(percent <= k)
+				amnt = k
+				break
+
+		if(has_ice())
+			over_liquid |= "[base_icon][amnt]_ice"
+
+		if(has_fizz())
+			over_liquid |= "[base_icon][amnt]_fizz"
+
+		for(var/S in R.glass_special)
+			if("[base_icon]_[S]" in icon_states(DRINK_ICON_FILE))
+				under_liquid |= "[base_icon]_[S]"
+			else if("[base_icon][amnt]_[S]" in icon_states(DRINK_ICON_FILE))
+				over_liquid |= "[base_icon][amnt]_[S]"
+
+		for(var/k in under_liquid)
+			underlays += image(DRINK_ICON_FILE, src, k, -3)
+
+		var/image/filling = image(DRINK_ICON_FILE, src, "[base_icon][amnt][R.glass_icon]", -2)
+		filling.color = reagents.get_color()
+		underlays += filling
+
+		for(var/k in over_liquid)
+			underlays += image(DRINK_ICON_FILE, src, k, -1)
+	else
+		name = initial(name)
+		desc = initial(desc)
+
+	var/side = "left"
+	for(var/item in extras)
+		if(istype(item, /obj/item/weapon/glass_extra))
+			var/obj/item/weapon/glass_extra/GE = item
+			var/image/I = image(DRINK_ICON_FILE, src, "[base_icon]_[GE.glass_addition][side]")
+			if(GE.glass_color)
+				I.color = GE.glass_color
+			underlays += I
+		else if(istype(item, /obj/item/weapon/reagent_containers/food/snacks/fruit_slice))
+			var/obj/FS = item
+			var/image/I = image(FS)
+
+			var/fsy = rim_pos[1] - 20
+			var/fsx = rim_pos[side == "left" ? 2 : 3] - 16
+
+			var/matrix/M = matrix()
+			M.Scale(0.5)
+			M.Translate(fsx, fsy)
+			I.transform = M
+			underlays += I
+		else continue
+		side = "right"

code/modules/reagents/reagent_containers/drinkingglass/extras.dm

@@ -0,0 +1,69 @@
+/obj/item/weapon/reagent_containers/food/drinks/glass2/attackby(obj/item/I as obj, mob/user as mob)
+	if(extras.len >= 2) return ..() // max 2 extras, one on each side of the drink
+
+	if(istype(I, /obj/item/weapon/glass_extra))
+		var/obj/item/weapon/glass_extra/GE = I
+		if(can_add_extra(GE))
+			extras += GE
+			user.remove_from_mob(GE)
+			GE.loc = src
+			user << "<span class=notice>You add \the [GE] to \the [src].</span>"
+			update_icon()
+		else
+			user << "<span class=warning>There's no space to put \the [GE] on \the [src]!</span>"
+	else if(istype(I, /obj/item/weapon/reagent_containers/food/snacks/fruit_slice))
+		var/obj/item/weapon/reagent_containers/food/snacks/fruit_slice/FS = I
+		extras += FS
+		user.remove_from_mob(FS)
+		FS.pixel_x = 0 // Reset its pixel offsets so the icons work!
+		FS.pixel_y = 0
+		FS.loc = src
+		user << "<span class=notice>You add \the [FS] to \the [src].</span>"
+		update_icon()
+	else
+		return ..()
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/attack_hand(mob/user as mob)
+	if(src != user.get_inactive_hand())
+		return ..()
+
+	if(!extras.len)
+		user << "<span class=warning>There's nothing on the glass to remove!</span>"
+		return
+
+	var/choice = input(user, "What would you like to remove from the glass?") as null|anything in extras
+	if(!choice || !(choice in extras))
+		return
+
+	if(user.put_in_active_hand(choice))
+		user << "<span class=notice>You remove \the [choice] from \the [src].</span>"
+		extras -= choice
+	else
+		user << "<span class=warning>Something went wrong, please try again.</span>"
+
+	update_icon()
+
+/obj/item/weapon/glass_extra
+	name = "generic glass addition"
+	desc = "This goes on a glass."
+	var/glass_addition
+	var/glass_desc
+	var/glass_color
+	w_class = 1
+	icon = DRINK_ICON_FILE
+
+/obj/item/weapon/glass_extra/stick
+	name = "stick"
+	desc = "This goes in a glass."
+	glass_addition = "stick"
+	glass_desc = "There is a stick in the glass."
+	icon_state = "stick"
+
+/obj/item/weapon/glass_extra/straw
+	name = "straw"
+	desc = "This goes in a glass."
+	glass_addition = "straw"
+	glass_desc = "There is a straw in the glass."
+	icon_state = "straw"
+
+#undef DRINK_ICON_FILE

code/modules/reagents/reagent_containers/drinkingglass/glass_boxes.dm

@@ -0,0 +1,75 @@
+/obj/item/weapon/storage/box/mixedglasses
+	name = "glassware box"
+	desc = "A box of assorted glassware"
+	can_hold = list(/obj/item/weapon/reagent_containers/food/drinks/glass2)
+	New()
+		..()
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/square(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/rocks(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/shake(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/cocktail(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/shot(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/pint(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/mug(src)
+		new /obj/item/weapon/reagent_containers/food/drinks/glass2/wine(src)
+
+/obj/item/weapon/storage/box/glasses
+	name = "box of glasses"
+	var/glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2
+	can_hold = list(/obj/item/weapon/reagent_containers/food/drinks/glass2)
+	New()
+		..()
+
+		for(var/i = 1 to 7)
+			new glass_type(src)
+
+/obj/item/weapon/storage/box/glasses/square
+	name = "box of half-pint glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/square
+
+/obj/item/weapon/storage/box/glasses/rocks
+	name = "box of rocks glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/rocks
+
+/obj/item/weapon/storage/box/glasses/shake
+	name = "box of milkshake glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/shake
+
+/obj/item/weapon/storage/box/glasses/cocktail
+	name = "box of cocktail glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/cocktail
+
+/obj/item/weapon/storage/box/glasses/shot
+	name = "box of shot glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/shot
+
+/obj/item/weapon/storage/box/glasses/pint
+	name = "box of pint glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/pint
+
+/obj/item/weapon/storage/box/glasses/mug
+	name = "box of glass mugs"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/mug
+
+/obj/item/weapon/storage/box/glasses/wine
+	name = "box of wine glasses"
+	glass_type = /obj/item/weapon/reagent_containers/food/drinks/glass2/wine
+
+/obj/item/weapon/storage/box/glass_extras
+	name = "box of cocktail garnishings"
+	var/extra_type = /obj/item/weapon/glass_extra
+	can_hold = list(/obj/item/weapon/glass_extra)
+	storage_slots = 14
+	New()
+		..()
+
+		for(var/i = 1 to 14)
+			new extra_type(src)
+
+/obj/item/weapon/storage/box/glass_extras/straws
+	name = "box of straws"
+	extra_type = /obj/item/weapon/glass_extra/straw
+
+/obj/item/weapon/storage/box/glass_extras/sticks
+	name = "box of drink sticks"
+	extra_type = /obj/item/weapon/glass_extra/stick

code/modules/reagents/reagent_containers/drinkingglass/glass_types.dm

@@ -0,0 +1,72 @@
+/obj/item/weapon/reagent_containers/food/drinks/glass2/square
+	name = "half-pint glass"
+	base_name = "glass"
+	base_icon = "square"
+	desc = "Your standard drinking glass."
+	filling_states = list(20, 40, 60, 80, 100)
+	volume = 30
+	possible_transfer_amounts = list(5,10,15,30)
+	rim_pos = list(23,13,20) // y, x0, x1
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/rocks
+	name = "rocks glass"
+	base_name = "glass"
+	base_icon = "rocks"
+	filling_states = list(25, 50, 75, 100)
+	volume = 20
+	possible_transfer_amounts = list(5,10,20)
+	rim_pos = list(21, 10, 23)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/shake
+	name = "milkshake glass"
+	base_name = "glass"
+	base_icon = "shake"
+	filling_states = list(25, 50, 75, 100)
+	volume = 30
+	possible_transfer_amounts = list(5,10,15,30)
+	rim_pos = list(25, 13, 21)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/cocktail
+	name = "cocktail glass"
+	base_name = "glass"
+	base_icon = "cocktail"
+	filling_states = list(33, 66, 100)
+	volume = 15
+	possible_transfer_amounts = list(5,10,15)
+	rim_pos = list(22, 13, 21)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/shot
+	name = "shot glass"
+	base_name = "shot"
+	base_icon = "shot"
+	filling_states = list(33, 66, 100)
+	volume = 5
+	possible_transfer_amounts = list(1,2,5)
+	rim_pos = list(17, 13, 21)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/pint
+	name = "pint glass"
+	base_name = "pint"
+	base_icon = "pint"
+	filling_states = list(16, 33, 50, 66, 83, 100)
+	volume = 60
+	possible_transfer_amounts = list(5,10,15,30,60)
+	rim_pos = list(25, 12, 21)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/mug
+	name = "glass mug"
+	base_name = "mug"
+	base_icon = "mug"
+	filling_states = list(25, 50, 75, 100)
+	volume = 40
+	possible_transfer_amounts = list(5,10,20,40)
+	rim_pos = list(22, 12, 20)
+
+/obj/item/weapon/reagent_containers/food/drinks/glass2/wine
+	name = "wine glass"
+	base_name = "glass"
+	base_icon = "wine"
+	filling_states = list(20, 40, 60, 80, 100)
+	volume = 25
+	possible_transfer_amounts = list(5, 10, 15, 25)
+	rim_pos = list(25, 12, 21)

code/modules/reagents/reagent_containers/food/drinks/cup.dm

@@ -0,0 +1,43 @@
+/obj/item/weapon/reagent_containers/food/drinks/cup
+	name = "coffee cup"
+	desc = "The container of oriental luxuries."
+	icon_state = "cup_empty"
+	amount_per_transfer_from_this = 5
+	volume = 30
+	center_of_mass = list("x"=16, "y"=16)
+
+	on_reagent_change()
+		if (reagents.reagent_list.len > 0)
+			var/datum/reagent/R = reagents.get_master_reagent()
+
+			if(R.cup_icon_state)
+				icon_state = R.cup_icon_state
+			else
+				icon_state = "cup_brown"
+
+			if(R.cup_name)
+				name = R.cup_name
+			else
+				name = "Cup of.. what?"
+
+			if(R.cup_desc)
+				desc = R.cup_desc
+			else
+				desc = "You can't really tell what this is."
+
+			if(R.cup_center_of_mass)
+				center_of_mass = R.cup_center_of_mass
+			else
+				center_of_mass = list("x"=16, "y"=16)
+
+			if(R.price_tag)
+				price_tag = R.price_tag
+			else
+				price_tag = null
+
+		else
+			icon_state = "cup_empty"
+			name = "coffee cup"
+			desc = "The container of oriental luxuries."
+			center_of_mass = list("x"=16, "y"=16)
+			return