Refactors NanoUI interaction (again)

Takes NanoUI interaction code and splits it into more manageable modules.

The default handler that checks distances, camera coverage, etc., etc.
Admin NanoUI windows now only check for admin rights, ignoring sight, distance, and anything else.
ERT/mercenary appearance changer now remains open for as long as the mob remains on the admin Z-level.
PDAs and uplinks now require that you keep the item somewhere in your main inventory (or contents to be precise). Hands or ears are fine, inside bags are not.
Rig suits also check that they are in the operator's inventory or that the synthetic operator is somewhere within the suit's contents (recursively).

code/modules/admin/admin_verbs.dm

@@ -724,7 +724,8 @@ var/list/admin_verbs_mentor = list(
 		return
 
 	if(holder)
-		S.subsystem_law_manager()
+		var/obj/nano_module/law_manager/L = new(S)
+		L.ui_interact(usr, state = admin_state)
 	admin_log_and_message_admins("has opened [S]'s law manager.")
 	feedback_add_details("admin_verb","MSL") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
 
@@ -738,7 +739,7 @@ var/list/admin_verbs_mentor = list(
 
 	if(holder)
 		admin_log_and_message_admins("is altering the appearance of [H].")
-		H.change_appearance(APPEARANCE_ALL, usr, usr, check_species_whitelist = 0)
+		H.change_appearance(APPEARANCE_ALL, usr, usr, check_species_whitelist = 0, state = admin_state)
 	feedback_add_details("admin_verb","CHAA") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
 
 /client/proc/change_human_appearance_self(mob/living/carbon/human/H in mob_list)

code/modules/clothing/spacesuits/rig/rig.dm

@@ -459,7 +459,7 @@
 
 	ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
 	if (!ui)
-		ui = new(user, src, ui_key, ((src.loc != user) ? ai_interface_path : interface_path), interface_title, 480, 550)
+		ui = new(user, src, ui_key, ((src.loc != user) ? ai_interface_path : interface_path), interface_title, 480, 550, data["ai"] ? contained_state : inventory_state)
 		ui.set_initial_data(data)
 		ui.open()
 		ui.set_auto_update(1)

code/modules/mob/living/carbon/human/appearance.dm

@@ -1,7 +1,7 @@
-/mob/living/carbon/human/proc/change_appearance(var/flags = APPEARANCE_ALL_HAIR, var/location = src, var/mob/user = src, var/check_species_whitelist = 1, var/list/species_whitelist = list(), var/list/species_blacklist = list())
+/mob/living/carbon/human/proc/change_appearance(var/flags = APPEARANCE_ALL_HAIR, var/location = src, var/mob/user = src, var/check_species_whitelist = 1, var/list/species_whitelist = list(), var/list/species_blacklist = list(), var/datum/topic_state/state = default_state)
 	var/obj/nano_module/appearance_changer/AC = new(location, src, check_species_whitelist, species_whitelist, species_blacklist)
 	AC.flags = flags
-	AC.ui_interact(user)
+	AC.ui_interact(user, state = state)
 
 /mob/living/carbon/human/proc/change_species(var/new_species)
 	if(!new_species)

code/modules/nano/interaction/admin.dm

@@ -0,0 +1,7 @@
+/*
+	This state checks that the user is an admin, end of story
+*/
+/var/global/datum/topic_state/admin_state/admin_state = new()
+
+/datum/topic_state/admin_state/can_use_topic(var/src_object, var/mob/user)
+	return check_rights(R_ADMIN, 0, user) ? STATUS_INTERACTIVE : STATUS_CLOSE

code/modules/nano/interaction/base.dm

@@ -0,0 +1,19 @@
+/atom/proc/nano_host()
+	return src
+
+/atom/proc/CanUseTopic(var/mob/user, var/datum/topic_state/state)
+	var/src_object = nano_host()
+	return state.can_use_topic(src_object, user)
+
+/datum/topic_state/proc/href_list(var/mob/user)
+	return list()
+
+/datum/topic_state/proc/can_use_topic(var/src_object, var/mob/user)
+	return STATUS_INTERACTIVE
+
+/mob/proc/shared_nano_interaction()
+	if (src.stat || !client)
+		return STATUS_CLOSE						// no updates, close the interface
+	else if (restrained() || lying || stat || stunned || weakened)
+		return STATUS_UPDATE					// update only (orange visibility)
+	return STATUS_INTERACTIVE

code/modules/nano/interaction/contained.dm

@@ -0,0 +1,18 @@
+/*
+	This state checks if user is somewhere within src_object, as well as the default NanoUI interaction.
+*/
+/var/global/datum/topic_state/contained_state/contained_state = new()
+
+/datum/topic_state/contained_state/can_use_topic(var/atom/src_object, var/mob/user)
+	if(!src_object.contains(src))
+		return STATUS_CLOSE
+
+	return user.shared_nano_interaction()
+
+/atom/proc/contains(var/atom/location)
+	if(!location)
+		return 0
+	if(location == src)
+		return 1
+
+	return contains(location.loc)

code/modules/nano/interaction/default.dm

@@ -1,41 +1,36 @@
-/atom/proc/nano_host()
-	return src
+/var/global/datum/topic_state/default_state = new()
 
-/obj/nano_module/nano_host()
-	return loc
+/datum/topic_state/default/href_list(var/mob/user)
+	return list()
 
+/datum/topic_state/default/can_use_topic(var/src_object, var/mob/user)
+	return user.default_can_use_topic(src_object)
 
-/atom/proc/CanUseTopic(var/mob/user, href_list, var/datum/topic_state/custom_state)
-	return user.can_use_topic(nano_host(), custom_state)
-
-
-/mob/proc/can_use_topic(var/mob/user, var/datum/topic_state/custom_state)
+/mob/proc/default_can_use_topic(var/src_object)
 	return STATUS_CLOSE // By default no mob can do anything with NanoUI
 
-/mob/dead/observer/can_use_topic()
+/mob/dead/observer/default_can_use_topic()
 	if(check_rights(R_ADMIN, 0, src))
 		return STATUS_INTERACTIVE				// Admins are more equal
 	return STATUS_UPDATE						// Ghosts can view updates
 
-/mob/living/silicon/pai/can_use_topic(var/src_object)
+/mob/living/silicon/pai/default_can_use_topic(var/src_object)
 	if(src_object == src && !stat)
 		return STATUS_INTERACTIVE
 	else
 		return ..()
 
-/mob/living/silicon/robot/can_use_topic(var/src_object, var/datum/topic_state/custom_state)
+/mob/living/silicon/robot/default_can_use_topic(var/src_object)
 	if(stat || !client)
 		return STATUS_CLOSE
 	if(lockcharge || stunned || weakened)
 		return STATUS_DISABLED
-	if(custom_state.flags & NANO_IGNORE_DISTANCE)
-		return STATUS_INTERACTIVE
 	// robots can interact with things they can see within their view range
 	if((src_object in view(src)) && get_dist(src_object, src) <= src.client.view)
 		return STATUS_INTERACTIVE	// interactive (green visibility)
 	return STATUS_DISABLED			// no updates, completely disabled (red visibility)
 
-/mob/living/silicon/robot/syndicate/can_use_topic(var/src_object)
+/mob/living/silicon/robot/syndicate/default_can_use_topic(var/src_object)
 	. = ..()
 	if(. != STATUS_INTERACTIVE)
 		return
@@ -50,7 +45,7 @@
 			return STATUS_INTERACTIVE
 	return STATUS_UPDATE
 
-/mob/living/silicon/ai/can_use_topic(var/src_object)
+/mob/living/silicon/ai/default_can_use_topic(var/src_object)
 	if(!client || check_unable(1))
 		return STATUS_CLOSE
 	// Prevents the AI from using Topic on admin levels (by for example viewing through the court/thunderdome cameras)
@@ -71,26 +66,13 @@
 			return apc_override ? STATUS_INTERACTIVE : STATUS_CLOSE
 		return STATUS_INTERACTIVE
 
-	return 	STATUS_CLOSE
-
-/mob/living/proc/shared_living_nano_interaction(var/src_object)
-	if (src.stat != CONSCIOUS)
-		return STATUS_CLOSE						// no updates, close the interface
-	else if (restrained() || lying || stat || stunned || weakened)
-		return STATUS_UPDATE					// update only (orange visibility)
-	return STATUS_INTERACTIVE
+	return STATUS_CLOSE
 
 //Some atoms such as vehicles might have special rules for how mobs inside them interact with NanoUI.
 /atom/proc/contents_nano_distance(var/src_object, var/mob/living/user)
 	return user.shared_living_nano_distance(src_object)
 
 /mob/living/proc/shared_living_nano_distance(var/atom/movable/src_object)
-	if(!isturf(src_object.loc))
-		if(src_object.loc == src)				// Item in the inventory
-			return STATUS_INTERACTIVE
-		if(src.contents.Find(src_object.loc))	// A hidden uplink inside an item
-			return STATUS_INTERACTIVE
-
 	if (!(src_object in view(4, src))) 	// If the src object is not in visable, disable updates
 		return STATUS_CLOSE
 
@@ -103,27 +85,17 @@
 		return STATUS_DISABLED 		// no updates, completely disabled (red visibility)
 	return STATUS_CLOSE
 
-/mob/living/can_use_topic(var/src_object, var/datum/topic_state/custom_state)
-	. = shared_living_nano_interaction(src_object)
-	if(. == STATUS_INTERACTIVE && !(custom_state.flags & NANO_IGNORE_DISTANCE))
+/mob/living/default_can_use_topic(var/src_object)
+	. = shared_nano_interaction(src_object)
+	if(. == STATUS_INTERACTIVE)
 		if(loc)
 			. = loc.contents_nano_distance(src_object, src)
-		else
-			. = shared_living_nano_distance(src_object)
 	if(STATUS_INTERACTIVE)
 		return STATUS_UPDATE
 
-/mob/living/carbon/human/can_use_topic(var/src_object, var/datum/topic_state/custom_state)
-	. = shared_living_nano_interaction(src_object)
-	if(. == STATUS_INTERACTIVE && !(custom_state.flags & NANO_IGNORE_DISTANCE))
+/mob/living/carbon/human/default_can_use_topic(var/src_object)
+	. = shared_nano_interaction(src_object)
+	if(. == STATUS_INTERACTIVE)
 		. = shared_living_nano_distance(src_object)
 		if(. == STATUS_UPDATE && (TK in mutations))	// If we have telekinesis and remain close enough, allow interaction.
 			return STATUS_INTERACTIVE
-
-/var/global/datum/topic_state/default_state = new()
-
-/datum/topic_state
-	var/flags = 0
-
-/datum/topic_state/proc/href_list(var/mob/user)
-	return list()

code/modules/nano/interaction/inventory.dm

@@ -0,0 +1,10 @@
+/*
+	This state checks that the src_object is somewhere in the user's first-level inventory (in hands, on ear, etc.), but not further down (such as in bags).
+*/
+/var/global/datum/topic_state/inventory_state/inventory_state = new()
+
+/datum/topic_state/inventory_state/can_use_topic(var/src_object, var/mob/user)
+	if(!(src_object in src))
+		return STATUS_CLOSE
+
+	return user.shared_nano_interaction()

code/modules/nano/interaction/zlevel.dm

@@ -0,0 +1,13 @@
+/*
+	This state checks that the user is on the same Z-level as src_object
+*/
+
+/var/global/datum/topic_state/z_state/z_state = new()
+
+/datum/topic_state/z_state/can_use_topic(var/src_object, var/mob/user)
+	var/turf/turf_obj = get_turf(src_object)
+	var/turf/turf_usr = get_turf(user)
+	if(!turf_obj || !turf_usr)
+		return STATUS_CLOSE
+
+	return turf_obj.z == turf_usr.z ? STATUS_INTERACTIVE : STATUS_CLOSE

code/modules/nano/modules/human_appearance.dm

@@ -18,7 +18,7 @@
 	src.whitelist = species_whitelist
 	src.blacklist = species_blacklist
 
-/obj/nano_module/appearance_changer/Topic(ref, href_list)
+/obj/nano_module/appearance_changer/Topic(ref, href_list, var/nowindow, var/datum/topic_state/state = default_state)
 	if(..())
 		return 1
 
@@ -35,13 +35,13 @@
 	if(href_list["skin_tone"])
 		if(can_change_skin_tone())
 			var/new_s_tone = input(usr, "Choose your character's skin-tone:\n(Light 1 - 220 Dark)", "Skin Tone", owner.s_tone) as num|null
-			if(isnum(new_s_tone) && CanUseTopic(usr) == STATUS_INTERACTIVE)
+			if(isnum(new_s_tone) && can_still_topic(state))
 				new_s_tone = 35 - max(min( round(new_s_tone), 220),1)
 				return owner.change_skin_tone(new_s_tone)
 	if(href_list["skin_color"])
 		if(can_change_skin_color())
 			var/new_skin = input(usr, "Choose your character's skin colour: ", "Skin Color", rgb(owner.r_skin, owner.g_skin, owner.b_skin)) as color|null
-			if(new_skin && can_still_topic())
+			if(new_skin && can_still_topic(state))
 				var/r_skin = hex2num(copytext(new_skin, 2, 4))
 				var/g_skin = hex2num(copytext(new_skin, 4, 6))
 				var/b_skin = hex2num(copytext(new_skin, 6, 8))
@@ -56,7 +56,7 @@
 	if(href_list["hair_color"])
 		if(can_change(APPEARANCE_HAIR_COLOR))
 			var/new_hair = input("Please select hair color.", "Hair Color", rgb(owner.r_hair, owner.g_hair, owner.b_hair)) as color|null
-			if(new_hair && can_still_topic())
+			if(new_hair && can_still_topic(state))
 				var/r_hair = hex2num(copytext(new_hair, 2, 4))
 				var/g_hair = hex2num(copytext(new_hair, 4, 6))
 				var/b_hair = hex2num(copytext(new_hair, 6, 8))
@@ -71,7 +71,7 @@
 	if(href_list["facial_hair_color"])
 		if(can_change(APPEARANCE_FACIAL_HAIR_COLOR))
 			var/new_facial = input("Please select facial hair color.", "Facial Hair Color", rgb(owner.r_facial, owner.g_facial, owner.b_facial)) as color|null
-			if(new_facial && can_still_topic())
+			if(new_facial && can_still_topic(state))
 				var/r_facial = hex2num(copytext(new_facial, 2, 4))
 				var/g_facial = hex2num(copytext(new_facial, 4, 6))
 				var/b_facial = hex2num(copytext(new_facial, 6, 8))
@@ -81,7 +81,7 @@
 	if(href_list["eye_color"])
 		if(can_change(APPEARANCE_EYE_COLOR))
 			var/new_eyes = input("Please select eye color.", "Eye Color", rgb(owner.r_eyes, owner.g_eyes, owner.b_eyes)) as color|null
-			if(new_eyes && can_still_topic())
+			if(new_eyes && can_still_topic(state))
 				var/r_eyes = hex2num(copytext(new_eyes, 2, 4))
 				var/g_eyes = hex2num(copytext(new_eyes, 4, 6))
 				var/b_eyes = hex2num(copytext(new_eyes, 6, 8))
@@ -91,7 +91,7 @@
 
 	return 0
 
-/obj/nano_module/appearance_changer/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+/obj/nano_module/appearance_changer/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
 	generate_data(check_whitelist, whitelist, blacklist)
 	var/data[0]
 
@@ -128,7 +128,7 @@
 	data["change_facial_hair_color"] = can_change(APPEARANCE_FACIAL_HAIR_COLOR)
 	ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
 	if (!ui)
-		ui = new(user, src, ui_key, "appearance_changer.tmpl", "[src.name]", 800, 450)
+		ui = new(user, src, ui_key, "appearance_changer.tmpl", "[src.name]", 800, 450, state = state)
 		ui.set_initial_data(data)
 		ui.open()
 		ui.set_auto_update(1)

code/modules/nano/modules/law_manager.dm

@@ -152,7 +152,7 @@
 
 	return 0
 
-/obj/nano_module/law_manager/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
+/obj/nano_module/law_manager/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/topic_state/state = default_state)
 	var/data[0]
 	owner.lawsync()
 
@@ -189,7 +189,7 @@
 
 	ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
 	if (!ui)
-		ui = new(user, src, ui_key, "law_manager.tmpl", sanitize("[src] - [owner]"), 800, is_malf(user) ? 600 : 400)
+		ui = new(user, src, ui_key, "law_manager.tmpl", sanitize("[src] - [owner]"), 800, is_malf(user) ? 600 : 400, state = state)
 		ui.set_initial_data(data)
 		ui.open()
 		ui.set_auto_update(1)

code/modules/nano/modules/nano_module.dm

@@ -1,2 +1,5 @@
-/obj/nano_module/proc/can_still_topic()
-	return CanUseTopic(usr, list(), default_state) == STATUS_INTERACTIVE
+/obj/nano_module/nano_host()
+	return loc
+
+/obj/nano_module/proc/can_still_topic(var/datum/topic_state/state = default_state)
+	return CanUseTopic(usr, state) == STATUS_INTERACTIVE

code/modules/nano/nanoexternal.dm

@@ -37,7 +37,7 @@
   *
   * @return nothing
   */
-/atom/movable/proc/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/nano_ui/master_ui = null, var/datum/topic_state/custom_state = null)
+/atom/movable/proc/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1, var/datum/nano_ui/master_ui = null, var/datum/topic_state/state = default_state)
 	return
 
 // Used by the Nano UI Manager (/datum/nanomanager) to track UIs opened by this mob

