VOREStation/code/game/objects/items/devices/aicard.dm

/obj/item/aicard
	name = "intelliCore"
	desc = "Used to preserve and transport an AI."
	icon = 'icons/obj/pda.dmi'
	icon_state = "aicard" // aicard-full
	item_state = "aicard"
	w_class = ITEMSIZE_NORMAL
	slot_flags = SLOT_BELT
	show_messages = 0
	preserve_item = 1

	var/flush = null
	origin_tech = list(TECH_DATA = 4, TECH_MATERIAL = 4)

	var/mob/living/silicon/ai/carded_ai

/obj/item/aicard/attack(mob/living/silicon/decoy/M as mob, mob/user as mob)
	if (!istype (M, /mob/living/silicon/decoy))
		return ..()
	else
		M.death()
		to_chat(user, span_infoplain(span_bold("ERROR ERROR ERROR")))

/obj/item/aicard/attack_self(mob/user)
	. = ..(user)
	if(.)
		return TRUE
	tgui_interact(user)

/obj/item/aicard/tgui_interact(mob/user, datum/tgui/ui = null, datum/tgui_state/custom_state)
	ui = SStgui.try_update_ui(user, src, ui)
	if(!ui)
		ui = new(user, src, "AICard", "[name]") // 600, 394
		ui.open()
	if(custom_state)
		ui.set_state(custom_state)

/obj/item/aicard/tgui_state(mob/user)
	return GLOB.tgui_inventory_state

/obj/item/aicard/tgui_data(mob/user)
	var/data[0]

	data["has_ai"] = carded_ai != null
	if(carded_ai)
		data["name"] = carded_ai.name
		data["integrity"] = carded_ai.hardware_integrity()
		data["backup_capacitor"] = carded_ai.backup_capacitor()
		data["radio"] = !carded_ai.aiRadio.disabledAi
		data["wireless"] = !carded_ai.control_disabled
		data["operational"] = carded_ai.stat != DEAD
		data["flushing"] = flush

		var/laws[0]
		for(var/datum/ai_law/law in carded_ai.laws.all_laws())
			if(law in carded_ai.laws.ion_laws) // If we're an ion law, give it an ion index code
				laws.Add(ionnum() + ". " + law.law)
			else
				laws.Add(num2text(law.get_index()) + ". " + law.law)
		data["laws"] = laws
		data["has_laws"] = length(carded_ai.laws.all_laws())

	return data

/obj/item/aicard/tgui_act(action, params, datum/tgui/ui)
	if(..())
		return TRUE

	if(!carded_ai)
		return

	switch(action)
		if("wipe")
			msg_admin_attack("[key_name_admin(ui.user)] wiped [key_name_admin(AI_DEPT)] with \the [src].")
			add_attack_logs(ui.user,carded_ai,"Purged from AI Card")
			INVOKE_ASYNC(src, PROC_REF(wipe_ai))
		if("radio")
			carded_ai.aiRadio.disabledAi = !carded_ai.aiRadio.disabledAi
			to_chat(carded_ai, span_warning("Your Subspace Transceiver has been [carded_ai.aiRadio.disabledAi ? "disabled" : "enabled"]!"))
			to_chat(ui.user, span_notice("You [carded_ai.aiRadio.disabledAi ? "disable" : "enable"] the AI's Subspace Transceiver."))
		if("wireless")
			carded_ai.control_disabled = !carded_ai.control_disabled
			to_chat(carded_ai, span_warning("Your wireless interface has been [carded_ai.control_disabled ? "disabled" : "enabled"]!"))
			to_chat(ui.user, span_notice("You [carded_ai.control_disabled ? "disable" : "enable"] the AI's wireless interface."))
			if(carded_ai.control_disabled && carded_ai.deployed_shell)
				carded_ai.disconnect_shell("Disconnecting from remote shell due to [src] wireless access interface being disabled.")
			update_icon()

	return TRUE

