mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-05-17 20:30:46 +01:00
Will
6f6ab0f281
* dizzy and jitter component * no need for set_jittery * minimize proc differences * not needed * jitter * match old behavior * jitter medical issue fix
54 lines
1.9 KiB
Plaintext
54 lines
1.9 KiB
Plaintext
/datum/disease/anxiety
|
|
name = "Severe Anxiety"
|
|
medical_name = "Lepidopteric Hyperemesis"
|
|
form = "Infection"
|
|
max_stages = 4
|
|
spread_text = "On contact"
|
|
spread_flags = DISEASE_SPREAD_BLOOD | DISEASE_SPREAD_FLUIDS | DISEASE_SPREAD_CONTACT
|
|
cure_text = REAGENT_ETHANOL
|
|
cures = list(REAGENT_ID_ETHANOL)
|
|
agent = "Excess Lepdopticides"
|
|
viable_mobtypes = list(/mob/living/carbon/human, /mob/living/carbon/human/monkey)
|
|
desc = "If left untreated subject will regurgitate butterflies."
|
|
danger = DISEASE_MINOR
|
|
|
|
/datum/disease/anxiety/stage_act()
|
|
..()
|
|
switch(stage)
|
|
if(2)
|
|
if(prob(15))
|
|
to_chat(affected_mob, span_notice("You feel anxious."))
|
|
if(3)
|
|
if(prob(10))
|
|
to_chat(affected_mob, span_notice("Your stomach flutters."))
|
|
if(prob(5))
|
|
to_chat(affected_mob, span_notice("You feel panicky."))
|
|
if(prob(2))
|
|
to_chat(affected_mob, span_danger("You're overtaken with panic!"))
|
|
affected_mob.AdjustConfused(rand(4, 6))
|
|
if(4)
|
|
if(prob(10))
|
|
to_chat(affected_mob, span_danger("You feel butterflies in your stomach."))
|
|
if(prob(5))
|
|
affected_mob.visible_message(
|
|
span_danger("[affected_mob] stumbles around in a panic"),
|
|
span_userdanger("You have a panic attack!")
|
|
)
|
|
affected_mob.AdjustConfused(rand(12, 16))
|
|
affected_mob.make_jittery(100 + rand(12, 16))
|
|
if(prob(2))
|
|
affected_mob.visible_message(
|
|
span_danger("[affected_mob] coughs up butterflies!"),
|
|
span_userdanger("You cough up butterflies!")
|
|
)
|
|
affected_mob.emote("cough")
|
|
for(var/i in 1 to 2)
|
|
var/mob/living/simple_mob/animal/sif/glitterfly/B = new(affected_mob.loc)
|
|
addtimer(CALLBACK(B, TYPE_PROC_REF(/mob/living/simple_mob/animal/sif/glitterfly, decompose)), rand(5, 25) SECONDS)
|
|
|
|
/mob/living/simple_mob/animal/sif/glitterfly/proc/decompose()
|
|
visible_message(
|
|
span_notice("[src] decomposes due to being outside of its original habitat for too long!"),
|
|
span_userdanger("You decompose for being too long out of your habitat!"))
|
|
dust()
|