code/modules/nano/nanoui.dm

@@ -55,7 +55,7 @@ nanoui is used to open and update nano browser uis
 	// Relationship between a master interface and its children. Used in update_status
 	var/datum/nanoui/master_ui
 	var/list/datum/nanoui/children = list()
-	var/datum/topic_state/custom_state = null
+	var/datum/topic_state/state = null
 
 	var/cached_data = null
 
@@ -73,7 +73,7 @@ nanoui is used to open and update nano browser uis
   *
   * @return /nanoui new nanoui object
   */
-/datum/nanoui/New(nuser, nsrc_object, nui_key, ntemplate_filename, ntitle = 0, nwidth = 0, nheight = 0, var/atom/nref = null, var/datum/nanoui/master_ui = null, var/datum/topic_state/custom_state = default_state)
+/datum/nanoui/New(nuser, nsrc_object, nui_key, ntemplate_filename, ntitle = 0, nwidth = 0, nheight = 0, var/atom/nref = null, var/datum/nanoui/master_ui = null, var/datum/topic_state/state = default_state)
 	user = nuser
 	src_object = nsrc_object
 	ui_key = nui_key
@@ -82,7 +82,7 @@ nanoui is used to open and update nano browser uis
 	src.master_ui = master_ui
 	if(master_ui)
 		master_ui.children += src