/obj/item/aicard/update_icon()
	cut_overlays()
	if(carded_ai)
		if (!carded_ai.control_disabled)
			add_overlay("aicard-on")
		if(carded_ai.stat)
			icon_state = "aicard-404"
		else
			icon_state = "aicard-full"
	else
		icon_state = "aicard"

/obj/item/aicard/proc/grab_ai(var/mob/living/silicon/ai/ai, var/mob/living/user)
	if(!ai.client && !ai.deployed_shell)
		to_chat(user, span_danger("ERROR:") + " AI [ai.name] is offline. Unable to transfer.")
		return 0

	if(carded_ai)
		to_chat(user, span_danger("Transfer failed:") + " Existing AI found on remote device. Remove existing AI to install a new one.")
		return 0

	if(!user.IsAdvancedToolUser() && isanimal(user))
		var/mob/living/simple_mob/S = user
		if(!S.IsHumanoidToolUser(src))
			return 0

	user.visible_message("\The [user] starts transferring \the [ai] into \the [src]...", "You start transferring \the [ai] into \the [src]...")
	show_message(span_critical("\The [user] is transferring you into \the [src]!"))

	if(do_after(user, 10 SECONDS, target = src))
		if(carded_ai)
			to_chat(user, span_danger("Transfer failed:") + " Existing AI found on remote device. Remove existing AI to install a new one.")
			return 0
		if(istype(ai.loc, /turf/))
			new /obj/structure/AIcore/deactivated(get_turf(ai))

		ai.carded = 1
		add_attack_logs(user,ai,"Extracted into AI Card")
		src.name = "[initial(name)] - [ai.name]"

		ai.loc = src
		ai.destroy_eyeobj(src)
		ai.cancel_camera()
		ai.control_disabled = 1
		ai.aiRestorePowerRoutine = 0
		carded_ai = ai
		ai.disconnect_shell("Disconnected from remote shell due to core intelligence transfer.") //If the AI is controlling a borg, force the player back to core!

		if(ai.client)
			to_chat(ai, span_infoplain("You have been transferred into a mobile core. Remote access lost."))
		if(user.client)
			to_chat(ai, span_notice(span_bold("Transfer successful:")) + " [ai.name] extracted from current device and placed within mobile core.")

		ai.canmove = 1
		update_icon()
	return 1

/obj/item/aicard/proc/clear()
	if(carded_ai && istype(carded_ai.loc, /turf))
		carded_ai.canmove = 0
		carded_ai.carded = 0
	name = initial(name)
	carded_ai = null
	update_icon()

/obj/item/aicard/see_emote(mob/living/M, text)
	if(carded_ai && carded_ai.client)
		var/rendered = span_message("[text]")
		carded_ai.show_message(rendered, 2)
	..()

/obj/item/aicard/show_message(msg, type, alt, alt_type)
	if(carded_ai && carded_ai.client)
		var/rendered = span_message("[msg]")
		carded_ai.show_message(rendered, type)
	..()

/obj/item/aicard/relaymove(var/mob/user, var/direction)
	if(user.stat || user.stunned)
		return
	var/obj/item/rig/rig = src.get_rig()
	if(istype(rig))
		rig.forced_move(direction, user)

/obj/item/aicard/proc/wipe_ai()
	var/mob/living/silicon/ai/our_ai = carded_ai
	flush = TRUE
	our_ai.suiciding = TRUE
	to_chat(our_ai, "Your power has been disabled!")
	while(our_ai && our_ai.stat != DEAD)
		// This is absolutely evil and I love it.
		if(our_ai.deployed_shell && prob(our_ai.oxyloss)) //You feel it creeping? Eventually will reach 100, resulting in the second half of the AI's remaining life being lonely.
			our_ai.disconnect_shell("Disconnecting from remote shell due to insufficent power.")
		our_ai.adjustOxyLoss(2)
		our_ai.updatehealth()
		sleep(10)
	flush = FALSE