mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-03-24 20:52:53 +00:00
84dc5535dc
* These two are easy * !!!runlevel_flags the fact it was global.runlevel_flags.len has me a bit...iffy on this. * !!!json_cache Same as above. used global. * player_list & observer_mob_list * mechas_list * this wasn't even used * surgery_steps * event_triggers * landmarks_list * dead_mob_list * living_mob_list * ai_list * cable_list * cleanbot_reserved_turfs * listening_objects * silicon_mob_list * human_mob_list * Update global_lists.dm * joblist * mob_list * Update global_lists.dm * holomap_markers * mapping_units * mapping_beacons * hair_styles_list * facial_hair_styles_list * Update global_lists.dm * facial_hair_styles_male_list * facial_hair_styles_female_list * body_marking_styles_list * body_marking_nopersist_list * ear_styles_list * hair_styles_male_list * tail_styles_list * wing_styles_list * escape_list & rune_list & endgame_exits these were all really small * endgame_safespawns * stool_cache * emotes_by_key * random_maps & map_count * item_tf_spawnpoints * narsie_list * active_radio_jammers * unused * paikeys * pai_software_by_key & default_pai_software * plant_seed_sprites * magazine_icondata_keys & magazine_icondata_states * unused * ashtray_cache * light_type_cache * HOLIDAY!!! this one was annoying * faction stuff (red?!) * Update preferences_factions.dm * vs edit removal * backbaglist, pdachoicelist, exclude_jobs * item_digestion_blacklist, edible_tech, blacklisted_artifact_effect, selectable_footstep, hexNums, syndicate_access * string_slot_flags and hexdigits->hexNums * possible_changeling_IDs * vr_mob_tf_options * vr_mob_spawner_options * pipe_colors * vr_mob_spawner_options * common_tools * newscaster_standard_feeds * Update periodic_news.dm * changeling_fabricated_clothing * semirandom_mob_spawner_decisions * id_card_states * Update syndicate_ids.dm * overlay_cache & gear_distributed_to * more * radio_channels_by_freq * Update global_lists.dm * proper * default_medbay_channels & default_internal_channels default_internal_channels is weird as it has a mapbased proc() but that proc is never called... * valid_ringtones * move this * possible_plants * more * separate these moves xeno2chemlist from a hook to a new global list. * tube_dir_list * valid_bloodreagents & monitor_states * Junk * valid_bloodtypes * breach_burn_descriptors & burn * more!! appliance_available_recipes seems uber cursed, re-look at later * Appliance code is cursed * wide_chassis & flying_chassis * allows_eye_color * all_tooltip_styles * direction_table * gun_choices * severity_to_string * old event_viruses * description_icons * MOVE_KEY_MAPPINGS * more more * pai & robot modules * Update global_lists.dm * GEOSAMPLES Also swaps a .len to LAZYLEN() * shieldgens * reagent recipies * global ammo types * rad collector * old file and unused global * nif_look_messages * FESH * nifsoft * chamelion * the death of sortAtom * globulins * lazylen that * Update global_lists.dm * LAZY * Theese too * quick fix --------- Co-authored-by: Kashargul <144968721+Kashargul@users.noreply.github.com>
70 lines
2.7 KiB
Plaintext
70 lines
2.7 KiB
Plaintext
// These are objects you can use inside special maps (like PoIs), or for adminbuse.
|
|
// Players cannot see or interact with these.
|
|
/obj/effect/map_effect
|
|
anchored = TRUE
|
|
invisibility = INVISIBILITY_BADMIN // So a badmin can go view these by changing their see_invisible.
|
|
icon = 'icons/effects/map_effects.dmi'
|
|
|
|
// Below vars concern check_for_player_proximity() and is used to not waste effort if nobody is around to appreciate the effects.
|
|
var/always_run = FALSE // If true, the game will not try to suppress this from firing if nobody is around to see it.
|
|
var/proximity_needed = 12 // How many tiles a mob with a client must be for this to run.
|
|
var/ignore_ghosts = FALSE // If true, ghosts won't satisfy the above requirement.
|
|
var/ignore_afk = TRUE // If true, AFK people (5 minutes) won't satisfy it as well.
|
|
var/retry_delay = 5 SECONDS // How long until we check for players again.
|
|
var/next_attempt = 0 // Next time we're going to do ACTUAL WORK
|
|
|
|
/obj/effect/map_effect/ex_act()
|
|
return
|
|
|
|
/obj/effect/map_effect/singularity_pull()
|
|
return
|
|
|
|
/obj/effect/map_effect/singularity_act()
|
|
return
|
|
|
|
// Base type for effects that run on variable intervals.
|
|
/obj/effect/map_effect/interval
|
|
var/interval_lower_bound = 5 SECONDS // Lower number for how often the map_effect will trigger.
|
|
var/interval_upper_bound = 5 SECONDS // Higher number for above.
|
|
|
|
/obj/effect/map_effect/interval/Initialize(mapload)
|
|
. = ..()
|
|
START_PROCESSING(SSobj, src)
|
|
|
|
/obj/effect/map_effect/interval/Destroy()
|
|
STOP_PROCESSING(SSobj, src)
|
|
return ..()
|
|
|
|
// Override this for the specific thing to do.
|
|
/obj/effect/map_effect/interval/proc/trigger()
|
|
return
|
|
|
|
// Handles the delay and making sure it doesn't run when it would be bad.
|
|
/obj/effect/map_effect/interval/process()
|
|
//Not yet!
|
|
if(world.time < next_attempt)
|
|
return
|
|
|
|
// Check to see if we're useful first.
|
|
if(!always_run && !check_for_player_proximity(src, proximity_needed, ignore_ghosts, ignore_afk))
|
|
next_attempt = world.time + retry_delay
|
|
// Hey there's someone nearby.
|
|
else
|
|
next_attempt = world.time + rand(interval_lower_bound, interval_upper_bound)
|
|
trigger()
|
|
|
|
// Helper proc to optimize the use of effects by making sure they do not run if nobody is around to perceive it.
|
|
/proc/check_for_player_proximity(var/atom/proximity_to, var/radius = 12, var/ignore_ghosts = FALSE, var/ignore_afk = TRUE)
|
|
if(!proximity_to)
|
|
return FALSE
|
|
|
|
for(var/thing in GLOB.player_list)
|
|
var/mob/M = thing // Avoiding typechecks for more speed, GLOB.player_list will only contain mobs anyways.
|
|
if(ignore_ghosts && isobserver(M))
|
|
continue
|
|
if(ignore_afk && M.client && M.client.is_afk(5 MINUTES))
|
|
continue
|
|
if(M.z == proximity_to.z && get_dist(M, proximity_to) <= radius)
|
|
return TRUE
|
|
return FALSE
|