mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-05-17 20:30:46 +01:00
Cameron Lennox
d5849910e5
* Begin clickcode attack_self fix Begins the work to make everything call back to parent for attack_self so that signals are sacred. * Makes MORE things call the attack_self() parent Yes, I could make special_handling a var on obj/item HOWEVER i want it to be specific so it can be tracked down later and ONLY the objects that use it can be refactored instead of sitting there literally forever and it just becoming 'a thing'. * Finishes making the rest of attack_self call parent. As mentioned, things such as 'specialty_goggles' 'special_handling' and the such are only there to help with attack_self until the attack_self is recoded for those items. * begone foul demon * some more cleanup * These * GOD this was annoying * yeh * Fix this * fLARES * Thesee too * toys! * Even more! * More fixes * Even more * rest of em * these too * Update syndie.dm * hardref clear * Update code/game/gamemodes/nuclear/pinpointer.dm * Update code/game/objects/effects/mines.dm * Update code/game/objects/items/blueprints_vr.dm * Update code/game/objects/items/blueprints_vr.dm * Update code/game/objects/items/contraband_vr.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/gunbox.dm * Update code/game/objects/items/gunbox.dm * Update code/game/objects/items/gunbox_vr.dm * Update code/game/objects/items/gunbox_vr.dm * Update code/game/objects/items/weapons/gift_wrappaper.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/gunbox.dm * these too * Update maintpanel_stack.dm * angry warning * Fixes packaged snacks. Fixes improper var default. * Special handling for these * proper poly types * Fixes magclaws Makes the 'features' it had just part of base magboots that can be adjusted via varswap. * Fixes jackets Fixes https://github.com/VOREStation/VOREStation/issues/18941 * Small bugfix Makes p_Theyre properly capitialize Makes examine show proper wording * Update gift_wrappaper.dm
154 lines
6.0 KiB
Plaintext
154 lines
6.0 KiB
Plaintext
#define T_FIREWORK_WEATHER_STAR(name) "weather firework star (" + (name) + ")"
|
|
|
|
/obj/item/firework_star
|
|
icon = 'icons/obj/firework_stars.dmi'
|
|
name = "firework star"
|
|
desc = "A very tightly compacted ball of chemicals for use with firework launcher."
|
|
icon_state = "star"
|
|
w_class = ITEMSIZE_SMALL
|
|
origin_tech = list(TECH_MATERIAL = 2, TECH_ENGINEERING = 1)
|
|
|
|
/obj/item/firework_star/proc/trigger_firework(var/datum/weather_holder/w_holder)
|
|
return
|
|
|
|
|
|
/obj/item/firework_star/weather
|
|
name = "weather firework star"
|
|
desc = "A firework star designed to alter a weather, rather than put on a show."
|
|
var/weather_type
|
|
origin_tech = list(TECH_MATERIAL = 5, TECH_ENGINEERING = 2)
|
|
|
|
/obj/item/firework_star/weather/trigger_firework(var/datum/weather_holder/w_holder)
|
|
if(!w_holder) // Sanity
|
|
return
|
|
if(w_holder.firework_override) // Make sure weather-based events can't be interfered with
|
|
return
|
|
if(weather_type && (weather_type in w_holder.allowed_weather_types))
|
|
w_holder.message_all_outdoor_players("Something seems to flash in the sky, as weather starts to rapidly shift!")
|
|
w_holder.queue_imminent_weather(weather_type)
|
|
var/datum/weather/our_weather = w_holder.allowed_weather_types[weather_type]
|
|
w_holder.message_all_outdoor_players(our_weather.imminent_transition_message)
|
|
|
|
/obj/item/firework_star/weather/clear
|
|
name = T_FIREWORK_WEATHER_STAR("CLEAR SKY")
|
|
weather_type = WEATHER_CLEAR
|
|
icon_state = "clear"
|
|
|
|
/obj/item/firework_star/weather/overcast
|
|
name = T_FIREWORK_WEATHER_STAR("CLOUDY")
|
|
weather_type = WEATHER_OVERCAST
|
|
icon_state = "cloudy"
|
|
|
|
/obj/item/firework_star/weather/fog
|
|
name = T_FIREWORK_WEATHER_STAR("FOG")
|
|
weather_type = WEATHER_FOG
|
|
icon_state = "cloudy"
|
|
|
|
/obj/item/firework_star/weather/rain
|
|
name = T_FIREWORK_WEATHER_STAR("RAIN")
|
|
weather_type = WEATHER_RAIN
|
|
icon_state = "rain"
|
|
|
|
/obj/item/firework_star/weather/storm
|
|
name = T_FIREWORK_WEATHER_STAR("STORM")
|
|
weather_type = WEATHER_STORM
|
|
icon_state = "rain"
|
|
|
|
/obj/item/firework_star/weather/light_snow
|
|
name = T_FIREWORK_WEATHER_STAR("SNOW - LIGHT")
|
|
weather_type = WEATHER_LIGHT_SNOW
|
|
icon_state = "snow"
|
|
|
|
/obj/item/firework_star/weather/snow
|
|
name = T_FIREWORK_WEATHER_STAR("SNOW - MEDIUM")
|
|
weather_type = WEATHER_SNOW
|
|
icon_state = "snow"
|
|
|
|
/obj/item/firework_star/weather/blizzard
|
|
name = T_FIREWORK_WEATHER_STAR("SNOW - HEAVY")
|
|
weather_type = WEATHER_BLIZZARD
|
|
icon_state = "snow"
|
|
|
|
/obj/item/firework_star/weather/hail
|
|
name = T_FIREWORK_WEATHER_STAR("HAIL")
|
|
weather_type = WEATHER_HAIL
|
|
icon_state = "snow"
|
|
origin_tech = list(TECH_MATERIAL = 5, TECH_ENGINEERING = 2, TECH_ILLEGAL = 1)
|
|
|
|
/obj/item/firework_star/weather/fallout
|
|
name = T_FIREWORK_WEATHER_STAR("NUCLEAR")
|
|
desc = "This is the worst idea ever."
|
|
weather_type = WEATHER_FALLOUT_TEMP
|
|
icon_state = "nuclear"
|
|
origin_tech = list(TECH_MATERIAL = 7, TECH_ENGINEERING = 3, TECH_ILLEGAL = 5)
|
|
|
|
/obj/item/firework_star/weather/confetti
|
|
name = T_FIREWORK_WEATHER_STAR("CONFETTI")
|
|
desc = "A firework star designed to alter a weather, rather than put on a show. This one makes colorful confetti rain from the sky."
|
|
weather_type = WEATHER_CONFETTI
|
|
icon_state = "confetti"
|
|
|
|
|
|
/obj/item/firework_star/aesthetic
|
|
name = "aesthetic firework star"
|
|
desc = "A firework star designed to paint the sky with pretty lights."
|
|
var/list/firework_adjectives = list("beautiful", "pretty", "fancy", "colorful", "bright", "shimmering")
|
|
var/list/firework_colors = list("red", "orange", "yellow", "green", "cyan", "blue", "purple", "pink", "beige", "white")
|
|
|
|
/obj/item/firework_star/aesthetic/trigger_firework(var/datum/weather_holder/w_holder)
|
|
if(!w_holder)
|
|
return
|
|
w_holder.message_all_outdoor_players(get_firework_message())
|
|
|
|
/obj/item/firework_star/aesthetic/proc/get_firework_message()
|
|
return "You see a [pick(firework_adjectives)] explosion of [pick(firework_colors)] sparks in the sky!"
|
|
|
|
/obj/item/firework_star/aesthetic/configurable
|
|
name = "configurable aesthetic firework star"
|
|
desc = "A firework star designed to paint the sky with pretty lights. This one's advanced and can be configured to specific shapes or colors."
|
|
icon_state = "config"
|
|
var/current_color = "white"
|
|
var/current_shape = "Random"
|
|
var/list/firework_shapes = list("none", "Random",
|
|
"a circle", "an oval", "a triangle", "a square", "a pentagon", "a hexagon", "an octagon", "a plus sign", "an x", "a star", "a spiral", "a heart", "a teardrop",
|
|
"a smiling face", "a winking face", "a mouse", "a cat", "a dog", "a fox", "a bird", "a fish", "a lizard", "a bug", "a butterfly", "a robot", "a dragon", "a teppi", "a catslug",
|
|
"a tree", "a leaf", "a flower", "a lightning bolt", "a cloud", "a sun", "a gemstone", "a flame", "a wrench", "a beaker", "a syringe", "a pickaxe", "a pair of handcuffs", "a crown",
|
|
"a bottle", "a boat", "a spaceship",
|
|
"Nanotrasen logo", "a geometric-looking letter S", "a dodecahedron")
|
|
|
|
/obj/item/firework_star/aesthetic/configurable/attack_self(mob/user)
|
|
. = ..(user)
|
|
if(.)
|
|
return TRUE
|
|
var/choice = tgui_alert(user, "What setting do you want to adjust?", "Firework Star", list("Color", "Shape", "Nothing"))
|
|
if(src.loc != user)
|
|
return
|
|
|
|
if(choice == "Color")
|
|
var/color_choice = tgui_input_list(user, "What color would you like firework to be?", "Firework Star", firework_colors)
|
|
if(src.loc != user)
|
|
return
|
|
if(color_choice)
|
|
current_color = color_choice
|
|
|
|
if(choice == "Shape")
|
|
var/shape_choice = tgui_input_list(user, "What shape would you like firework to be?", "Firework Star", firework_shapes)
|
|
if(src.loc != user)
|
|
return
|
|
if(shape_choice)
|
|
current_shape = shape_choice
|
|
|
|
/obj/item/firework_star/aesthetic/configurable/get_firework_message()
|
|
var/temp_shape = current_shape
|
|
if(temp_shape == "Random")
|
|
var/list/shapes_copy = firework_shapes.Copy()
|
|
shapes_copy -= "Random"
|
|
temp_shape = pick(shapes_copy)
|
|
|
|
if(temp_shape == "none" || !temp_shape)
|
|
return "You see a [pick(firework_adjectives)] explosion of [current_color] sparks in the sky!"
|
|
else
|
|
return "You see a [pick(firework_adjectives)] explosion of [current_color] sparks in the sky, forming into shape of [current_shape]!"
|
|
|
|
#undef T_FIREWORK_WEATHER_STAR
|