-	src.custom_state = custom_state
+	src.state = state
 
 	// add the passed template filename as the "main" template, this is required
 	add_template("main", ntemplate_filename)
@@ -142,8 +142,7 @@ nanoui is used to open and update nano browser uis
   * @return nothing
   */
 /datum/nanoui/proc/update_status(var/push_update = 0)
-	var/atom/movable/host = src_object.nano_host()
-	var/new_status = host.CanUseTopic(user, list(), custom_state)
+	var/new_status = src_object.CanUseTopic(user, state)
 	if(master_ui)
 		new_status = min(new_status, master_ui.status)
 
@@ -483,7 +482,7 @@ nanoui is used to open and update nano browser uis
 		set_map_z_level(text2num(href_list["mapZLevel"]))
 		map_update = 1
 
-	if ((src_object && src_object.Topic(href, href_list, 0, custom_state)) || map_update)
+	if ((src_object && src_object.Topic(href, href_list, 0, state)) || map_update)
 		nanomanager.update_uis(src_object) // update all UIs attached to src_object
 
  /**
@@ -510,4 +509,4 @@ nanoui is used to open and update nano browser uis
   * @return nothing
   */
 /datum/nanoui/proc/update(var/force_open = 0)
-	src_object.ui_interact(user, ui_key, src, force_open, master_ui, custom_state)
+	src_object.ui_interact(user, ui_key, src, force_open, master_ui, state)