mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-08-30 15:38:02 +01:00
cdafe425a5
* Adds Trait Genetics from Outpost21 Adds trait genetics from Outpost 21 - Tried to update each file it touched to be equivalent to their Chomp specific variants in order to maintain functionality and make sure no oddities would happen due to code differences. (Some things like the eardeaf loop were left there but commented out) * Morph trait * Fixes a server crashing bug with flip aa * flip * Makes morph superpower better - Makes it use the appearance_changer instead of 1000 different procs - Makes cocoon weaver able to change eye and skin color. I did NOT select you. BAD * begone * fix dna modifier * Fixes massive memory leak * Brain Runtime Fix * There was no reason for this to be a spawn(0) And no I didn't spawn with no blood - https://i.imgur.com/vPizqCD.png * revert revert the dna changes there * Deconf * gets rid of unused proc vars that did nothing * expects enough free slots * glob * fixed and added two other tests * another few tests * this is a list * fixed bad injector * lets wrap these for sanity * better feedback * wrong name * don't allow multiple occupants into the dna pod * future traits will have activation levels instead of binary on/off --------- Co-authored-by: Kashargul <144968721+Kashargul@users.noreply.github.com> Co-authored-by: Willburd <7099514+Willburd@users.noreply.github.com>
87 lines
2.6 KiB
Plaintext
87 lines
2.6 KiB
Plaintext
/**
|
|
* Sends a div formatted chat box announcement
|
|
*
|
|
* Formatted like:
|
|
*
|
|
* " Server Announcement " (or sender_override)
|
|
*
|
|
* " Title "
|
|
*
|
|
* " Text "
|
|
*
|
|
* Arguments
|
|
* * text - required, the text to announce
|
|
* * title - optional, the title of the announcement.
|
|
* * players - optional, a list of all players to send the message to. defaults to the entire world
|
|
* * play_sound - if TRUE, play a sound with the announcement (based on player option)
|
|
* * sound_override - optional, override the default announcement sound
|
|
* * sender_override - optional, modifies the sender of the announcement
|
|
* * encode_title - if TRUE, the title will be HTML encoded (escaped)
|
|
* * encode_text - if TRUE, the text will be HTML encoded (escaped)
|
|
*/
|
|
|
|
/proc/send_ooc_announcement(
|
|
text,
|
|
title = "",
|
|
players,
|
|
play_sound = TRUE,
|
|
sound_override = 'sound/misc/bloop.ogg',
|
|
sender_override = "Server Admin Announcement",
|
|
encode_title = TRUE,
|
|
encode_text = FALSE,
|
|
)
|
|
if(isnull(text))
|
|
return
|
|
|
|
var/list/announcement_strings = list()
|
|
|
|
if(encode_title && title && length(title) > 0)
|
|
title = html_encode(title)
|
|
if(encode_text)
|
|
text = html_encode(text)
|
|
if(!length(text))
|
|
return
|
|
|
|
announcement_strings += span_major_announcement_title(sender_override)
|
|
announcement_strings += span_subheader_announcement_text(title)
|
|
announcement_strings += span_ooc_announcement_text(text)
|
|
var/finalized_announcement = create_ooc_announcement_div(jointext(announcement_strings, ""))
|
|
|
|
if(islist(players))
|
|
for(var/mob/target in players)
|
|
to_chat(target, finalized_announcement)
|
|
//if(play_sound && target.client?.prefs.read_preference(/datum/preference/toggle/sound_announcements))
|
|
if(play_sound && target.client?.prefs.read_preference(/datum/preference/toggle/holder/play_adminhelp_ping))
|
|
SEND_SOUND(target, sound(sound_override))
|
|
else
|
|
to_chat(world, finalized_announcement)
|
|
|
|
if(!play_sound)
|
|
return
|
|
|
|
for(var/mob/player in player_list)
|
|
//if(player.client?.prefs.read_preference(/datum/preference/toggle/sound_announcements))
|
|
if(player.client?.prefs.read_preference(/datum/preference/toggle/holder/play_adminhelp_ping))
|
|
SEND_SOUND(player, sound(sound_override))
|
|
|
|
/**
|
|
* Inserts a span styled message into an alert box div
|
|
*
|
|
*
|
|
* Arguments
|
|
* * message - required, the message contents
|
|
* * color - optional, set a div color other than default
|
|
*/
|
|
/proc/create_announcement_div(message, color = "default")
|
|
return "<div class='chat_alert_[color]'>[message]</div>"
|
|
|
|
/**
|
|
* Inserts a span styled message into an OOC alert style div
|
|
*
|
|
*
|
|
* Arguments
|
|
* * message - required, the message contents
|
|
*/
|
|
/proc/create_ooc_announcement_div(message)
|
|
return "<div class='ooc_alert'>[message]</div>"
|